[Iska]

Sergey.l, следует разместить сие перед каждой командой move. Кроме того, на Windows 2003 и выше имеет смысл задействовать не set /p, а choice.exe (на предыдущих версиях его не было в комплекте, и требовалась отдельная установка из Resource Kit'ов), наподобие:

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

choice.exe /m "Переместить *.doc"
if %errorlevel% equ 1 move d:/folder/*.doc d:/folder/2018/01/09/

choice.exe /m "Переместить *.docx"
if %errorlevel% equ 1 move d:/folder/*.docx d:/folder/2018/01/09/

choice.exe /m "Переместить *.txt"
if %errorlevel% equ 1 move d:/folder/*.txt d:/folder/2018/01/09/

endlocal
exit /b 0

[Sergey.l]

У нас Windows 7. Т.е. choice.exe будет выдавай запрос на разрешение выполнения команды? Я просто не вижу теста с (Y/N)

Sergey.l, следует разместить сие перед каждой командой move. Кроме того, на Windows 2003 и выше имеет смысл задействовать не set /p, а choice.exe (на предыдущих версиях его не было в комплекте, и требовалась отдельная установка из Resource Kit'ов), наподобие: Код: @echo off setlocal enableextensions enabledelayedexpansion choice.exe /m "Переместить *.doc" if %errorlevel% equ 1 move d:/folder/*.doc d:/folder/2018/01/09/ choice.exe /m "Переместить *.docx" if %errorlevel% equ 1 move d:/folder/*.docx d:/folder/2018/01/09/ choice.exe /m "Переместить *.txt" if %errorlevel% equ 1 move d:/folder/*.txt d:/folder/2018/01/09/ endlocal exit /b 0

[Iska]

Я просто не вижу теста с (Y/N) »

Смотрите:

Скрытый текст

«[Y,N]?» — добавляется по умолчанию, если иного не задано параметром /c:

/C список Создаваемый список выбираемых элементов. Список по умолчанию "YN".

[Sergey.l]

Все хорошо, но как быть если в батнике более 20 команд. Устанешь Y нажимать. Может есть возможность команды выполнить под одним подтверждением или запуск батника сделать с подтверждением?

Я просто не вижу теста с (Y/N) » Смотрите: Скрытый текст «[Y,N]?» — добавляется по умолчанию, если иного не задано параметром /c:

[Sergey.l]

Или может в ТоталКоммандере прописать ключ для запуска батника с подтверждением?
p.s. необходимость подтверждения возникла из за осторожности, чтобы случайно не "понажимать", а то у нас девушки в смене, которые нажимают куда попало

«[Y,N]?» — добавляется по умолчанию, если иного не задано параметром /c: »

[Sergey.l]

Наткнулся на вот эту статью http://www.winblog.ru/win7/1147767821-09121101.html
Можно сделать такое меню, чтобы под цифрами выполнялись батники?

[Sergey.l]

Воспользовался вашим советом. решил вместо подтверждения сделать диалог, меню
Написал такой код

Код:

Echo off
cls
Echo Work menu
Echo ============================================================================
Echo 1 111.bat             создать папки
Echo 2 222.bat             переместить заготовки
Echo 2 333.bat             забрать файлы по маске

Echo ============================================================================
Choice /C 123 /M "Выберите один из вариантов!"

If Errorlevel 1 Goto 1
If Errorlevel 2 Goto 2
If Errorlevel 3 Goto 3

Goto End

:3
cls
d:\папка\333.bat
Goto End


:2
cls
d:\папка\222.bat
Goto End

:1
cls
d:\папка\111.bat
Goto End

Проблема в том, что нажимаю цифру 2 или 3 выполняется все равно батник под цифрой 1
Поможете разобраться?

choice.exe »

[Iska]

Все хорошо, но как быть если в батнике более 20 команд. Устанешь Y нажимать. Может есть возможность команды выполнить под одним подтверждением »

Прошу прощения, видимо, я неправильно Вас понял. Возможно, Вы хотели что-то такое?

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

choice.exe /m "Переместить файлы *.doc, *.docx, *.txt"

if %errorlevel% equ 1 (
	move d:/folder/*.doc d:/folder/2018/01/09/
	move d:/folder/*.docx d:/folder/2018/01/09/
	move d:/folder/*.txt d:/folder/2018/01/09/
)

endlocal
exit /b 0

Или, ещё проще:

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

choice.exe /m "Переместить файлы *.doc, *.docx, *.txt"

if %errorlevel% equ 1 for %%i in (*.doc *.docx *.txt) do move "d:/folder/%%~i" "d:/folder/2018/01/09/"

endlocal
exit /b 0

Можно сделать такое меню, чтобы под цифрами выполнялись батники? »

Можно. Примерно так:

Скрытый текст

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

:Repeat
echo ╔═══════════ Меню ═══════════╗
echo ║ 1. Создать папки           ║
echo ║ 2. Переместить заготовки   ║
echo ║ 3. Забрать файлы по маске  ║
echo ║ 4. Выход из меню           ║
echo ╟────────────────────────────╢
echo ║ Выберите один из вариантов ║
echo ╚════════════════════════════╝
echo.
choice.exe /c 1234

if %errorlevel% equ 4 exit /b
if %errorlevel% equ 255 exit /b

call :Sub%errorlevel%
goto :Repeat

endlocal
exit /b 0

:Sub1
	call d:\папка\111.bat
	exit /b

:Sub2
	call d:\папка\222.bat
	exit /b

:Sub3
	call d:\папка\333.bat
	exit /b

Причём необязательно, чтобы именно «выполнялись батники» — можно исполнять код непосредственно в процедурах прямо в этом же файле.

[Sergey.l]

Подскажите, а как вы делали рамку для меню?

Код:

echo ╔═══════════ Меню ═══════════╗
echo ║ 1. Создать папки           ║
echo ║ 2. Переместить заготовки   ║
echo ║ 3. Забрать файлы по маске  ║
echo ║ 4. Выход из меню           ║
echo ╟────────────────────────────╢
echo ║ Выберите один из вариантов ║
echo ╚════════════════════════════╝
echo.

есть ли инструмент для этого или вручную символ в каждую строку?

Можно. Примерно так: Скрытый текст »