Автоматическая установка Alcohol 120%, 52%

morismoss · Отправлено: **22:11, 02-05-2008** | #51

А на забугорном форуме поддержки никто не спрашивал на счёт тихой установки?

semiono · Отправлено: **23:12, 16-09-2008** | #52

Огромное спасибо за скрипт!!!
Только вот controlclick проапдейтили! Я сначало ругаться стал, но потом смекнул...
вообще-то я au3 второй раз лишь вижу и очень далёк от этого.
Вообщем заглянул в history и нашёл. (AutoIt3.exe v3.2.12.1)
...
controlclick($Title,'Not for Business Use','Include the Alcohol Soft Toolbar (recommended).','left',1)
...
controlclick($Title,'Completing the Alcohol','Button4','left',1)
controlclick($Title,'Completing the Alcohol','Add Alcohol Virtual Drive at first run.','left',,1)
...
И ещё из моей самодеятельности

winwaitactive($Title,'Choose Components')
send('{DOWN} {BS}')
send('{DOWN} {BS}')
send('{DOWN} {BS}')
send('{DOWN} {BS}')
send('{ENTER}')

Методом тыка подбирал, хотя так и не доходит до мну почему BS (backspace) работает как uncheck? 0O
Тут вообщем я снимаю все чекбоксы, так мне более нравится.
И вообще буквально нельзяли "анчек" какойнить вместо кликов юзать?

PS: я откатил практически все рег-сетингс Alcohol52 и сохранил все его файлики, SPTD у мну предустановлен.
Ставлю InnoSetup - свой билд, захожу в алкоголь и он не может добавить адаптер!
Ставлю поверх оригинальный дистриб, при этом фотографирую реестр - изменений практически ноль!
Но при этом прога уже начинает монтировать! Удаляю (uninst.exe) - опять тоже самое и так раз десять, даже на разных системах.
Кароче я не могу понять что он делает такого что потом адаптер virtual drive становится доступным, хотя в реестре никаких изменений по сравнению с моим инсталлом... хотя драйвера и службы это такие дебри, что я понятия не имею как они заводятся!

PPS: там какой-то iss- конструктор был - я еле распаковал его! Лучше бы скрипт и выложили как есть, чем готовый эксешник.
Ведь конструктор же делаете? Тогда можно бы его поразрабатывать, ато так не интересно!

это самое, я имел ввиду, что если свой инсталл делаешь, то автоит другой версии не будет работать правильно с исходным скриптом, потому-что left добавилось!...

semiono · Отправлено: **00:29, 17-09-2008** | #53

Немного переделанный скрипт:
Alcohol_52% 4.12.7.6221, AutoIt 3.2.12.1

добавленно сегодня:
прикол в том, что чем болше настроек в реестре предустановленно тем больше проблем ;-
вот когда была чистая установка всё работало правильно, но теперь у мну не появляется
"монтировать на виртуал драйв" в проводнике - интересно от чего это зависит!
если не лезть в реестр установщик сам всё делает правильно. Но ведь хочется чуть опций поднастроить...
теперь надо искать что мешает! Ведь даже AXShlEx.dll было зарегистрированно - что ещё ему надо!
Разницы чёй-то совсем не могу понять! Всё один в один было. 0_o

а ещё проблемма, что это не годится для тихой установки в nLite!
ведь окна не должны быть видны! (AutoIt не хочет нажимать скрытые окна - InnoSetup.exe /VERYSILENT)
хотя я думаю что ничего страшного не произойдёт если окно выскочит во время установки Windows,
просто будет торчать окно! хотя это не очень красиво?

добавленно сегодня, сегодня:
из-за такого пустячка целый день провозился!
оказывается Alcohol сам мишет этот кей, а у меня было с "ошибкой"!
RegWrite("HKLM\Software\Microsoft\Windows\CurrentVersion\App Paths\Alcohol.exe", "Path", "REG_SZ", $InstallPath & "\")
Если бы все девелоперы сами добросовесно писали бы повсюду, я бы и не лез туда.
Вообщем без этого слеша проподает опция монтирования в проводнике!
Сам этот кей писать не надо так как Алкоголь его сам генерит, когда там нету App Paths\Alcohol.exe

semiono · Отправлено: **22:33, 18-09-2008** | #54

Сборка для nLite (только для теста!)
rapidshare.com/files/146375940/Alcoholz.zip.html
исходные скрипты внутри!

Проблемы:
1. не знаю к чему приведёт перезагруз shutdown -r -f -t 03 на T13 установки?
2. жаль что окна инсталлера не скрыты в autoit3, просто не знаю как это зделать.
3. недоработка пока, что сабж остаётся тоже после инсталла в {win}\RunOnce (пока лень было доделать это)

На установленной виндоус установка пока прошла успешно!

Мой экран 1152x864 - хотя у Alcohol по дефолту окно вообще как попало открывается,
конечно удобнее было бы зделать для всех - FullScreen.

Если я что-то нарушаю не наказывайте меня пожалуста! Просто предупредите?
Просто я даже не знаю, вроде Alcohol52 не варез, но мож чё не так?

Проверил:
На nLite сборке работает! +1

Alcohol был между двумя другими пакетами, всё корректно!
Похоже что внутрипакетный shutdown.exe игнорируется установкой windows, может они и не нужен даже.
Сам AutoIt запускается над десктопом уже - RunOnce соответственно.
Хотя вот тут уже я не уверен, что будет если в RunOnce будет не один пакет,
а штук 10!? Может и заглючить!... А может и нет.

mariolast · Отправлено: **22:21, 21-09-2008** | #55

semiono,
Нету готового комплекта из 53-го поста? Потестирую скажу что не так.

mariolast · Отправлено: **21:09, 05-10-2008** | #56

Цитата semiono:

из-за такого пустячка целый день провозился!
оказывается Alcohol сам мишет этот кей, а у меня было с "ошибкой"!
RegWrite("HKLM\Software\Microsoft\Windows\CurrentVersion\App Paths\Alcohol.exe", "Path", "REG_SZ", $InstallPath & "\")
Если бы все девелоперы сами добросовесно писали бы повсюду, я бы и не лез туда.
Вообщем без этого слеша проподает опция монтирования в проводнике!
Сам этот кей писать не надо так как Алкоголь его сам генерит, когда там нету App Paths\Alcohol.exe »

Не работает метод, по прежнему нету в проводнике опции монтирования

solo111 · Отправлено: **08:27, 24-10-2008** | #57

Скажите, какой строкой можно выполнить силент-установку Алкоголя 52%?
именно командной строкой, не скриптом AutoIt?

katok888 · Отправлено: **15:25, 23-11-2008** | #58

Кто знает как получить такой вариант на странице выбора компонентов:

katok888 · Отправлено: **19:50, 23-11-2008** | #59

Вобщем сам нашел на MSFN грамотно написанный скрипт, в котором можно легко менять устанавливаемые
компоненты:

Код:

; Components to choose. 1 = Yes, 0 = No.
$langfiles  = 1 ; Multi-Language Files   
$manual     = 0 ; Online manual
$shortcuts  = 1 ; Desktop Shortcut
$startmenu  = 1 ; Startmenu Entries
$starwind   = 0 ; iSCSI Service

Вот собственно сам скрипт (немного подправил под себя) :

Код:

#region - Alcohol120_1.9.6.5429 install script - (Automated with WinExists functions)

#include <IE.au3>
Opt('TrayIconDebug', 1)

; Installer.
$executable = 'Alcoholsetup.exe'
; Show progess.
$splash = 0
; Default catagory folder in startmenu.
$group = 'Alcohol 120%'
; New catagory to move the default folder into.
$catagory = ''
; Installation folder in Program Files.
$directory = 'Alcohol Soft\Alcohol 120'
; Allowed time for installation.
$allowed = 60 * 1000
; Components to choose. 1 = Yes, 0 = No.
$langfiles  = 1 ; Multi-Language Files   
$manual     = 0 ; Online manual
$shortcuts  = 1 ; Desktop Shortcut
$startmenu  = 1 ; Startmenu Entries
$starwind   = 0 ; iSCSI Service

; ----- Settings Complete (Paste registration on line 83) ------

; Set components to install via registry.
$key = 'HKLM\SOFTWARE\Alcohol Soft\Alcohol 120%\AddRemove\Components'
RegWrite($key & '\SecLangFiles',    'Installed', 'Reg_Dword', $langfiles)
RegWrite($key & '\SecManual',       'Installed', 'Reg_Dword', $manual)
RegWrite($key & '\SecShortcuts',    'Installed', 'Reg_Dword', $shortcuts)
RegWrite($key & '\SecStartMenu',    'Installed', 'Reg_Dword', $startmenu)
RegWrite($key & '\SecStarWind',     'Installed', 'Reg_Dword', $starwind)

; Run the installer.
$pid = _Install()
$time = TimerInit()
$title = 'Alcohol 120%'
Do
    Select
		Case WinExists($title, 'Already Installed')
			_Abort()

		Case WinExists($title, 'Welcome to the Alcohol 120%')
            WinMove($title, 'Welcome to the Alcohol 120%', @DesktopWidth, 0)
            ControlClick($title, 'Welcome to the Alcohol 120%', 'Button2')

        Case WinExists($title, 'License Agreement')
            ControlClick($title, 'License Agreement', 'Button2')
			
		Case WinExists('Alcohol Soft Setup', 'Additional Features and License Agreement')
			WinMove('Alcohol Soft Setup', 'Additional Features and License Agreement', @DesktopWidth, 0)
			Sleep(1000)
			$oIE = _IEAttach ('Alcohol Soft Setup', 'embedded')
			If IsObj($oIE) Then
				$oSubmit = _IEGetObjByName ($oIE, "chk1")
				If IsObj($oSubmit) Then
					_IEAction ($oSubmit, "click")
				EndIf
				_IELoadWait ($oIE)
				$oIE = 0
			EndIf
			ControlClick('Alcohol Soft Setup', 'Additional Features and License Agreement', 'Button2')
			WinWaitClose('Alcohol Soft Setup', 'Additional Features and License Agreement', 1)

        Case WinExists($title, 'Choose Components')
            ControlClick($title, 'Choose Components', 'Button2')

        Case WinExists($title, 'Choose Install Location')
            ControlClick($title, 'Choose Install Location', 'Button2')

        Case WinExists($title, 'Click Finish to close this wizard')
            ControlCommand($title, 'Click Finish to close this wizard', 'Button4', 'UnCheck'); Run
			ControlCommand($title, 'Click Finish to close this wizard', 'Button5', 'UnCheck'); Add Drive
            ControlClick($title, 'Click Finish to close this wizard', 'Button2')

        Case Else
            Sleep(250)
    EndSelect
    If TimerDiff($time) > $allowed Then _Abort()
Until Not ProcessExists($pid)

; *** Paste Registration on the next line ***


; Exit if $startmenu = 0 from above.
If Not $startmenu Then Exit

; Remove shortcuts.
If _MainShortcut('Alcohol 120%.lnk') Then
    FileDelete('Alcohol Command Launcher.lnk')
    FileDelete('Alcohol Manual.lnk')
;~  FileDelete('Uninstall Alcohol 120%.lnk')
;~  _Desktop('Alcohol 120%.lnk')
EndIf

#endregion

Exit

Func _Install($path = Default)
    ; Run the installer in Default Script directory.
    Dim $splash
    If $path = Default Then $path = @ScriptDir
    If StringRight($path, 1) <> '\' Then $path &= '\'
    If StringInStr($executable, '\') Then $path = ''
    If Not FileExists($path & $executable) Then Exit 1
    If $splash Then _Splash('Installing:' & StringTrimRight(StringReplace(@ScriptName, '_', ' '), 4))
    If StringRight($executable, 3) = 'msi' Then
        Return Run('"' & @SystemDir & '\msiexec.exe" /i "' & $path & $executable & '"')
    Else
        Return Run('"' & $path & $executable & '"')
    EndIf
EndFunc

Func _Abort()
    ; close process if exists then exit.
    Dim $pid
    If ProcessExists($pid) Then
        ProcessClose($pid)
        Exit 2
    Else
        Exit 3
    EndIf
EndFunc

Func _Desktop($shortcut)
    ; Delete a Desktop shortcut.
    If FileExists(@DesktopDir & '\' & $shortcut) Then
        Return FileDelete(@DesktopDir & '\' & $shortcut)
    ElseIf FileExists(@DesktopCommonDir & '\' & $shortcut) Then
        Return FileDelete(@DesktopCommonDir & '\' & $shortcut)
    EndIf
EndFunc

Func _MainShortcut($shortcut, $rename = '')
    ; Change working directory to correct StartMenu\Group directory.
    Dim $group, $catagory, $splash
    If $group = '' Then Return 0
    If FileExists(@ProgramsDir & '\' & $group) Then
        FileChangeDir(@ProgramsDir & '\' & $group)
    ElseIf FileExists(@ProgramsCommonDir & '\' & $group) Then
        FileChangeDir(@ProgramsCommonDir & '\' & $group)
    Else
        Return 0
    EndIf
    ; Wait for main shortcut.
    If $splash Then _Splash('Waiting for shortcuts')
    For $i = 1 To 20
        If FileExists($shortcut) Then ExitLoop
        Sleep(500)
    Next
    If $splash Then _Splash('Cleaning up:' & StringTrimRight(StringReplace(@ScriptName, '_', ' '), 4))
    ; If catagory not assigned anything, then return.
    If $catagory = '' Then Return 1
    ; Move the group folder into the catagory folder.
    If FileChangeDir('..') And DirCopy($group, $catagory & '\' & $group, 1) Then
        If DirRemove($group, 1) Then
            ; If optional rename parameter is used, then rename the group folder.
            If $rename <> '' And FileChangeDir($catagory) Then
                If DirCopy($group, $rename, 1) And DirRemove($group, 1) Then
                    Return FileChangeDir($rename)
                EndIf
            Else
                Return FileChangeDir($catagory & '\' & $group)
            EndIf
        EndIf
    EndIf
EndFunc

Func _QuickLaunch($shortcut)
    ; Delete a Quicklaunch shortcut.
    Local $subdirs = '\Microsoft\Internet Explorer\Quick Launch'
    If FileExists(@AppDataDir & $subdirs & '\' & $shortcut) Then
        Return FileDelete(@AppDataDir & $subdirs & '\' & $shortcut)
    ElseIf FileExists(@AppDataCommonDir & $subdirs & '\' & $shortcut) Then
        Return FileDelete(@AppDataCommonDir & $subdirs & '\' & $shortcut)
    EndIf
EndFunc

Func _Splash($text = '')
    ; Shows a small borderless splash message.
    Dim $splash
    If $splash Then
        If $text Then
            SplashTextOn('', $text, 500, 25, -1, 5, 1, '', 14)
        Else
            SplashOff()
        EndIf
    EndIf
EndFunc

Func _WinClose($title, $text = '')
    ; Close a window with further attempts.
    For $i = 1 To 10
        WinClose($title, $text)
        If Not WinExists($title) Then Return 1
        Sleep(500)
    Next
EndFunc

Func OnAutoItStart()
    ; A 2nd script instance will exit.
    Local $interpreter
    $interpreter = StringTrimRight(@ScriptName, 4) & ' Script Interpreter'
    If WinExists($interpreter) Then Exit
    AutoItWinSetTitle($interpreter)
EndFunc

di2blo · Конфигурация компьютера

Привет не у кого нету тихой установки Alcohol 120% 1.9.7.6221 + чтоб вечно работало