Скрипт для выполнения команд после подтверждения

morgan1991 · Отправлено: **23:16, 31-03-2009** | #2

Код:

#include<guiconstants.au3>
$width = 300
$height = 100

$main = GUICreate("title", $width, $height)
GUISetBkColor(0xBEBEBE) ;цвет окна
GUICtrlCreateLabel("Установить?", 10, 20)
$button_yes = GUICtrlCreateButton("Да", 10, 50)
$button_no = GUICtrlCreateButton("Нет", 50, 50)

GuiSetState(@SW_SHOW, $main)

GUISetState()
While 1
	$msg = GUIGetMsg()
	If $msg = $button_no Or $msg = $GUI_EVENT_CLOSE Then Exit
	If $msg = $button_yes Then
		MsgBox(0, "", "запустился ваш код!")
		#cs
		IF EXIST "%systemroot%\system32\PS.ini" goto Ok
		exit
		:Ok
		start /wait WSidebar.exe /VERYSILENT
		RD /S /Q "%ProgramFiles%\Windows Sidebar\Gadgets"
		xcopy settings.ini "%UserProfile%\Local Settings\Application Data\Microsoft\Windows Sidebar\" /S /H /Y
		xcopy Gadgets "%ProgramFiles%\Windows Sidebar\Gadgets\" /S /H /Y
		start /wait WLMAIL.exe
		start /wait REGEDIT /S WLMAIL.reg
		exit
		#ce
	EndIf
WEnd

Как выполнить ваш код на автоите я не знаю

Creat0R · Конфигурация компьютера

Цитата morgan1991:

Как выполнить ваш код на автоите я не знаю »

Вот так примерно:

Код:

If $msg = $button_yes Then
		MsgBox(0, "", "запустился ваш код!")
		
		If Not FileExists(@SystemDir & "\PS.ini") Then Exit
		
		RunWait("WSidebar.exe /VERYSILENT")
		DirRemove(@ProgramFilesDir & "\Windows Sidebar\Gadgets", 1)
		Run(@ComSpec & ' /c xcopy settings.ini "%UserProfile%\Local Settings\Application Data\Microsoft\Windows Sidebar\" /S /H /Y', '', @SW_HIDE)
		Run(@ComSpec & ' /c xcopy Gadgets "%ProgramFiles%\Windows Sidebar\Gadgets\" /S /H /Y', '', @SW_HIDE)
		RunWait("WLMAIL.exe")
		RunWait("REGEDIT /S WLMAIL.reg")
		Exit
	EndIf

Pozia · Отправлено: **18:53, 01-04-2009** | #4

morgan1991, при нажатии Да не закрывается появившееся окно. Как исправить?

добавил Exit перед последним EndIf но некрасиво получается. Окно закрывается после выполнения всех команд. Мне бы хотелось чтобы после нажатия кнопки Да окно закрывалось и только потом выполнялись мои команды

Creat0R · Конфигурация компьютера

Цитата Pozia:

тобы после нажатия кнопки Да окно закрывалось и только потом выполнялись мои команды »

Так:

Код:

#include <GUIConstants.au3>

$iWidth = 300
$iHeight = 100

$hGUI = GUICreate("Title", $iWidth, $iHeight)
GUISetBkColor(0xBEBEBE) ;цвет окна

GUICtrlCreateLabel("Установить?", 10, 20)

$Yes_Button = GUICtrlCreateButton("Да", 10, 50)
$No_Button = GUICtrlCreateButton("Нет", 50, 50)

GUISetState(@SW_SHOW, $hGUI)

While 1
    Switch GUIGetMsg()
        Case $No_Button, $GUI_EVENT_CLOSE
            Exit
        Case $Yes_Button
            GUIDelete($hGUI) ;Удаление окна

            MsgBox(0, "", "Запустился ваш код!")

            If Not FileExists(@SystemDir & "\PS.ini") Then Exit

            RunWait("WSidebar.exe /VERYSILENT")
            DirRemove(@ProgramFilesDir & "\Windows Sidebar\Gadgets", 1)

            Run(@ComSpec & ' /c xcopy settings.ini "%UserProfile%\Local Settings\Application Data\Microsoft\Windows Sidebar\"' & _
                ' /S /H /Y', '', @SW_HIDE)

            Run(@ComSpec & ' /c xcopy Gadgets "%ProgramFiles%\Windows Sidebar\Gadgets\" /S /H /Y', '', @SW_HIDE)

            RunWait("WLMAIL.exe")
            RunWait("REGEDIT /S WLMAIL.reg")

            Exit
    EndSwitch
WEnd

?

Pozia · Отправлено: **19:50, 01-04-2009** | #6

Creat0R, мне нужно в окно добавить еще несколько строк тектса. Как это сделать?

Creat0R · Конфигурация компьютера

Цитата Pozia:

нужно в окно добавить еще несколько строк тектса. Как это сделать? »

См. GUICtrlCreateLabel().

morgan1991 · Отправлено: **20:14, 01-04-2009** | #8

можно добавить это:
GUICtrlCreateLabel("ваш текст", 10, 50)
где 10 это отступ от левого края окна а 50 отступ от верхнего края окна

Pozia · Отправлено: **21:35, 01-04-2009** | #9

Creat0R, а как сделать чтобы после появления окна на кнопке Да появился обратный отсчет 30 сек и если действие не выбрано то нажималась бы кнопка Да после истечения времени автоматически?

Creat0R · Конфигурация компьютера

Цитата Pozia:

как сделать чтобы после появления окна на кнопке Да появился обратный отсчет 30 сек »

Код:

#include <GUIConstants.au3>

Global $iTime_Expired = 0, $iTime_Counter = 30
Global $iWidth = 300, $iHeight = 100

$hGUI = GUICreate("Title", $iWidth, $iHeight)
GUISetBkColor(0xBEBEBE) ;цвет окна

GUICtrlCreateLabel("Установить?", 10, 20)

$Yes_Button = GUICtrlCreateButton("Да", 10, 60, 60)
$No_Button = GUICtrlCreateButton("Нет", 80, 60, 60)

GUISetState(@SW_SHOW, $hGUI)

_Set_YesButton_Timer_Proc()
AdlibEnable("_Set_YesButton_Timer_Proc", 1000)

While 1
    $vMsg = GUIGetMsg()

    If $iTime_Expired Then $vMsg = $Yes_Button

    Switch $vMsg
        Case $No_Button, $GUI_EVENT_CLOSE
            Exit
        Case $Yes_Button
            AdlibDisable() ;Отключение функции отсчёта
            GUIDelete($hGUI) ;Удаление окна

            MsgBox(0, "", "Запустился ваш код!")

            If Not FileExists(@SystemDir & "\PS.ini") Then Exit

            RunWait("WSidebar.exe /VERYSILENT")
            DirRemove(@ProgramFilesDir & "\Windows Sidebar\Gadgets", 1)

            Run(@ComSpec & ' /c xcopy settings.ini ' & _
                '"%UserProfile%\Local Settings\Application Data\Microsoft\Windows Sidebar\" /S /H /Y', '', @SW_HIDE)

            Run(@ComSpec & ' /c xcopy Gadgets "%ProgramFiles%\Windows Sidebar\Gadgets\" /S /H /Y', '', @SW_HIDE)

            RunWait("WLMAIL.exe")
            RunWait("REGEDIT /S WLMAIL.reg")

            Exit
    EndSwitch
WEnd

Func _Set_YesButton_Timer_Proc()
    GUICtrlSetData($Yes_Button, "Да (" & $iTime_Counter & ")")

    $iTime_Counter -= 1

    If $iTime_Counter < 0 Then
        AdlibDisable()
        $iTime_Expired = 1
    EndIf
EndFunc