[Petya V4sechkin]

Удаленное удаление программ
Установка и удаление программ под АД
Удаления приложений на удаленном компьютере
[решено] Помогите найти скрипт для удаленного удаления програм

[Dvizhnyak]

Проблемма в том что я не знаю какие именно программы понаставили юзеры. Поэтому мне для начала нужено удалено получить список установленых программ. Как это сделать?

[Petya V4sechkin]

Dvizhnyak, здесь пример vbs-скрипта для получения списка установленных программ (Installed Applications Via Registry Enumeration).

Создаем файл InstalledApplications.vbs:

Код:

Dim N
If WScript.Arguments.Count = 0 Then N = "." Else N = WScript.Arguments(0)
WScript.Echo InstalledApplications(N)

Function InstalledApplications(node)
 Const HKLM = &H80000002 'HKEY_LOCAL_MACHINE
 Set oRegistry = GetObject("winmgmts://" _
  & node & "/root/default:StdRegProv")
 sBaseKey = _
  "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\"
 iRC = oRegistry.EnumKey(HKLM, sBaseKey, arSubKeys)

 For Each sKey In arSubKeys

  iRC = oRegistry.GetStringValue( _
   HKLM, sBaseKey & sKey, "DisplayName", sValue)
  If iRC <> 0 Then
   oRegistry.GetStringValue _
    HKLM, sBaseKey & sKey, "QuietDisplayName", sValue
  End If
  If sValue <> "" Then
   InstalledApplications = _
    InstalledApplications & sValue & vbCrLf
  End If
 Next
End Function

Далее, файл ScanWorkgroupARP.cmd:

Код:

@Echo Off
SetLocal EnableExtensions

For /F "Tokens=1 Delims=\ " %%I In ('Net View ^| Find "\"') Do (
  Echo %%I
  CScript /Nologo InstalledApplications.vbs %%I >%%I.lst
)

Запускаем ScanWorkgroupARP.cmd и получаем набор файлов типа Имя_компа.lst (соответствующих включенным на данный момент компьютерам) со списками программ.

P. S. Предполагается, что учетная запись (под которой запускаем скрипты) имеет административный доступ. А на компах работает служба "Удаленный реестр".

[Dvizhnyak]

А может всетаки есть способ зайти на компьютер юзера через "Удаленый рабочий стол", но так чтобы компьютер пользователя не блокировался и юзер не знал что я зашел на его компьютер?

[Petya V4sechkin]

Может всетаки есть способ зайти на компьютер юзера через "Удаленый рабочий стол", но так чтобы компьютер пользователя не блокировался?

Это запрещено лицензией.