[gora]

Код:

rem Распаковка файла
Expand -r "Temp\Comctl2.dl_" Temp\ >nul
pause
rem Упаковка файла
MakeCab /D CompressionMemory=21 /D CompressionType=LZX /L "Temp" Temp\Comctl2.dll Comctl2.dl_ >nul
pause

Можете подсмотреть в скрипте UpDatePack-a.

[Pozia]

gora, выполняю так:

Код:

Expand -r "*.*" \ >nul

и ничего. А нужно чтобы все файлы из текущей папки распаковало в эту же папку.

[gora]

нужно чтобы все файлы из текущей папки распаковало в эту же папку »

Текущей - значит скрипт находится в той же папке, что и распаковываемые файлы.

Код:

For %%I In (*.??_) Do Expand -r "%%I" >nul

[Pozia]

Можете подсмотреть в скрипте UpDatePack-a. »

я туговат с этими скриптами. Могли бы Вы подсказать еще скрипт для распаковки кучи файлов в нужную мне папку и упаковку обратно всех файлов из одной папки в другую?

[gora]

скрипт для распаковки кучи файлов в нужную мне папку и упаковку обратно всех файлов из одной папки в другую? »

Код:

@Echo Off
setlocal enabledelayedexpansion
rem Путь и имя папки со сжатыми файлами
Set "Source=c:\musor\temp"
rem Путь и имя папки для распакованных файлов
Set "Out_1=c:\musor\temp1"
rem Путь и имя папки для повторно сжатых файлов
Set "Out_2=c:\musor\temp2"

rem Распаковка файлов из папки Source в папку Out_1
For /F "UseBackQ Delims=" %%I In (`Dir "%Source%\*.??_" /B /ON 2^>nul`) Do Expand -r "%Source%\%%~I" "%Out_1%" >nul
Pause

rem Упаковка файлов из папки Out_1 в папку Out_2
For /F "UseBackQ Delims=" %%I In (`Dir "%Out_1%\*" /B /ON 2^>nul`) Do (
	Set ext=%%~xI
	MakeCab /D CompressionMemory=21 /D CompressionType=LZX /L "%Out_2%" "%Out_1%\%%~I" "%%~nI!ext:~0,-1!_" >nul
)
Pause
Exit

[Pozia]

gora, подскажите еще команду пожалуйста. Мне нужно кучу файлов из одной папки упаковать в CAB архив в другую папку. Как это записать?

[E-mpty]

Pozia, я делал так:

Код:

For %%I In (Диск:\папка с файлами,которые нужно уапаковать\*.*) Do START /WAIT MAKECAB.exe "%%~I"

Запакованные файлы появится там от куда был запущен батник.

[Petya V4sechkin]

нужно кучу файлов из одной папки упаковать в CAB архив в другую папку.

Можно с помощью Makecab:

Код:

@Echo Off
SetLocal EnableExtensions

Set SrcDir=Папка_с_файлами
Set DestCAB=Полное_имя_CAB-файла

Echo .OPTION EXPLICIT > "%Temp%\x1.DDF"
Echo .Set RptFileName="%Temp%\x1.RPT" >> "%Temp%\x1.DDF"
Echo .Set InfFileName=NUL >> "%Temp%\x1.DDF"
Echo .Set DestinationDir= >> "%Temp%\x1.DDF"
Echo .Set CabinetName1="%DestCAB%" >> "%Temp%\x1.DDF"
Echo .Set DiskDirectoryTemplate= >> "%Temp%\x1.DDF"
Echo .Set UniqueFiles=Off >> "%Temp%\x1.DDF"
Echo .Set FolderSizeThreshold=5000000 >> "%Temp%\x1.DDF"
Echo .Set MaxDiskSize=0 >> "%Temp%\x1.DDF"
Echo .Set Cabinet=On >> "%Temp%\x1.DDF"
Echo .Set Compress=On >> "%Temp%\x1.DDF"
Echo .Set CompressionType=LZX >> "%Temp%\x1.DDF"
Echo .Set CompressionMemory=21 >> "%Temp%\x1.DDF"
For /F "Delims=" %%K In ('Dir /A-D /B "%SrcDir%"') Do Echo "%SrcDir%\%%~K" >> "%Temp%\x1.DDF"
MAKECAB.EXE /F "%Temp%\x1.DDF"

или воспользоваться Cabarc.exe

[Pozia]

Petya V4sechkin, а можете попроще написать команду? Самому не получается. Мне нужно запустить скрипт, который сожмет все файлы в папке лежащей рядом со скриптом в файл под тем же именем что и папка??? Ведение журнала мне совершенно не нужно (если я правильно понял Ваш скрипт)