[SyDr]

Да в том то и дело, что не хочется его разворачивать. При развернутом окне и SEND замечательно работает »

Дело в том, что если окно неактивно - далеко не факт, что оно среагирует. Например, в моём случае высылка работает, но игра реагирует только после разворачивания (получения фокуса).

[araneon]

Спасибо огромное что отозвались на мой вопрос. Но WinActivate("заголовок нужного окна", "") непомогает, почемуто окно нестановится активным, заголовок окна смотрел в AutoIt v3 Window Info в строке >>>>Window<<<<< Title. Может ещё как небуть можно сделать его активным ???

[6757439]

Цитата CrazyNNM:а как найти имена этих контролов? » Используя бесплатную утилиту debugbar »

у меня прога отображается в меню выбора панелей, но не запускается =( мож есть какая-то наподобии?

[Maza Faka]

почемуто окно нестановится активным »

заголовок окна смотрел в AutoIt v3 Window Info »

Какой заголовок показывает AutoIt Window Info?

у меня прога отображается в меню выбора панелей, но не запускается »

Курсором мыши тянешь иконку в виде "прицела" на интересующий тебя объект и смотришь его параметры.

[6757439]

Спасибо огромное что отозвались на мой вопрос. Но WinActivate("заголовок нужного окна", "") непомогает, почемуто окно нестановится активным, заголовок окна смотрел в AutoIt v3 Window Info в строке >>>>Window<<<<< Title. Может ещё как небуть можно сделать его активным ??? »

поробуй комманду, которая дает комманды даже неактивному окну:

Код:

ControlSend ( "title", "text", controlID, "string" [, flag] )

[araneon]

Незнаю печему оно нестановится активным, AutoIt Window Info показывает что заголовок "Setup - FOX*Video Converter" но выход из положения нашолся в таком виде ?Код?WinWait("Setup - FOX Video Converter","Setup has finished installing ")?ControlClick("Setup - FOX Video Converter","Setup has finished installing ","TNewCheckListBox1")

[Babullika]

Здраствуйте ,
Помогите плиз реализовать - нужно если интернет работает больше часа по времени, отключить интернет и проверить отключился ли ... интернет адсл , при отключении надо чтото вроде длл метода так как rasdial "название подключения" /disconnect почемуто невсегда срабатывает
заранее спасибо.

[Maza Faka]

Babullika
Незнаю, как сработает с ADSL подключением, но с dialup работает:

Код:

While 1
    If Int(_RASConStat(4) / 1000 / 60) >= 60 Then
        $hRASConn = _RasEnumConnections()
        If Not @error Then _RasHangUp($hRASConn)
        Exit
    EndIf

    Sleep(1000)
WEnd

; #FUNCTION# ====================================================================================================================
; $iFlag:
; 1 - The number of bytes transmitted through this connection or link.
; 2 - The number of bytes received through this connection or link.
; 3 - Total
; 4 - The amount of time, in milliseconds, that the connection or link has been connected.
Func _RASConStat($sFlags = 1)
    Local $hRASConn = _RasEnumConnections()
    If @error Then Return SetError(1, 0, 0)

    $tRAS_STATS = DllStructCreate("dword dwSize;dword dwBytesXmited;dword dwBytesRcved;dword dwFramesXmited;" & _
                                  "dword dwFramesRcved;dword dwCrcErr;dword dwTimeoutErr;dword dwAlignmentErr;" & _
                                  "dword dwHardwareOverrunErr;dword dwFramingErr;dword dwBufferOverrunErr;" & _
                                  "dword dwCompressionRatioIn;dword dwCompressionRatioOut;dword dwBps;dword dwConnectDuration")

    DllStructSetData($tRAS_STATS, "dwSize", DllStructGetSize($tRAS_STATS))

    $aRet = DllCall("rasapi32.dll", "int", "RasGetConnectionStatistics", _
                                            "hwnd", $hRASConn, _
                                            "ptr", DllStructGetPtr($tRAS_STATS))
    If $aRet[0] Then Return SetError(2, 0, 0)

    Local $iResult = 0

    Switch $sFlags
        Case 1
            $iResult = DllStructGetData($tRAS_STATS, "dwBytesXmited")
        Case 2
            $iResult = DllStructGetData($tRAS_STATS, "dwBytesRcved")
        Case 3
            $iResult = DllStructGetData($tRAS_STATS, "dwBytesXmited") + DllStructGetData($tRAS_STATS, "dwBytesRcved")
        Case 4
            $iResult = DllStructGetData($tRAS_STATS, "dwConnectDuration")
    EndSwitch

    Return $iResult
EndFunc   ;==>_RASConStat

Func _RasEnumConnections()
    Local Const $MAX_PATH = 260
    Local Const $RAS_MaxDeviceType = 16
    Local Const $RAS_MaxEntryName = 256
    Local Const $RAS_MaxDeviceName = 128

    Local $tRASCONN, $iCntByte, $iCntConn, $aRet

    $tRASCONN = DllStructCreate("dword dwSize;hwnd hRasConn;char szEntryName[" & $RAS_MaxEntryName + 1 & "];" & _
                                "char szDeviceType[" & $RAS_MaxDeviceType + 1 & "];" & _
                                "char szDeviceName[" & $RAS_MaxDeviceName + 1 & "];" & _
                                "char szPhonebook[" & $MAX_PATH & "];" & _
                                "dword dwSubEntry;byte guidEntry[16];dword dwFlags;byte luid[8]")

    DllStructSetData($tRASCONN, "dwSize", DllStructGetSize($tRASCONN))

    $iCntByte = DllStructCreate("dword")
    $iCntConn = DllStructCreate("dword")

    DllStructSetData($iCntByte, 1, DllStructGetSize($tRASCONN))

    $aRet = DllCall("rasapi32.dll", "int", "RasEnumConnections", _
                                            "ptr", DllStructGetPtr($tRASCONN), _
                                            "ptr", DllStructGetPtr($iCntByte), _
                                            "ptr", DllStructGetPtr($iCntConn))

    If $aRet[0] Then Return SetError(1, $aRet[0], -1)
    If DllStructGetData($iCntConn, 1) < 1 Then Return SetError(2, 0, 0) ;Error: not opened connections

    Return DllStructGetData($tRASCONN, "hRasConn")
EndFunc   ;==>_RasEnumConnections

Func _RasHangUp($HRASCONN)
    $aRet = DllCall("Rasapi32.dll", "int", "RasHangUp", _
                                            "hwnd", $HRASCONN)
    Return $aRet[0]
EndFunc   ;==>_RasHangUp

[CrazyNNM]

почему-то не пашет у меня функция
_IEFormSubmit($oForm)
название кнопки я указал правльно, как в дебагере указано....

код

Код:

#include <IE.au3>
$sURL = "http://192.168.1.1/"
$oIE = _IECreate($sURL)
$oName = _IEGetObjByName($oIE, "username")
$oPass = _IEGetObjByName($oIE, "password")
$oForm = _IEFormGetObjByName($oIE, "login")
_IEFormElementSetValue($oName, "admin")
_IEFormElementSetValue($oPass, "admin")
_IEFormSubmit($oForm)

[Creat0R]

И опять вопрос по RegExp'сам (не уверен, но вроде это уже обсуждали)...

Пытаюсь сделать универсальную функцию для получения значения ком. строки:

Код:

If $CmdLine[0] = 0 Then $CmdLineRaw = '/Param=1 -File "C:\Program Files\Some App\File - Name.txt" /URL "http://google.com"'

MsgBox(64, "", _
    _GetCmdLine($CmdLineRaw, "/Param=") & @LF & _
    _GetCmdLine($CmdLineRaw, "/URL") & @LF & _
    _GetCmdLine($CmdLineRaw, "-File"))

Func _GetCmdLine($sCmdLine, $sArgument)
    If Not StringInStr($sCmdLine, $sArgument) Then Return SetError(1, 0, "")

    Local $sRetCmd = StringRegExpReplace($sCmdLine, '(?i).*' & $sArgument & '( |)("|)(.*?)("|)( /| -|$).*$', '\3')
    If $sRetCmd = $sCmdLine Then Return SetError(2, 0, "")

    Return StringStripWS($sRetCmd, 3)
EndFunc

Проблема в том, что если в значении параметра присутствует хоть один (потенциальный) разделитель ком строки (в нашем случае это - или /), то значение обрывается именно на нём, и возвращается уже не целиком. Как и видно на примере выше, в третьем значении (путь к файлу) нехватает «- Name.txt», причину я знаю, там происходит поиск по аргументу, затем поиск кавычки (если есть такова), затем поиск любой строки до... либо закрывающей кавычки, либо одного из разделителей параметров (/ или -), смотря что попадётся первым. Вот именно это мне и нужно исправить, чтобы разделитель определялся только после закрывающей кавычки (если она конечно присутствует, значение может быть и не в кавычках, это указывает юзер).