Автоматическая установка Alcohol 120%, 52%

Автоматическая установка Alcohol 120%, 52%

unikum111

Старожил

Сообщения: 212
Благодарности: 33

Конфигурация

Профиль | Отправить PM | Цитировать

Изменения

Автор: unikum111
Дата: 01-12-2008

Alcohol 1.9.8.7117

Сайт программы
Страницы загрузки: Alcohol 52%, Alcohol 120%
Описание программы:

Поскольку я так и не смог найти/придумать способ "тихой" установки, я написал AutoIt скрипт для инсталляции, который, собственно и предлагаю Вашему вниманию. Если кто-то знает другие способы "тихой" утсановки, буду рад узнать о них. Единственным условием работы скрипта является предварительная установка драйвера SPTD (я его интегрирую в дистрибутив аддном, например).
Скрипт установки и регистрации Alcohol 120%/52%:

Код:

$Title='Alcohol'
;Файл инсталлятор
$SetupFile='Alcoholsetup.exe'
;Пусть к папке с программой
$InstallPath=@ProgramFilesDir & '\Alcohol'

;Блокируем клавиатуру и мышь
Blockinput(1)

;Установка программы
;Запускаем инсталлятор
run($SetupFile)
winwaitactive($Title,'Welcome to the Alcohol')
send('{ENTER}')
;Соглашаемся с лицензионным соглашением
winwaitactive($Title,'License Agreement')
send('{ENTER}')
;Отказываемся от установки Alcohol toolbar (только для Alcohol 52%)
if winexists($Title,'Not for Business Use') Then
winwaitactive($Title,'Not for Business Use')
controlclick($Title,'Not for Business Use','Include the Alcohol Soft Toolbar (recommended).',1)
send('{ENTER}')
endif
;Отказываемся от установки ярлыка на рабочем столе и онлайн руководства
winwaitactive($Title,'Choose Components')
send('{PGDN} {UP} {BS}')
send('{ENTER}')
;Выбираем путь для инсталляции
winwaitactive($Title,'Choose Install Location')
send($InstallPath)
send('{ENTER}')
winwaitactive($Title,'Completing the Alcohol')
;Снимаем галочку с пункта "&Run Alcohol..."
controlclick($Title,'Completing the Alcohol','Button4',1)
;Снимаем галочку с пункта "Add Alcohol Virtual Drive at first run."
controlclick($Title,'Completing the Alcohol','Add Alcohol Virtual Drive at first run.',1)
send('{ENTER}')

;Регистрация для патча от Gegter или для keymaker 3.8 от Betamster
if not fileexists('patch.exe') and not fileexists('keymaker.exe') Then exit
if fileexists('patch.exe') Then
run('patch.exe')
WinWaitActive('GEGTER')
ControlClick('GEGTER','','patCh',1)
WinWaitActive('AX_RU.dll','Can not find the file. Search the file?')
ControlClick('AX_RU.dll','Can not find the file. Search the file?','&Да',1)
WinWaitActive('Открыть')
send(@ProgramFilesDir & '\Alcohol\Langs\AX_RU.dll')
send("{ENTER}")
WinWaitActive('star_syn_client.dll','Can not find the file. Search the file?')
ControlClick('star_syn_client.dll','Can not find the file. Search the file?','&Да',1)
WinWaitActive('Открыть')
send(@ProgramFilesDir & '\Alcohol\star_syn_client.dll')
send("{ENTER}")
WinWaitActive('GEGTER')
ControlClick('GEGTER','','eXit',1)
exit
endif
if fileexists('keymaker.exe') Then
run('keymaker.exe')
WinWaitActive('Activation keymaker')
controlclick('Activation keymaker','','Register',1)
controlclick('Activation keymaker','','Patch server check [Optional]',1)
controlclick('Activation keymaker','','Activate',1)
winclose('Activation keymaker')
exit
Endif

;Разблокируем клавиатуру и мышь
Blockinput(0)

Вариант скрипта установки Alcohol 120% reteil от sattva (на основе скрипта от Sanja Alone)

Код:

#cs
----------------------
Приложение: Alcohol 120%
На какой(их) версии(ях) тестировалось: 1.9.5 (build 3823); 1.9.5 (build 4212); Alcohol120_retail_1.9.7 (build 6221)

Автор скрипта: Sanja Alone (http://forum.oszone.net/member.php?userid=28800); sattva (http://forum.oszone.net/member.php?userid=27732)
----------------------
#ce
;предотвращение возможности множественного запуска скрипта
If WinExists(@ScriptName) Then Exit
AutoItWinSetTitle(@ScriptName)
;скрыть в системной панели индикатор AutoIt
;AutoItSetOption("TrayIconHide", 1)
;Отображать текущую строку сценария с помощью индикатора системной панели в режиме отладки.
AutoItSetOption("TrayIconDebug", 1)
AutoItSetOption("SendKeyDelay", 10)
If ProcessExists ( "ps.exe" )<>0 Then
     ProcessClose ( "ps.exe" )
     ProcessWaitClose ( "ps.exe" )
EndIf
;нельзя блокировать при находящемся в памяти Punto Switcher-е - не будет работать установка
;блокируем мышь и клаву
;If @OSType="WIN32_NT" Then BlockInput ( 1 )
#cs
----------------------
пояснения
----------------------

Принцип установки такой:
1. Запускаем инсталлятор и отказываемся от перезагрузки после установки драйвера SPTD
2. Создаем ярлык для запуска скрипта установки Alcohol в меню "Автозагрузка" (т.е. этого же скрипта)
3. После перезагрузки установка будет продолжена

P.S. Возобновление установки сделано через меню, а не через ветку RunOnceEx для нормальной работы скрипта при установке приложений с пом. WPI

----------------------
объявление переменных
----------------------

$Title - заголовок окна установки
$file - установочный файл
$programgroup - в какую программную группу положить ярлыки программы
$AutoIt3exePath - если установка производится из au3, а не из exe файла, то укажите здесь путь к AutoIt3.exe без обратного слэша в конце (например: EnvGet("CDROM")&"\Tools")
$hostsban - привязка IP адресов доменов Алкоголя к локальной машине 127.0.0.1 (1 - да; любое другое значение - нет)

Переменная $patchfile - имя "лекарственного" файла.
У Вас может быть другой патч, а может и рабочий серийник, поэтому Алкоголь будет 
зарегистрирован только при наличии такого же патча или рабочего серийника.

!!! Если серийник делается рабочим при помощи патча, то значение переменной $SNwork должно быть отличным от единицы. !!!

Если у Вас есть рабочий серийник, то присвойте его переменной $serial, 
а имя пользователя - переменной $username; еще задайте $SNwork=1.

В противном же случае, будет просто произведена установка и 
прописаны в реестр н-рые настройки Алкоголя.

-----------------------------------
#ce
Global $Title='Alcohol'
Global $file='Alcohol120_retail_1.9.7.6221.exe'
Global $patchfile='keymaker.exe'
Global $programgroup='CD и DVD утилиты\Alcohol 120%'
Global $username='Users'
Global $serial=''
Global $SNwork=0
Global $hostsban=1
Global $AutoIt3exePath=''
Global $InstPatch=@ProgramFilesDir & '\Alcohol Soft\Alcohol 120\'

;установка
Run ( @ScriptDir&'\'&$file )
WinWait($Title,"Welcome")
WinActivate($Title,"Welcome")
WinWaitActive($Title,"Welcome")
Send("{ENTER}")
WinWait($Title,"License Agreement")
WinActivate($Title,"License Agreement")
WinWaitActive($Title,"License Agreement")
Send("{ENTER}")
If WinWait("SPTD","",3) Then
     WinActivate("SPTD")
     WinWaitActive("SPTD")
     Send("{ENTER}")
     WinWait($Title,"Setup must restart Windows")
     WinActivate($Title,"Setup must restart Windows")
     WinWaitActive($Title,"Setup must restart Windows")
     ControlClick($Title,"Setup must restart Windows","Button2")
     ;создание ярлыка для запуска скрипта после перезагрузки
     If @compiled=1 Then
         FileCreateShortcut(@ScriptFullPath,@StartupCommonDir&'\'&$Title&'.lnk',@ScriptDir)
       Else
         FileCreateShortcut($AutoIt3exePath&"\Autoit3.exe "&@ScriptFullPath,@StartupCommonDir&'\'&$Title&'.lnk',@ScriptDir)
     EndIf
     MsgBox (64,'Информация','Установка '&$Title&' будет продолжена после перезагрузки',5)
	 AdlibEnable("restart")
     Exit
EndIf
;нужно для переустановки
AdlibEnable("AlreadyInstalled",500)
WinWait($Title,"Choose Components")
AdlibDisable()
WinActivate($Title,"Choose Components")
WinWaitActive($Title,"Choose Components")
ControlFocus($Title,"Choose Components","SysTreeView321")
;отключить "Desktop Shortcut"
Send("{DOWN}")
Send("{DOWN}")
Send("{DOWN}")
Send("{DOWN}")
Send("{SPACE}")
;Далее
Send("{ENTER}")
WinWait($Title,"Choose Install Location")
WinActivate($Title,"Choose Install Location")
WinWaitActive($Title,"Choose Install Location")
$InstPath = ControlGetText($Title,"Choose Install Location","Edit1")
;по ум. C:\Program Files\Alcohol Soft\Alcohol 120
Send("{ENTER}")
WinWait($Title,"Completing")
WinActivate($Title,"Completing")
WinWaitActive($Title,"Completing")
;снять галку с пункта "Run Alcohol"
Send("{SPACE}")
Send("{ENTER}")

Sleep ( 50 )

;регистрация/лечение Алкоголя (при наличии серийника или патча)
If $serial<>'' Then ;если есть серийник, то производим регистрацию (честным способом или с пом. патча)
    	Select
          Case $SNwork=1 ;если серийник легальный
               If $username<>'' Then RegWrite('HKEY_CURRENT_USER\Software\Alcohol Soft\Alcohol 120%\Info',"UserName","REG_SZ",$username)
               RegWrite('HKEY_CURRENT_USER\Software\Alcohol Soft\Alcohol 120%\Info',"ServerKey","REG_SZ",$serial)
          Case Else ;  (проверялось на версии 1.9.5 build 4212)
                  If FileExists ( @ScriptDir&'\'&$patchfile ) Then
				    FileCopy (@ScriptDir & '\' & $patchfile, $InstPatch, 1)
                    FileChangeDir ( $InstPatch )
                    ;выключения звука (чтобы кейген не шумел)
                    Send('{VOLUME_MUTE}')
                    ;запуск кейгена
                    Run ( $InstPatch & '\' & $patchfile )
                    WinWait ( 'Activation keymaker', 'Activate' )
                    WinActivate ( 'Activation keymaker', 'Activate' )
                    WinWaitActive ( 'Activation keymaker', 'Activate' )
                    ControlSetText ( 'Activation keymaker', 'Activate', 'TMemo1', $serial )
                    ;Register
                    ControlClick ( 'Activation keymaker', 'Register', 'TButton4' )
                    Sleep(400)
                    ;Activate
                    ControlClick ( 'Activation keymaker', 'Activate', 'TButton3' )
                    Sleep(400)
					;Patch Server Check
					ControlClick ( 'Activation keymaker', 'Patch server check [Optional]', 'TButton1' )
                    Sleep(400)
                    WinClose ( 'Activation keymaker', 'Activate' )
                    WinWaitClose ( 'Activation keymaker', 'Activate' )
                    ;включения звука
                    Send('{VOLUME_MUTE}')
               EndIf
     EndSelect
ElseIf FileExists ( @ScriptDir&'\'&$patchfile ) Then ;если есть патч, то копируем его в каталог Алкоголя и проводим лечение (проверялось на версии 1.9.7 build 6221)
       FileCopy ( @ScriptDir & '\' & $patchfile, $InstPatch, 1 )
	   FileCopy(@ScriptDir & '\*.txt',  $InstPatch, 9)
       FileChangeDir ( $InstPatch & '\' )
       Run ( $InstPatch & $patchfile )
                    WinWait ( 'Activation keymaker', 'Activate' )
                    WinActivate ( 'Activation keymaker', 'Activate' )
                    WinWaitActive ( 'Activation keymaker', 'Activate' )
                    ;Register
                    ControlClick ( 'Activation keymaker', 'Register', 'TButton4' )
                    Sleep(400)
                    ;Activate
                    ControlClick ( 'Activation keymaker', 'Activate', 'TButton3' )
                    Sleep(400)
					;Patch Server Check
					ControlClick ( 'Activation keymaker', 'Patch server check [Optional]', 'TButton1' )
                    Sleep(400)
                    WinClose ( 'Activation keymaker', 'Activate' )
                    WinWaitClose ( 'Activation keymaker', 'Activate' )
EndIf

;привязка IP адресов доменов Алкоголя к локальной машине (127.0.0.1), чтобы он не лез проверять серийник
If $hostsban=1 Then hostsban()

;н-рые настройки
RegWrite('HKEY_CURRENT_USER\Software\Alcohol Soft\Alcohol 120%\Options\Display',"AutostartWhenWindowsStartup","REG_SZ",'0');Отключить "Запускать программу автоматически вместе с Windows"
RegWrite('HKEY_CURRENT_USER\Software\Alcohol Soft\Alcohol 120%\Options\Display',"ExecuteInFullScreen","REG_SZ",'0') ;Отключить "Запускать программу п полноэкранном режиме"
RegWrite('HKEY_CURRENT_USER\Software\Alcohol Soft\Alcohol 120%\Options\Display',"ListPhysicalDevicesFirst","REG_SZ",'0') ;Отключить "Отображать физические накопители ПЕРЕД виртуальными"
RegWrite('HKEY_CURRENT_USER\Software\Alcohol Soft\Alcohol 120%\Options\General',"AutoCheckCurrentVersionViaInternetAtStart","REG_SZ",'0');Отключить "Проверять нличие новых версий на сайте программы"
RegWrite('HKEY_CURRENT_USER\Software\Alcohol Soft\Alcohol 120%\Options\Virtual drive',"MountImageTo1stDeviceOnDblClickingImageFile","REG_SZ",'1');Включить "монтировать образ на Устройство 0 по двойному щелчку"
RegWrite('HKEY_CURRENT_USER\Software\Alcohol Soft\Alcohol 120%\Options\Recording',"OverBurnDisc","REG_SZ",'1');Включить "Экстразапись"

;установка ручного типа запуска службы StarWindService (по ум. "Авто")
RegWrite('HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\StarWindService','Start',"REG_DWORD",0x00000003)

;удаление из автозагрузки ярлыка для запуска скрипта
FileDelete ( @StartupCommonDir&'\'&$Title&'.lnk' )

;перенос и удаление ярлыков
FileCopy ( @ProgramsCommonDir & '\Alcohol 120%\Alcohol 120%.lnk', @AppDataDir & '\Microsoft\Internet Explorer\Quick Launch\Alcohol 120%.lnk', 1 )
FileDelete ( @DesktopCommonDir & '\Alcohol 120%.lnk' )
Sleep ( 50 )
If StringLower($programgroup)<>'alcohol 120%' Then
DirCopy ( @ProgramsCommonDir & '\Alcohol 120%', @ProgramsCommonDir & '\' & $programgroup, 1 )
Sleep ( 50 )
DirRemove ( @ProgramsCommonDir & '\Alcohol 120%', 1 )
EndIf

;Запускаем первый раз Alcohol 120%
Run($InstPatch & '\Alcohol_.exe')
WinWait('Alcohol 120%')
Sleep(10000)
ProcessClose('Alcohol_.exe')
ProcessWaitClose('Alcohol_.exe')
;BlockInput ( 0 )

;----------------------
;вспомогательные ф-ции
;----------------------
Func AlreadyInstalled()
     If WinExists($Title,"Already Installed") Then
          WinActivate($Title,"Already Installed")
          WinWaitActive($Title,"Already Installed")
          Send("{ENTER}")
		  RunWait('regedit /S ' & @ScriptDir & '\DeleteActivation.reg','',@SW_HIDE)
     EndIf
EndFunc

Func hostsban()
     $file=FileOpen(@SystemDir&'\drivers\etc\hosts',1)
     If $file = -1 Then
          Return(0)
          SetError(1)
     Else
          FileWriteLine($file,"127.0.0.1       serial.alcohol-soft.com")
          FileWriteLine($file,"127.0.0.1       support.alcohol-soft.com")
          FileWriteLine($file,"127.0.0.1       www.alcohol-soft.com")
          FileWriteLine($file,"127.0.0.1       images.alcohol-soft.com")
          Return(1)
          SetError(0)
     EndIf
     FileClose($file)
 EndFunc
 
 Func restart()
	 $j=30
ProgressOn("Пожалуйста, подождите...", "Происходит уничтожение данных :)", "Система обнаружила использование нелегальной" & CHR(10) & "копии Windows. Через " & $j & " сек. все данные" & CHR(10) & "на ваших дисках будут уничтожены.")
For $i = 1 to 99 step 3.3
	$j=$j-1 
	sleep(1000)
ProgressSet( $i, "Система обнаружила использование нелегальной" & CHR(10) & "копии Windows. Через " & $j & " сек. все данные" & CHR(10) & "на ваших дисках будут уничтожены.")
Next
ProgressSet(-1 , "Шеф! Все пропало. Прощайте.")
Shutdown(2)
sleep(5000)
EndFunc

Скрипт, предложенный участником конференции katok888 для установки Аlcohol.120.v1.9.8.7117

Код:

#region - Alcohol.120.v1.9.8.7117 install script - (Automated with WinExists functions)

#include <IE.au3>
Opt('TrayIconDebug', 1)

; Installer.
$executable = 'Alcoholsetup.exe'
; Show progess.
$splash = 0
; Default catagory folder in startmenu.
$group = 'Alcohol 120%'
; New catagory to move the default folder into.
$catagory = ''
; Installation folder in Program Files.
$directory = 'Alcohol Soft\Alcohol 120'
; Allowed time for installation.
$allowed = 60 * 1000
; Components to choose. 1 = Yes, 0 = No.
$SecACID    = 1 ; A.C.I.D Wizard
$langfiles  = 1 ; Multi-Language Files   
$manual     = 0 ; Online manual
$shortcuts  = 1 ; Desktop Shortcut
$startmenu  = 1 ; Startmenu Entries
$starwind   = 0 ; iSCSI Service

; ----- Settings Complete (Paste registration on line 83) ------

; Set components to install via registry.
$key = 'HKLM\SOFTWARE\Alcohol Soft\Alcohol 120%\AddRemove\Components'
RegWrite($key & '\SecACID',         'Installed', 'Reg_Dword', $SecACID)
RegWrite($key & '\SecLangFiles',    'Installed', 'Reg_Dword', $langfiles)
RegWrite($key & '\SecManual',       'Installed', 'Reg_Dword', $manual)
RegWrite($key & '\SecShortcuts',    'Installed', 'Reg_Dword', $shortcuts)
RegWrite($key & '\SecStartMenu',    'Installed', 'Reg_Dword', $startmenu)
RegWrite($key & '\SecStarWind',     'Installed', 'Reg_Dword', $starwind)

; Run the installer.
$pid = _Install()
$time = TimerInit()
$title = 'Alcohol 120%'
Do
    Select
		Case WinExists($title, 'Already Installed')
			_Abort()

		Case WinExists($title, 'Welcome to the Alcohol 120%')
            WinMove($title, 'Welcome to the Alcohol 120%', @DesktopWidth, 0)
            ControlClick($title, 'Welcome to the Alcohol 120%', 'Button2')

        Case WinExists($title, 'License Agreement')
            ControlClick($title, 'License Agreement', 'Button2')
			
		Case WinExists('Alcohol Soft Setup', 'Additional Features and License Agreement')
			WinMove('Alcohol Soft Setup', 'Additional Features and License Agreement', @DesktopWidth, 0)
			Sleep(1000)
			$oIE = _IEAttach ('Alcohol Soft Setup', 'embedded')
			If IsObj($oIE) Then
				$oSubmit = _IEGetObjByName ($oIE, "chk1")
				If IsObj($oSubmit) Then
					_IEAction ($oSubmit, "click")
				EndIf
				_IELoadWait ($oIE)
				$oIE = 0
			EndIf
			ControlClick('Alcohol Soft Setup', 'Additional Features and License Agreement', 'Button2')
			WinWaitClose('Alcohol Soft Setup', 'Additional Features and License Agreement', 1)

        Case WinExists($title, 'Choose Components')
            ControlClick($title, 'Choose Components', 'Button2')

        Case WinExists($title, 'Choose Install Location')
            ControlClick($title, 'Choose Install Location', 'Button2')

        Case WinExists($title, 'Click Finish to close this wizard')
            ControlCommand($title, 'Click Finish to close this wizard', 'Button4', 'UnCheck'); Run
			;ControlCommand($title, 'Click Finish to close this wizard', 'Button5', 'UnCheck'); Add Drive
            ControlClick($title, 'Click Finish to close this wizard', 'Button2')

        Case Else
            Sleep(250)
    EndSelect
    If TimerDiff($time) > $allowed Then _Abort()
Until Not ProcessExists($pid)

; *** Paste Registration on the next line ***


; Exit if $startmenu = 0 from above.
If Not $startmenu Then Exit

; Remove shortcuts.
If _MainShortcut('Alcohol 120%.lnk') Then
    FileDelete('Alcohol Command Launcher.lnk')
    FileDelete('Alcohol Manual.lnk')
;~  FileDelete('Uninstall Alcohol 120%.lnk')
;~  _Desktop('Alcohol 120%.lnk')
EndIf

#endregion

Exit

Func _Install($path = Default)
    ; Run the installer in Default Script directory.
    Dim $splash
    If $path = Default Then $path = @ScriptDir
    If StringRight($path, 1) <> '\' Then $path &= '\'
    If StringInStr($executable, '\') Then $path = ''
    If Not FileExists($path & $executable) Then Exit 1
    If $splash Then _Splash('Installing:' & StringTrimRight(StringReplace(@ScriptName, '_', ' '), 4))
    If StringRight($executable, 3) = 'msi' Then
        Return Run('"' & @SystemDir & '\msiexec.exe" /i "' & $path & $executable & '"')
    Else
        Return Run('"' & $path & $executable & '"')
    EndIf
EndFunc

Func _Abort()
    ; close process if exists then exit.
    Dim $pid
    If ProcessExists($pid) Then
        ProcessClose($pid)
        Exit 2
    Else
        Exit 3
    EndIf
EndFunc

Func _Desktop($shortcut)
    ; Delete a Desktop shortcut.
    If FileExists(@DesktopDir & '\' & $shortcut) Then
        Return FileDelete(@DesktopDir & '\' & $shortcut)
    ElseIf FileExists(@DesktopCommonDir & '\' & $shortcut) Then
        Return FileDelete(@DesktopCommonDir & '\' & $shortcut)
    EndIf
EndFunc

Func _MainShortcut($shortcut, $rename = '')
    ; Change working directory to correct StartMenu\Group directory.
    Dim $group, $catagory, $splash
    If $group = '' Then Return 0
    If FileExists(@ProgramsDir & '\' & $group) Then
        FileChangeDir(@ProgramsDir & '\' & $group)
    ElseIf FileExists(@ProgramsCommonDir & '\' & $group) Then
        FileChangeDir(@ProgramsCommonDir & '\' & $group)
    Else
        Return 0
    EndIf
    ; Wait for main shortcut.
    If $splash Then _Splash('Waiting for shortcuts')
    For $i = 1 To 20
        If FileExists($shortcut) Then ExitLoop
        Sleep(500)
    Next
    If $splash Then _Splash('Cleaning up:' & StringTrimRight(StringReplace(@ScriptName, '_', ' '), 4))
    ; If catagory not assigned anything, then return.
    If $catagory = '' Then Return 1
    ; Move the group folder into the catagory folder.
    If FileChangeDir('..') And DirCopy($group, $catagory & '\' & $group, 1) Then
        If DirRemove($group, 1) Then
            ; If optional rename parameter is used, then rename the group folder.
            If $rename <> '' And FileChangeDir($catagory) Then
                If DirCopy($group, $rename, 1) And DirRemove($group, 1) Then
                    Return FileChangeDir($rename)
                EndIf
            Else
                Return FileChangeDir($catagory & '\' & $group)
            EndIf
        EndIf
    EndIf
EndFunc

Func _QuickLaunch($shortcut)
    ; Delete a Quicklaunch shortcut.
    Local $subdirs = '\Microsoft\Internet Explorer\Quick Launch'
    If FileExists(@AppDataDir & $subdirs & '\' & $shortcut) Then
        Return FileDelete(@AppDataDir & $subdirs & '\' & $shortcut)
    ElseIf FileExists(@AppDataCommonDir & $subdirs & '\' & $shortcut) Then
        Return FileDelete(@AppDataCommonDir & $subdirs & '\' & $shortcut)
    EndIf
EndFunc

Func _Splash($text = '')
    ; Shows a small borderless splash message.
    Dim $splash
    If $splash Then
        If $text Then
            SplashTextOn('', $text, 500, 25, -1, 5, 1, '', 14)
        Else
            SplashOff()
        EndIf
    EndIf
EndFunc

Func _WinClose($title, $text = '')
    ; Close a window with further attempts.
    For $i = 1 To 10
        WinClose($title, $text)
        If Not WinExists($title) Then Return 1
        Sleep(500)
    Next
EndFunc

Func OnAutoItStart()
    ; A 2nd script instance will exit.
    Local $interpreter
    $interpreter = StringTrimRight(@ScriptName, 4) & ' Script Interpreter'
    If WinExists($interpreter) Then Exit
    AutoItWinSetTitle($interpreter)
EndFunc

Отличия между Alcohol 120% и Alcohol 52%: "Имеется также бесплатный вариант программы - Alcohol 52%. Он отличается отсутствием возможности записи CD и DVD дисков и меньшим количеством виртуальных дисков"

Это сообщение посчитали полезным следующие участники:

AliEnder, CrOsP, Drinko, gen0m.rsw, hobbit25, ivsatel, kir100, LitOS, Morpheya, pan3o, Pozia, R@MZEZzz, semiono, Serega, Stalingrad, Studenka62, tupica, underr, valentin_vdovin

Отправлено: 14:30, 17-01-2008

jameszero

Модератор

Сообщения: 4920
Благодарности: 2580

Профиль | Сайт | Отправить PM | Цитировать

Ссылка на тему

[addon] SPTD

-------
RuntimePack официальный сайт
--
мои аддоны в облаке

Не было печали, апдейтов накачали.

Отправлено: 21:06, 27-02-2008 | #21

Для отключения данного рекламного блока вам необходимо зарегистрироваться или войти с учетной записью социальной сети.

Если же вы забыли свой пароль на форуме, то воспользуйтесь данной ссылкой для восстановления пароля.

hobbit25

Ветеран

Сообщения: 1199
Благодарности: 128

Профиль | Отправить PM | Цитировать

unikum111, а что и где нужно пдправить для 52% что б на раб столе значок был!!! заранее спасибо!

Отправлено: 17:49, 11-03-2008 | #22

unikum111

Старожил

Сообщения: 212
Благодарности: 33

Профиль | Отправить PM | Цитировать

Цитата hobbit25:

unikum111, а что и где нужно пдправить для 52% что б на раб столе значок был!!! заранее спасибо! »

Убрать из скрипта эту строчку:

Код:

send('{PGDN} {UP} {BS}')

Отправлено: 18:47, 11-03-2008 | #23

hobbit25

Ветеран

Сообщения: 1199
Благодарности: 128

Профиль | Отправить PM | Цитировать

unikum111,

;Отказываемся от установки ярлыка на рабочем столе и онлайн руководства
winwaitactive('Alcohol 52% FE Version 1.9.7.6221','Choose Components')
если убрать эту строчку --->send('{PGDN} {UP} {BS}') то онлайн руководство УСТанавливается или Нет и если устанавливается то как сделать чтоб не устанавливалось заранее спасибо!

P.S. нужен тока ярлык на раб столе!

Отправлено: 09:34, 12-03-2008 | #24

unikum111

Старожил

Сообщения: 212
Благодарности: 33

Профиль | Отправить PM | Цитировать

hobbit25, вроде так:
send('{PGDN} {UP} {BS} {DOWN}')

hobbit25, вроде так:

Код:

send('{PGDN} {UP} {BS} {DOWN}')

Отправлено: 18:52, 14-03-2008 | #25

sattva

Пользователь

Сообщения: 116
Благодарности: 12

Профиль | Отправить PM | Цитировать

Вложения

	Alcohol_120.7z
(3.9 Kb, 92 просмотров)

Alcohol120_retail_1.9.7.6221

P.S: Проверено все работает, но не надо заходить в меню "О программе"...

Это сообщение посчитали полезным следующие участники:

Stalingrad, unikum111

Отправлено: 12:46, 22-03-2008 | #26

unikum111

Старожил

Сообщения: 212
Благодарности: 33

Профиль | Отправить PM | Цитировать

sattva, не плохо, а что там в меню "О программе"?

Отправлено: 17:39, 22-03-2008 | #27

МИШАНЧИК

Ветеран

Сообщения: 989
Благодарности: 38

Профиль | Отправить PM | Цитировать

Подскажите пожалуйста, как сделать чтоб при первом запуске создавался виртуальный диск? Я в скрипте удалил строчки:
;Снимаем галочку с пункта "Add Alcohol Virtual Drive at first run."
ControlClick('Alcohol 120% 1.9.7.6221','Completing the Alcohol 120% Setup Wizard','Add Alcohol Virtual Drive at first run.')
Но ничего не изменилось. При первом запуске отображается только физический накопитель.

Отправлено: 12:06, 25-03-2008 | #28

unikum111

Старожил

Сообщения: 212
Благодарности: 33

Профиль | Отправить PM | Цитировать

МИШАНЧИК, по идее, вы всё делаете правильно. Попробуйте пройти весь путь инсталляции "вручную". Возможно, что вирутальный привод создаётся при первом запуске сразу после инсталляции, когда программу запускает сам инсталлятор, хотя я не уверен.

Отправлено: 13:25, 25-03-2008 | #29

serj88rus

Старожил

Сообщения: 193
Благодарности: 5

Профиль | Сайт | Отправить PM | Цитировать

Скажите, пожалуйста как в командном файле написать, чтобы в папку с Алгоголем копировался определенный файл. не получается никак

ECHO.
ECHO Installing Alcohol_120
ECHO Please wait...
start /wait %systemdrive%\install\Alcohol\setup.exe /qn
REGEDIT /S %systemdrive%\install\Alcohol\russian.reg

-------
По несчастью иль по счастью истина проста –
Никогда не возвращайся в прежние места.

Отправлено: 20:29, 25-03-2008 | #30