[Котяра]

Creat0R, спасибо за ответ. Деинсталлятор мой действительно простой, а то, что предложили Вы - это де инсталлятор как программа, а я говрю о Uninstall для какой-то конкретной программы.

[Котяра]

Вот так делаются Setup'ы:

Код:

$installpath = InputBox("Установка", "Введите путь установки.", @ProgramFilesDir & "\Example", "")
if $installpath = '' then Exit
if @error = 1 then Exit
DirCreate($installpath)
FileCopy(@ScriptDir & "\example.txt", $installpath & "\example.txt")
FileCopy(@ScriptDir & "\Uninst.exe", $installpath & "\Uninst.exe")
MsgBox(4160, "Установка", "Установка успешно завершена!")
; Write a single REG_SZ value
RegWrite("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\Example", "DisplayName", "REG_SZ", "Example v1.00")
RegWrite("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\Example", "UninstallString", "REG_SZ", $installpath & "\Uninst.exe")

А так Uninstall'ы:

Код:

$installpath = InputBox("Установка", "Введите путь установки.", @ProgramFilesDir & "\Example", "")
if $installpath = '' then Exit
if @error = 1 then Exit
DirCreate($installpath)
FileCopy(@ScriptDir & "\example.txt", $installpath & "\example.txt")
FileCopy(@ScriptDir & "\Uninst.exe", $installpath & "\Uninst.exe")
MsgBox(4160, "Установка", "Установка успешно завершена!")
; Write a single REG_SZ value
RegWrite("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\Example", "DisplayName", "REG_SZ", "Example v1.00")
RegWrite("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\Example", "UninstallString", "REG_SZ", $installpath & "\Uninst.exe")

Устанавливается и удаляется один файл. Минус один - не создаются ярлыки и после деинсталляции Uninst.exe остается лежать. Uninst.exe - это скомплированный деинсталлятор.

Давно искал инструмент типа AutoIt'а. Bat-файлы обладают малой функциональстью, малым средства для создания пользовательского интерфейса, VBS-скрипты сложны в освоений. AutoIt - классная вещь!

[Котяра]

При желании можно в Uninstall добавить проверку на установленность программы:

Код:

$installed = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\Example", "UninstallString")
if $installed = '' Then Exit

это в самое начало

[Котяра]

Creat0R, да, классный деинсталлятор. Замена всяким платным Best Uninstaller'ам и прочим.
Только одного смущает - нет кнопки для запуска изменения программы.

И самое главное, чем меня НЕ устроили батники: плохая поддержка русского языка

[Maza Faka]

Котяра

Замена всяким платным Best Uninstaller'ам »

Попробуй InnoSetup, очень удобный и простой в освоении, бесплатен.

[DNK_Inc]

Подскажите, пожалуйста , какими командами в AutoIt можно запустить окно свойств необходимого логического диска и эмулировать нажатие необходимых кнопок на активной вкладке? А также, как запустить из скрипта консольную команду control userpasswords2 ?

Всю справку облазил - по свойствам диска и по консольным командам вообще ничего не нашёл, а по поводу кнопки - в команде ControlClick в качестве параметров указываю текст заголовка окна, текст на кнопке, classnameNN (эти данные взял с помощью утилиты AutoIt Window Info), а команда либо не исполняется вообще, либо эмулирует нажатие кнопки из совершенно другой вкладки данного окна свойств . Из ситуации выхожу эмулированием нажатий клавиш и их комбинаций. Но, во-первых, скрипт из-за этого получается довольно-таки громоздким и тяжёлым для разбора, а во-вторых, не всегда работает (не всегда срабатывает команда Send при передвижении по объектам проводника).

[amel27]

Creat0R

Установленные секунды округляются до чётного числа »

нет, баг не в этом - для FAT четное число будет всегда, просто AutoIT округляет неправильно... вот цитата из MSDN:

Not all file systems can record creation and last access time and not all file systems record them in the same manner. For example, on NT FAT, create time has a resolution of 10 milliseconds, write time has a resolution of 2 seconds, and access time has a resolution of 1 day (really, the access date). On NTFS, access time has a resolution of 1 hour. Therefore, the GetFileTime function may not return the same file time information set using the SetFileTime function. Furthermore, FAT records times on disk in local time. However, NTFS records times on disk in UTC.

вот вариант UDF, который показывает заодно и причину округления:

Код:

$File = "s:\Test.txt"

$hOpenFile = FileOpen($File, 2)
FileWrite($hOpenFile, "Test")
FileClose($hOpenFile)

$SetTime = '20060322083528' ; - 2

_FileSetTime($File, $SetTime)
;FileSetTime($File, $SetTime)

$GetTime = FileGetTime($File, 0, 1)
MsgBox(0, "", StringFormat("Set Time: %s \nGet Time: %s", $SetTime, $GetTime))
FileDelete($File)

Func _FileSetTime($strFile, $strTime, $intType = 0)
    Local $iY=Number(StringLeft($strTime,4))
    Local $iM=Number(StringMid($strTime,5,2))
    Local $iD=Number(StringMid($strTime,7,2))
    Local $iH=Number(StringMid($strTime,9,2))
    Local $iN=Number(StringMid($strTime,11,2))
    Local $iS=Number(StringMid($strTime,13))
    ; DOS-формат для времени
    Local $iFatDate = BitShift($iY-1980,-9) + BitShift($iM,-5) + $iD
    Local $iFatTime = BitShift($iH,-11) + BitShift($iN,-5) + $iS/2 ; вот тут косячок в хранении секунд
    ; базовые структуры
    Local $FILETIME = DllStructCreate("dword;dword")
    Local $SYSTEMTIME = DllStructCreate("ushort;ushort;ushort;ushort;ushort;ushort;ushort;ushort")
    ; туда-сюда-обратно
    Local $ret = DllCall("kernel32.dll", "int", "DosDateTimeToFileTime", "ushort", $iFatDate, "ushort", $iFatTime, "ptr", DllStructGetPtr($FILETIME))
    If $ret[0] =0 Then Return SetError(1, 1, False)
    $ret = DllCall("kernel32.dll", "int", "FileTimeToSystemTime", "ptr", DllStructGetPtr($FILETIME), "ptr", DllStructGetPtr($SYSTEMTIME))
    If $ret[0] =0 Then Return SetError(1, 2, False)
    DllStructSetData($SYSTEMTIME,7,$iS) ; пытаемся откорректировать
    $ret = DllCall("kernel32.dll", "int", "SystemTimeToFileTime", "ptr", DllStructGetPtr($SYSTEMTIME), "ptr", DllStructGetPtr($FILETIME))
    If $ret[0] =0 Then Return SetError(1, 3, False)
    ; открываем файл
    $ret = DllCall("kernel32.dll", "int", "CreateFile", _
        "str", $strFile, "dword", 0x100, "dword", 0, "ptr", 0, "dword", 3, "dword", 0, "ptr", 0 )
    If $ret[0] =0 Then Return SetError(2, 1, False)
    ; правим время и закрываем файл
    Local $hFile=$ret[0], $aSysTime[3] = [0,0,0]
    $aSysTime[$intType]=DllStructGetPtr($FILETIME)
    $ret = DllCall("kernel32.dll", "int", "SetFileTime", "int", $hFile, "ptr", $aSysTime[1], "ptr", $aSysTime[2], "ptr", $aSysTime[0])
    DllCall("kernel32.dll", "int", "CloseHandle", "int", $hFile)
    If $ret[0] =0 Then Return SetError(2, 2, False)
    Return True
EndFunc

А на счёт печяти никто так и не знает решения? amel27, не подскажешь? »

может невнимательно читал, но ты про что?

[Dump]

Помогите пожалуйста.
Как в AutoIT можно написать скрипт, чтобы он выполнял такое действие: Если в папке C:\123 появились файлы, то нужно отправить сообщение пользователю через netsend. А в идеале было бы, чтобы по почте отправлялись сообщения. Почтовый сервер на exchange2003

[Creat0R]

amel27,

для FAT четное число будет всегда

Действительно, даже NirCmd не справляется.
Тогда у меня проблема намного серъёзнее чем я думал...

Дело в том, что мне нужно получать дату последнего изменения у файла в сети, и сравнивать её с датой изменения у файла на диске, если есть разница, то пытаться скачать файл (точнее юзер будет качать через диалог). После удачной закачки, я устанавливаю дату изменения файла на диске, чтобы при последующей проверки даты совпали. И получается что если дата файла в сети имеет не чётные секунды, то у меня всегда будет разница в данных

вот вариант UDF, который показывает заодно и причину округления:

Спасибо, для NTFS пригодится

ты про что?

Нужно напечатать файл-изображение, но при печати должен быть выведен диалог Мастера печати...

Но кажется я нашёл решение:

Код:

Run('Rundll32.exe "' & @SystemDir & '\mshtml.dll",PrintHTML "c:\image.png"', @SystemDir)

Правда пока негде потестить, дома у меня принтер не работает. Диалог то выводится, но печатает ли, вот это и нужно проверить.

DNK_Inc,

как запустить из скрипта консольную команду control userpasswords2 ?

Код:

Run(@ComSpec & ' /c control userpasswords2', '', @SW_HIDE)

Dump,

Если в папке C:\123 появились файлы, то нужно отправить сообщение пользователю через netsend

Код:

If FileExists("C:\123\*.*") Then Run(@ComSpec & ' /c net send {имя | * | /DOMAIN[:имя] | /USERS} сообщение', '', @SW_HIDE)

А в идеале было бы, чтобы по почте отправлялись сообщения.

Есть неплохой UDF: _INetSmtpMailCom.

[amel27]

Creat0R

если дата файла в сети имеет не чётные секунды, то у меня всегда будет разница в данных »

не понял в чем проблема?.. просто округляй секунды перед сравнением до четного числа

Нужно напечатать файл-изображение, но при печати должен быть выведен диалог Мастера печати...

можно и через Shell.Application:

Код:

_FileOpenPrint("D:\BUF\P1010376.JPG")

While 1
    Sleep (100)
WEnd

Func _FileOpenPrint ($sFilePath)
    Local $oShellApp = ObjCreate('shell.application')
    Local $sPath = StringRegExpReplace($sFilePath, "\\[^\\]+$", "")
    If @extended =0 Then $sPath = @WorkingDir
    Local $oPath = $oShellApp.Namespace ($sPath), $oItem
    For $oItem In $oPath.items
        If $oItem.Path = $sFilePath Then
            ConsoleWrite($oItem.Path &@CRLF)
            $oItem.InvokeVerb('&Печать')
        EndIf
    Next
EndFunc ; => _FileOpenPrint

; Эта UDF может быть полезна для просмотра поддерживаемых Verbs
Func _FileListVerbs($sFilePath)
    Local $oShellApp = ObjCreate('shell.application')
    Local $sPath = StringRegExpReplace($sFilePath, "\\[^\\]+$", "")
    If @extended =0 Then $sPath = @WorkingDir
    Local $oPath = $oShellApp.Namespace ($sPath), $oItem
    For $oItem In $oPath.items
        If $oItem.path = $sFilePath Then
            Local $oVerbs = $oItem.Verbs
            For $oVerb In $oVerbs
                ConsoleWrite($oVerb.Name &@CRLF)
            Next
        EndIf
    Next
EndFunc ; => _FileListVerbs