[Ramzes_]

Код:

Option Explicit
Dim WshShell,theNotepad,Res,Text,Title,RetCode
Set WshShell = WScript.CreateObject("WScript.Shell")

Text="Хранитель паролей"
Title="Установка"
Res=WshShell.Popup(Text,0,Title,vbOkCancel)

If (Res=vbOk) Then
  RetCode = WshShell.Run("""C:\Program Files\KeePass-1.08\KeePass.exe""", 1, vbTrue)
End If

Text="RegShot"
Title="Установка"
Res=WshShell.Popup(Text,0,Title,vbOkCancel)

If (Res=vbOk) Then
  RetCode = WshShell.Run("""C:\Program Files\regshot181_src_bin\regshot.exe""", 1, vbTrue)
End If

WScript.Sleep 100

Но я бы сделал так:

Код:

'------------------------
Option Explicit
'------------------------

Dim setup_dic
Set setup_dic = CreateObject("Scripting.Dictionary")

Call setup_dic.Add("Хранитель паролей", """C:\Program Files\KeePass-1.08\KeePass.exe""")
Call setup_dic.Add("RegShot", """C:\Program Files\regshot181_src_bin\regshot.exe""")

Dim prog, progs
progs = setup_dic.Keys

For Each prog In progs
  Call setup_prog(prog, setup_dic(prog))
Next

'------------------------
dim g_WshShell

Function setup_prog(prog_name, prog_path)
  If IsEmpty(g_WshShell) Then
    Set g_WshShell = WScript.CreateObject("WScript.Shell")
  End If 

  If (g_WshShell.Popup(prog_name,0,"Установка",vbOkCancel) = vbOk) Then
     Call g_WshShell.Run(prog_path, 1, vbTrue)
  End If
End Function

Таким образом усилия по добавлению новых программ сводятся к минимуму.

[skatet]

вообще спасибо! Но есть пару моментов - когда я нажмаю ок при первой программе, то после запука, недожидаясь завершения первой запускается 2ая.
2ое - не мог бы ты разъяснить чуток что описывается в скрипте?
Буду очень благодарен.

[Ramzes_]

Только что попробовал. Программы нормально запускаются по порядку, проверь скрипт.

По поводу скрипта.

Код:

Dim setup_dic
Set setup_dic = CreateObject("Scripting.Dictionary")

Call setup_dic.Add("Хранитель паролей", """C:\Program Files\KeePass-1.08\KeePass.exe""")
Call setup_dic.Add("RegShot", """C:\Program Files\regshot181_src_bin\regshot.exe""")

Scripting.Dictionary – объект, позволяющий хранить коллекцию данных в виде ключ-значение. Ключ должен быть уникальным. В качестве ключа здесь выступает название программы, в качестве значения – путь к ней. Сначала мы заполняем словарь известными программами.

Код:

Dim prog, progs
progs = setup_dic.Keys

Получаем массив, содержащий все значения ключей.

Код:

For Each prog In progs
  Call setup_prog(prog, setup_dic(prog))
Next

Теперь перебираем все значения ключей (имя программы), и для каждого значения вызываем функцию запуска, в которую передаем название программы, и путь ее запуска (значение словаря, соответствующее имени программы – setup_dic(prog))

[skatet]

отличный скрипт, так на самом деле станет еще проще перебирать все программы с помощью словаря!
Респект! Я еще с ним повожусь, потом поделюсь впечатлениеми подробнее.
Спасибо.