[Creat0R]

amel27,

если пусто, значит берется дефолтовый из HKLM\SOFTWARE\Classes\CLSID

У меня там кроме Мой компьютер везде пусто...

А по второму адресу - к примеру тут HKEY_LOCAL_MACHINE\SOFTWARE\Classes\CLSID\{645FF040-5081-101B-9F08-00AA002F954E} должно быть имя корзины, там так и написано Корзина (в “по умолчанию”), но у меня корзина именуется как Mycop - Вот тут то и проблема, список содержит именно Mycop (это латинские буквы кстати), в реестре я не нашёл это значение

[amel27]

Creat0R
ну не знаю ... у меня после переименования новое имя сразу появилось в HKCU, правда чтобы я смог переименовать корзину с рабочего стола мне пришлось применить соответствующий твик

[Creat0R]

amel27,
А «Мои документы» тоже нормально отображаются в реестре?
У меня их вообще нигде нету, даже не в оригинальном названии .

[Maza Faka]

Creat0R
Большое спасибо за пример, а если бы ты ещё нашёл время, что бы разжевать мне эту функцию:

Код:

Func InitializeCallBack($CallEvery, $FuncName="MyCallBackFunc")
    $pTimerProc = _DllCallBack($FuncName, "hwnd;uint;uint;dword")
    $uiTimer = DllCall("user32.dll", "uint", "SetTimer", "hwnd", 0, "uint", 0, "int", $CallEvery, "ptr", $pTimerProc)
    $uiTimer = $uiTimer[0]
EndFunc

то было бы вообще здорово! А то ведь простое использование знаний не даст.

[Creat0R]

Maza Faka,

разжевать мне эту функцию:

Там всё просто...
вызывается функция _DllCallBack, которая как бы регистрирует для процесса (скрипта) указанную функцию (через параметр $FuncName), и возвращает на неё указатель..
Далее просто по этому указателю вызывается таймер (строка с вызовом Dll) с заданым временем промежутка между повторами вызова (a.k.a AdibEnable ) - Всё, наша функция вызывается каждый заданный промежуток времени, пока не высвободить таймер (см. в функции Quit()).

---

Пример-Скрипт для предотвращения ввода не цифр в Input-поле:

Код:

#include <GuiConstants.au3>

Global Const $WM_COMMAND = 0x0111
Global $GUIOldPos[2]

$GUI = GUICreate("<Only Numbers> in Input Demo GUI", 300, 100)

$Input = GUICtrlCreateInput("", 20, 40, 260, 20)
$Exit = GUICtrlCreateButton("Exit", 20, 70, 60, 20)

GUISetState()
GUIRegisterMsg($WM_COMMAND, "MY_WM_COMMAND")

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE, $Exit
            ExitLoop
        Case Else
            CheckToolTip()
    EndSwitch
WEnd

Func CheckToolTip()
    Local $GetCurInfo = GUIGetCursorInfo($GUI)
    Local $GuiGetPos = WinGetPos($GUI)
    If $GetCurInfo[2] = 1 Or $GUIOldPos[0] <> $GuiGetPos[0] Or $GUIOldPos[1] <> $GuiGetPos[1] Then
        ToolTip("")
        $GUIOldPos = $GuiGetPos
    EndIf
EndFunc

Func _Input_Changed()
    ToolTip("")
    Local $ReadInput = GUICtrlRead($Input)
    If StringRegExp($ReadInput, '[^0-9]') Then
        GUICtrlSetData($Input, StringRegExpReplace($ReadInput, '[^0-9]', ''))

        Local $GuiGetPos = WinGetPos($GUI)
        Local $XPos = $GuiGetPos[0] + 280
        Local $YPos = $GuiGetPos[1] + 80

        ToolTip("Here only numbers are allowed", $XPos, $YPos, "Not allowed symbol", 3, 1)
        DllCall("user32.dll", "int", "MessageBeep", "int", 0x0)
    EndIf
EndFunc   ;==>_Input_Changed

Func MY_WM_COMMAND($hWnd, $msg, $wParam, $lParam)
    Local $nNotifyCode = BitShift($wParam, 16)
    Local $nID = BitAND($wParam, 0xFFFF)
    Local Const $EN_CHANGE = 0x300
    Local Const $EN_SETFOCUS = 0x100

    Switch $nID
        Case $Input
            Switch $nNotifyCode
                Case $EN_CHANGE
                    _Input_Changed()
                Case $EN_SETFOCUS
                    ToolTip("")
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>MY_WM_COMMAND

Многие используют стиль $ES_NUMBER, но он не перестраховывает от вставки текста по Ctrl V или с контексного меню.

[DenchikK]

Подскажите пожалуйста, что то я так и не нашёл - как можно настроить скрипт на выход из цикла по нажатию на определённую клавишу?

Вот как то так пытался, не выходит:

Код:

WinActivate ("µTorrent","")

Sleep (500)

Global $i

$i = 0

While $i <= 10 or Send ('{F2}') 
Sleep (1000)
Send ("{APPSKEY}")
Sleep (1000)
Send ("{UP}{UP}")
Sleep (1000)
Send ("{Enter}")
$i=$i+1
Sleep (1000)

WEnd

[amel27]

Creat0R,

А «Мои документы» тоже нормально отображаются в реестре? »

измененное имя в HKCU аналогично другим, дефолтового действительно нет но его можно взять из параметра Personal ключа "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders"

[Lodoss]

Привет всем.

По работе понадобилось конвертировать большое количество файлов из одного формата в другой.
Пакетного конвертера который бы выполнил мою задачу я ненашёл, поэтому пришлось изголяться непосредственно с приложением в котором есть такая возможность используя обычные команды меню и горячие клавиши (открывая последовательно сначала один файл: выполняя ряд действий, "импорт",..."экспорт" ;затем открывая второй файл и т. д....)


Проблему решил написав следующий скрипт

Код:

; выбор одного или нескольких файлов
$files = FileOpenDialog("Пакетное конвертирование файлов", "c:\", "любые файлы (*.*)", 1 + 4 ) & "|"
; если ничего не выбрано то выходим 
If @error Then
	TrayTip("пакетная обработка файлов", 'Выход', 5, 3)
	MsgBox(16,"Информация","Ничего не выбрано", 7)
	Exit
EndIf
$dir_in = StringMid($files,1, StringInStr($files, "\",0,-1))
$Chetchik=1
While $Chetchik<3
  $sch=StringInStr( $files,"|",0,$Chetchik)
  if $sch<>0 Then
	 	 $Chetchik=$Chetchik+1
   Else
	ExitLoop
   endif  
WEnd
; рисуем цикл для двух типов выделений
if $Chetchik>2  Then 
   ; группа файлов
   $i=1
  While StringLen($files)>$i 
  $dir_in = StringReplace(StringReplace(StringMid($files,1, StringInStr($files, "|",0,1)), "|", "\"), "\\", "\")
  $name=StringMid(StringMid($files,StringInStr ( $files,$dir_in)+2 ),StringInStr(StringMid($files,StringInStr ( $files,$dir_in)+2 ),"|",0,$i)+1,StringInStr( StringMid($files,StringInStr ( $files,$dir_in)+2 ),"|",0,$i+1) - StringInStr( StringMid($files,StringInStr ( $files,$dir_in)+2 ),"|",0,$i)-1)
if StringLen($name)>0 Then 
	     $i=$i+1 
		 prt_to_dwg($name)
	 Else
		 ExitLoop
	 endif 	 
   WEnd
Else ; один файл
   $name=StringTrimRight(StringMid($files,StringInStr($files,$dir_in)+StringLen($dir_in)),1)
   prt_to_dwg($name)
EndIf
; конец выполнения программы
TrayTip("пакетная обработка файлов", 'Конец', 5, 1)
 MsgBox(64, "Информация", "Все опрации завершены" )
  
; функция обработки файла  
Func prt_to_dwg($value)
     $value = $value
	 TrayTip("пакетная обработка", 'обработка файла "' & $value & '"', 10, 1)
; для примера откроем блокнот
Run("notepad")
WinWait("Безымянный")
WinActivate("Безымянный")
Send("^o")
WinWait("Открыть")
WinActivate("Открыть")
Sleep(100)
ControlSetText("Открыть", "", "Edit1", $dir_in & $value)
Sleep(5000)
WinClose("Открыть")
WinClose("Безымянный")
WinWaitClose("Безымянный")
EndFunc

Сейчас осенила мысль - неплохо бы написать к этому скрипту GUI
с прогресс баром, возможностью выбора входящих и исходящих папок до и после обработки + возможность
использовать включающий и исключающий фильтр в названиях обрабатываемых файлов.

Посему вопрос: не делал ли кто нибудь нечто похожее? Неохота изобретать велосипед

[Maza Faka]

DenchikK
Попробуй так:

Код:

Dim $i = 0

HotKeySet("{F2}", "Quit")

WinWait("µTorrent")
WinActivate ("µTorrent")

Sleep (500)

While $i <= 10
    Sleep (1000)
    Send ("{APPSKEY}")
    Sleep (1000)
    Send ("{UP}{UP}")
    Sleep (1000)
    Send ("{Enter}")
    $i += 1
    Sleep (1000)
WEnd

Func Quit()
    Exit
EndFunc

[Maza Faka]

Lodoss
Вот пример как это можно сделать, если нужен законченный скрипт, тогда выкладывай подробности