[VelDmi]

Из скрипта запускается консольный nerocmd.exe. Можно ли как то получить данные, показываемые в консоли для отображения их в GUI автоита?

[Creat0R]

TERMINAL

Как сделать чтобы скрипт дождался полного ввода серийника

Попробуй вместо ControlSetText прописать так:

Код:

ControlCommand("ACDSee 8 - InstallShield Wizard", "Customer Information", "Edit3", "EditPaste", $serial)

И ещё, заголовок окна, чувствителен к регистру, поставь в начало скрипта, такую строчку - Opt("WinTitleMatchMode", 4)

когда вылазит окно ММ закрыть его и повторить установку заново

Нужно всё поместить в цикл, и в конце проверять существование окна...

Код:

Opt("WinTitleMatchMode", 4)

While 1
Global $serial='12345-67890-12345-67890'
Run ( @ScriptDir & '\' & 'Setup.exe' )
WinWait("ACDSee 8 - InstallShield Wizard","ACDSee 8 can run with previous")
WinActivate("ACDSee 8 - InstallShield Wizard","ACDSee 8 can run with previous")
ControlClick("ACDSee 8 - InstallShield Wizard","ACDSee 8 can run with previous","Button1")
WinWait("ACDSee 8 - InstallShield Wizard","I &accept the terms in the lic")
WinActivate("ACDSee 8 - InstallShield Wizard","I &accept the terms in the lic")
ControlClick("ACDSee 8 - InstallShield Wizard","I &accept the terms in the lic","Button3")
ControlClick("ACDSee 8 - InstallShield Wizard","I &accept the terms in the lic","Button5")
WinWait("ACDSee 8 - InstallShield Wizard","&Organization:")
WinActivate("ACDSee 8 - InstallShield Wizard","&Organization:")
ControlClick("ACDSee 8 - InstallShield Wizard","&Organization:","RichEdit20W3")
ControlCommand("ACDSee 8 - InstallShield Wizard", "Customer Information", "Edit3", "EditPaste", $serial)
ControlClick("ACDSee 8 - InstallShield Wizard","&Organization:","Button8")
WinWait("ACDSee 8 - InstallShield Wizard","&Complete")
WinActivate("ACDSee 8 - InstallShield Wizard","&Complete")

WinWait("MM", "", 10) ; ждём 10 секунд окна с заголовком MM
If WinExists("MM", "") Then ContinueLoop
ExitLoop
Wend

VelDmi

Можно ли как то получить данные, показываемые в консоли

Попрубуй так:

Код:

$NerocmdTxt = WinGetText("Заголовок консоли", "")

[TERMINAL]

Creat0R

<Нужно всё поместить в цикл, и в конце проверять существование окна...>

А примерчик простенький можна?

[Creat0R]

TERMINAL

примерчик простенький можна?

Неужели не видно тот пример который я привёл в своём посте?

Цикл:

Код:

While 1
....
Wend

Это “заставит” скрипт “ходить” от While 1 до Wend, до тех пор, пока что то не заставит выйти из этого цикла...

Код:

While 1
ExitLoop ; Выход с цикла
Wend

И соответственно строим условие, при существовании которго, что то произойдёт (выход из цикла, или продолжение цикла)...

Код:

While 1
If WinExists("MM", "") Then ContinueLoop ;Если окно существует, то цикл начнётся заного, и скрипт моментально “продолжит” с начала цикла (While 1)
ExitLoop ;Выход из цикла (так как окно небыло найдено)
Wend

[amel27]

Creat0R

Имеется файл, а в нём много разного текста, и нужно перечитать весь текст, и проверить, не содержатся ли в нём дубликаты определённой переменной.

Обычным циклом устроит? Функция выводит сообщения (Select) и возвращает двумерный массив со счетчиком (номер строки и текст) , можно на выбор оставить что-нибудь одно:

Код:

#include <File.au3>

$dups = _TextInFile ("c:\test.txt", "Просто текст")

Func _TextInFile ($file, $text)
	Local $i, $txtLines, $res [1][2] = [[0,0]]
	Local $str='Строки, содержащие "' & $text & '":' & @CRLF & @CRLF
	_FileReadToArray ($file, $txtLines)
	If Not IsArray ($txtLines) Then
		MsgBox (16, 'Ошибка', 'Файл пуст')
	EndIf
	For $i=1 To $txtLines [0]
		If StringInStr ($txtLines [$i], $text) Then
			ReDim $res [$res [0][0]+2][2]
			$res [0][0] = $res [0][0] +1
			$res [$res [0][0]][0] = $i
			$res [$res [0][0]][1] = $txtLines [$i]
			$str = $str & $i & ':' & @TAB & $txtLines [$i] & @CRLF
		EndIf
	Next
	Select
		Case $res [0][0] =0
			MsgBox (16, 'Ошибка', 'Вхождений не обнаружено!')
		Case $res [0][0] =1
			MsgBox (64, 'Сообщение', 'Дублей нет')
		Case Else
			MsgBox (48, 'Предупреждение', $str)
	EndSelect
	Return $res
EndFunc

[amel27]

Lodoss

можно ли получить список всех учёток зарегестрированых на компе и обладающих администраторскими привелегиями?.

ну ты горазд задачки задавать... три дня колдовал на DllCall ... самое забавное, что на форуме AutoIt не нашел ни одного рабочего варианта... Зато теперь можно смело замахнуться на всю линейку NetApi32

Код:

;===============================================================================
; Использование:     _NetLocalGroupGetMembers ($s_Group, [$s_Computer, [, $i_ShowDomain [, $i_Filter]]])
; Параметры:         $s_Group - имя локальной группы;
;                    $s_Computer - DNS или NetBIOS имя компьютера, пустая строка или пропущенный
;                       параметр равнозначны локальному компьютеру;
;                    $i_ShowDomain - "1" включить имя домена, "0" не включать;
;                    $i_Filter - набор флагов, задающих фильтр отбираемых записей:
;                        1 - пользователи,
;                        2 - группы,
;                       16 - предопределенные (WellKnown) группы,
;                       32 - удаленные учетные записи,
;                      128 - неизвестный тип.
; Результат:         При успешном завершении возвращает 1-мерный массив учетных записей,
 ;                       1-й элемент массива (индекс 0) содержит количество записей.
;                    При неудаче 1-й элемент содержит "-1" и @error указывает код ошибки
;
;===============================================================================

Func _NetLocalGroupGetMembers ($sGroup, $sServer = "", $iShowDom = 1, $iFilter = 511)
    Local $res [1] = [0], $uPTR= DllStructCreate ("ptr")
    If $iShowDom Then
        $iShowDom=2
    Else
        $iShowDom=1
    EndIf
    Local $ret = DllCall ("netapi32.dll", "int", "NetLocalGroupGetMembers", _
        "wstr", $sServer, _
        "wstr", $sGroup, _
        "int", $iShowDom, _
        "ptr", DllStructGetPtr ($uPTR), _
        "int", -1, _
        "int_ptr", 0, _
        "int_ptr", 0, _
        "int_ptr", 0 )
    If $ret[0] Then
        SetError ($ret [0])
        $res[0] = -1
    Else
        If $ret[6]>0 Then
            Local $i, $string
            Local $uBUF = DllStructCreate ("ptr[" & $ret[6]*3 & "]", DllStructGetData ($uPTR,1) )
            For $i=3 To $ret[6]*3 Step 3
                If BitAnd (BitShift (1, 1 - DllStructGetData ($uBUF, 1, $i-1) ), $iFilter) Then
                    $ret = DllCall("kernel32.dll", "int", "WideCharToMultiByte", _
                        "int", 0, _
                        "int", 0, _
                        "ptr", DllStructGetData ($uBUF, 1, $i), _
                        "int", -1, _
                        "str", "", _
                        "int", 0, _
                        "int", 0, _
                        "int", 0 )
                    $string = DllStructCreate ("char[" & $ret[0] & "]")
                    $ret = DllCall("kernel32.dll", "int", "WideCharToMultiByte", _
                        "int", 0, _
                        "int", 0, _
                        "ptr", DllStructGetData ($uBUF, 1, $i), _
                        "int", $ret[0], _
                        "ptr", DllStructGetPtr ($string), _
                        "int", $ret[0], _
                        "int", 0, _
                        "int", 0 )
                    ReDim $res [$res[0]+2]
                    $res [0] = $res [0]+1
                    $res [$res[0]] = DllStructGetData ($string,1)
                EndIf
            Next
        EndIf
    EndIf
    DllCall ("netapi32.dll", "int" ,"NetApiBufferFree", _
        "ptr" , DllStructGetData ($uPTR,1) )
    Return $res
EndFunc

[TERMINAL]

Я наверное плохо объяснил...
Суть проблемки с циклами вот в чём-программа имеет сетап и патч. При установки сетапа всё происходит ОК, а при установке патча (если нет видео драйверов) выдаётся ошибка и прекращается установка.Потом опять запускаешь патч до тех пор пока он не начинает сам ставится (это бывает от 1 до 2 раз). Вот я и хочу объяснить скрипту что если ничего не вылезет то можно продолжать установку (а не так как у тебя-ВЫХОД), а если вылезет окно ошибки, то нужно закрыть его и опять устанавливат этот патч пока он не установится.

[Creat0R]

amel27

Функция выводит сообщения (Select) и возвращает двумерный массив со счетчиком (номер строки и текст)

Немного не так - Мне нужно чтобы вернулись в массив все номера строк, которые содержат дубляжи (именно дубляжи, без первой находки искомого слова), и желательно, чтобы в массиве эти номера строк, помещались через разделитель (допустим, через | ). В случае неудачи (или если вовсе не найденно вхождении), т.е если дубликатов нет, ненужно выводить сообщения, а просто в массив с нулём ($Array[0]) поместить содержание искомого слова (ну или вообще просто пустату "" - это нужно для проверки содержит ли массив номера строк, т.е дубляжи).

Просто дело в том, что задача у меня примерно такая:
-Проверить файл на дубликаты определённово слова (а точнее ссылки), если есть таковы, то просто удалить все дубликаты, оставив один-“оригинал” - Как удалять я знаю, имея номера строк, я могу восспользоваться функцией _FileWriteToLine...

Код:

#include <File.au3>

$Array = StringSplit("1|4|6|8", "|") ;Вместо цифр будет подставлен тот самый массив с номерами строк

For $i = 1 to $Array[0]
	_FileWriteToLine("File.txt", $Array[$i], "", 1)
Next

Но и тут есть проблема, после удаления строки под первым номером присутствующем в массиве, все остальные теряют своё значения, и удаляются уже не те строки (вернее по номеру это правильные строки, а по контексту нет) - Поэтому нужно как то удалять строки все одновременно, или на основе номеров строк, брать их содержание в другой массив, и уже потом удалять (вернее заменять) их основываясь на тексте - Но как это реализовать, я пока смутно себе представляю

---------------------------------

TERMINAL

У тебя в примере, нет упоминания о патче, но попробую привести нужны пример на основе воображения :

Код:

Opt("WinTitleMatchMode", 4)

Global $serial='12345-67890-12345-67890'
Run ( @ScriptDir & '\' & 'Setup.exe' )
WinWait("ACDSee 8 - InstallShield Wizard","ACDSee 8 can run with previous")
WinActivate("ACDSee 8 - InstallShield Wizard","ACDSee 8 can run with previous")
ControlClick("ACDSee 8 - InstallShield Wizard","ACDSee 8 can run with previous","Button1")
WinWait("ACDSee 8 - InstallShield Wizard","I &accept the terms in the lic")
WinActivate("ACDSee 8 - InstallShield Wizard","I &accept the terms in the lic")
ControlClick("ACDSee 8 - InstallShield Wizard","I &accept the terms in the lic","Button3")
ControlClick("ACDSee 8 - InstallShield Wizard","I &accept the terms in the lic","Button5")
WinWait("ACDSee 8 - InstallShield Wizard","&Organization:")
WinActivate("ACDSee 8 - InstallShield Wizard","&Organization:")
ControlClick("ACDSee 8 - InstallShield Wizard","&Organization:","RichEdit20W3")
ControlCommand("ACDSee 8 - InstallShield Wizard", "Customer Information", "Edit3", "EditPaste", $serial)
ControlClick("ACDSee 8 - InstallShield Wizard","&Organization:","Button8")
WinWait("ACDSee 8 - InstallShield Wizard","&Complete")
WinActivate("ACDSee 8 - InstallShield Wizard","&Complete")

While 1
Run( @ScriptDir & '\' & 'Path.exe' )

WinWait("MM", "", 10) ; ждём 10 секунд окна с заголовком MM

;В случае появления окна с заголовком “MM”, Закрываем его, и запускаем патч снова
If WinExists("MM", "") Then
WinClose("MM", "") 
ContinueLoop
EndIf
ExitLoop
Wend

[XXXler]

Нижеприведенная функция убивает все возможные окна от запущенного ей процесса и если какие-либо окна появлялись - перезапускает прогу заново (убиваются окна также дочерних процессов, просто одноименные окна\процессы не затрагиваются)

Код:

;~ Пример запускает+закрывает setup.exe:
RunKillWin(@SystemDir&"\setup.exe")

;~ Использование:
;~ RunKillWin("Путь и имя файла"[, таймаут ожидания завершения выполнения exe(сек)][,количество попыток "тихого" выполнения])
;~ Возвращает количесто выполненых попыток

Func RunKillWin($Exe,$MaxTimeOutForProcess=300,$MaxCountToReRun=10)
Local $i,$PID,$Timer,$WinArr,$y,$z=0

For $i=1 To $MaxCountToReRun

	;~ Корявая поверка необходимости перезапуска
	If $z=1 Then ExitLoop
	$z=1
	
	$PID=Run($Exe)
	;~ Запуск таймера таймаута выполнения
	$Timer=TimerInit()
		
	While ProcessExists($PID)

		;~ Сверка таймера
		If TimerDiff($Timer)>$MaxTimeOutForProcess*1000 Then
			ProcessClose($PID)
			If Not(ProcessWaitClose($PID,30)) Then Return -1
			$z=0
			ContinueLoop 2
		EndIf
		
		$WinArr=WinList()
		For $y=1 To $WinArr[0][0]
			If Not(WinGetProcess($WinArr[$y][1])=$PID) Then ContinueLoop
			;~ Собственно действие над окном\доп. проверку его титла можно поменять здесь
			WinKill($WinArr[$y][1])
			$z=0
		Next
		
	WEnd
	
Next
Return $i-1
EndFunc

[Sanja Alone]

TERMINAL

Как сделать чтобы скрипт дождался полного ввода серийника

Код:

$serial="серийник"
WinWait ("Заголовок", "Текст")
Do
	ControlSetText ( "Заголовок", "Текст", "Edit1", $serial )
Until ControlGetText ( "Заголовок", "Текст", "Edit1" )=$serial

Думаю, что идея ясна.