[coderman]

Если честно то некоторые здесь задолбали со своим Inno!!!
Вопрос остался открытым - скрипт для перепаковки Winamp нужен или софтина какая вытаскивающая сей скрипт из дистриба. Софта я пока такого не нашел. Есть идеи - пишите.

[boss911]

coderman

Если честно то некоторые здесь задолбали со своим Inno!!!

Долбают дятлы, Вы не туда попали, Вам в зоопарк! Выбирайте вырожение плиз, тут стараютса помочь, а некого-то "задолбать"!!

Вопрос... Возможно при автоматической установки выбирать компоненты? в NSIS...
Или как ниудь отредактировать ехе сделаный в nsis?

[unikum111]

Lesder2, нужна конкретная задача, какую программу, версию и т.д.

unikum111, Вот например Регет поменял свой инсталятор на NSIS... Теперь настройки его хранятся в ini файлах которые при запуске распаковываются... Я бы хотел как нибудь их изменить... Просто что менять я знаю... как распаковыть тоже ... А вот как редактить... ну или хотябы запаковать после распаковки... незнаю..

[Master of Magic]

Lesder2, расскажи

как распаковыть тоже

Чем NSIS инсталлятор можно распаковать? Желательно, что б сам скрипт тоже остался.

Собрал инсталлятор для Strong DC++ 2.11, прокомментировал и выложил скрипт сюда:

читать дальше »

Код:

;NSIS Modern User Interface version 1.70
;Example Script
;Written by Master of Magic

;--------------------------------
;Include Modern UI
  !include "MUI.nsh"
;--------------------------------
;Главная секция

  ;Название программы
  Name "Strong DC++ v.2.11"
  ; Заголовок которой будет отображаться при установки программы
  Caption "Strong DC++ v.2.11 DeepNet"
  ; Название файла который получится на выходе (после компиляции скрипта)
  OutFile "SDC.exe"
  
  ;Папка установки файлов по умолчания
  InstallDir "$PROGRAMFILES\StrongDC++"
  ;Требования к правам пользователя для установки данной программы
  RequestExecutionLevel user
  ; Устанавливаем компрессор lzma по умолчанию
  SetCompressor /FINAL lzma
 
  ;--------------------------------
;Установки интерфейса
  
  !define MUI_ABORTWARNING ; Вы действительно хотите прекратить установку данной программы
  !define MUI_ICON "C:\Documents and Settings\Администратор\Рабочий стол\HubikStrongDC\StrongDC\modern-install-colorful.ico" ; Иконка для собранного инсталлятора
  !define MUI_UNICON "C:\Documents and Settings\Администратор\Рабочий стол\HubikStrongDC\StrongDC\modern-uninstall-colorful.ico" ; Иконка для деинсталлятора
  !define MUI_FINISHPAGE_NOAUTOCLOSE ; Последняя страница установщика не закрывается автоматически
  !define MUI_FINISHPAGE_RUN ; Запускает последнюю страницу установщика
  !define MUI_FINISHPAGE_RUN_CHECKED ; Ставит флажок в положение Вкл по умолчанию
  !define MUI_FINISHPAGE_RUN_TEXT "Запустить программу" ; Надпись рядом с флажком
  !define MUI_FINISHPAGE_RUN_FUNCTION "LaunchLink" ; Запускаем функцию под именем LaunchLink

;--------------------------------
;Станицы

  !insertmacro MUI_PAGE_LICENSE "data\License.txt" ; Вставляем файл с лицензией
  !insertmacro MUI_PAGE_COMPONENTS
  !insertmacro MUI_PAGE_DIRECTORY
  !insertmacro MUI_PAGE_INSTFILES
  !insertmacro MUI_PAGE_FINISH ; Вставляет в ваш инсталлятор страницу завершения установки (функциональность управляется в Установках интерфейса см.Выше)

  !insertmacro MUI_UNPAGE_CONFIRM
  !insertmacro MUI_UNPAGE_INSTFILES
  !insertmacro MUI_UNPAGE_FINISH ; Вставляет в ваш инсталлятор страницу завершение деинсталляции (перезагрузить систему и т.д.)
  ;--------------------------------
;Язык
 
  !insertmacro MUI_LANGUAGE "Russian"

;--------------------------------
;Секция установки

Section "Strong DC++" SecMainProgram

  SectionIn RO
  
  ; Устанавливаем путь для копирования файлов
  SetOutPath $INSTDIR
  
  ; Сюда записываем файлы

File data\changelog-dc.txt
File data\changelog-en.txt
File data\changelog.txt
File data\dcppboot.xml
File data\License.txt
File data\russian.xml
File data\StrongDC.exe
File data\unicows.dll
File data\home.url

; Поскольку папок много приходится менять путь установки

SetOutPath $INSTDIR\EmoPacks

File data\EmoPacks\Kolobok.xml

SetOutPath $INSTDIR\EmoPacks\Kolobok

File /r data\EmoPacks\Kolobok\*.* ; Копируем все файлы в этой папке, /r - означает что копируем полностью все файлы в этой папке

SetOutPath $INSTDIR\Settings

File /r data\Settings\*.*

SetOutPath $INSTDIR\Settings\Certificates

File /r data\Settings\Certificates\*.*

SetOutPath $INSTDIR\Settings\HubLists

File /r data\Settings\HubLists\*.*
  SetOverwrite on
  SetOutPath $INSTDIR

writeuninstaller "$INSTDIR\uninstall.exe" ; Создаем файл деинсталляции в папке Program Files\StrongDC++, при компиляции скрипта uninstall.exe создается сам

   SectionEnd
;--------------------------------
; Вызов этой функции прописан в Установке интерфейса, если влажок вкл. функция запускает exe файл.
Function LaunchLink
  ExecShell "" "$INSTDIR\StrongDC.exe"
FunctionEnd


;--------------------------------

; Пользователь сам выбирает, какие ярлыки ему нужны, по умолчанию все включено
Section "Ярлык в меню Пуск" MenuProgramsShortcut

  CreateDirectory "$SMPROGRAMS\StrongDC++"
  CreateShortCut "$SMPROGRAMS\StrongDC++\Strong DC++ DeepNet.lnk" "$INSTDIR\StrongDC.exe" "" "$INSTDIR\StrongDC.exe" 0
  CreateShortCut "$SMPROGRAMS\StrongDC++\Наш сайт.lnk" "$INSTDIR\home.url" ""
  CreateShortCut "$SMPROGRAMS\StrongDC++\Удаление.lnk" "$INSTDIR\uninstall.exe" ""
  
SectionEnd
;--------------------------------

Section "Ярлык на рабочем столе" SecDesctopShortcut

  CreateShortCut "$DESKTOP\Strong DC++ DeepNet.lnk" "$INSTDIR\StrongDC.exe" "" "$INSTDIR\StrongDC.exe" 0
  
SectionEnd
;--------------------------------
;
Section "Ярлык в панели быстрого запуска" SecQlaunchShortcut

  CreateShortCut "$QUICKLAUNCH\Strong DC++ DeepNet.lnk" "$INSTDIR\StrongDC.exe" "" "$INSTDIR\StrongDC.exe" 0
  
SectionEnd
;--------------------------------
;
Section "Добавить программу в автозапуск" SecArlaunchShortcut

  CreateShortCut "$SMSTARTUP\Strong DC++ DeepNet.lnk" "$INSTDIR\StrongDC.exe" "" "$INSTDIR\StrongDC.exe" 0
  SectionEnd
;--------------------------------
; Деинсталляция
; Функция подтверждающая желание пользователя удалить приложение
Function un.onInit 
  MessageBox MB_ICONQUESTION|MB_YESNO|MB_DEFBUTTON2 "Вы уверены в том, что желаете удалить $(^Name) и все компоненты программы?" IDYES +2 
  Abort 
FunctionEnd 

Section "Uninstall"

SetOutPath $INSTDIR

KillProcDLL::KillProc "StrongDC.exe" ; Перед тем как удалить программу необходимо завршить пработу программы, непосредственно NSIS не имеет средств для этого придется качать Plug-In отсюда 
Sleep 700 ; Делаем паузу потому, что программа убивается не сразу

; Удаляем ярлыки RmDir /r - удаляем директорию со всем её содержимым
  RmDir /r "$SMPROGRAMS\StrongDC++"  
  Delete "$QUICKLAUNCH\Strong DC++ DeepNet.lnk"
  Delete "$SMSTARTUP\Strong DC++ DeepNet.lnk"
  Delete "$DESKTOP\Strong DC++ DeepNet.lnk"
  Delete "$SMPROGRAMS\StrongDC++\Uninstall.lnk"
; Удаление программы

Delete "changelog-dc.txt"
Delete "changelog-en.txt"
Delete "changelog.txt"
Delete "dcppboot.xml"
Delete "License.txt"
Delete "russian.xml"
Delete "StrongDC.exe"
Delete "unicows.dll"
Delete "home.url"
RmDir /r "$INSTDIR\Settings"
RmDir /r "$INSTDIR\EmoPacks"
RmDir /r "$INSTDIR\Logs"

Delete "Uninstall.exe" ; удаляем сам файл деинсталяции
RmDir /rebootok "$INSTDIR" ; Директория удаляется только после перезагрузки компьютера, без перезагрузки удалить папку не получилось, толи глюк инсталлятора, то ли у меня руки кривые

SetAutoClose true ; Автозакрытие окна после завершения деинсталляции

SectionEnd

;--------------------------------
;Descriptions

  ;Language strings
  ;LangString DESC_SecDummy ${LANG_ENGLISH} "Ярлык на рабочем столе"

  ;Здесь находится описание ярлыков
  !insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
    !insertmacro MUI_DESCRIPTION_TEXT ${SecMainProgram} "Программа для общения и обмена файлами в сети"
    !insertmacro MUI_DESCRIPTION_TEXT ${MenuProgramsShortcut} "Создать ярлык в меню Пуск"
    !insertmacro MUI_DESCRIPTION_TEXT ${SecDesctopShortcut} "Создать ярлык на рабочем столе"
    !insertmacro MUI_DESCRIPTION_TEXT ${SecQlaunchShortcut} "Создать ярлык в панели быстрого запуска"
    !insertmacro MUI_DESCRIPTION_TEXT ${SecArlaunchShortcut} "Добавить программу в автозапуск"
  !insertmacro MUI_FUNCTION_DESCRIPTION_END

;--------------------------------

Master of Magic
7zip\м расспаковывается )))
Но скрипта нету =(

[Master of Magic]

7zip и плагином в тотал командаре, это я и сам знаю, скриптик нужен...
Кстати, что 7zip, что плагин в Total-е только частично поддерживают распаковку NSIS

[simplix]

Master of Magic, Следующий код:

Код:

File data\changelog-dc.txt
File data\changelog-en.txt
File data\changelog.txt
File data\dcppboot.xml
File data\License.txt
File data\russian.xml
File data\StrongDC.exe
File data\unicows.dll
File data\home.url

; Поскольку папок много приходится менять путь установки

SetOutPath $INSTDIR\EmoPacks

File data\EmoPacks\Kolobok.xml

SetOutPath $INSTDIR\EmoPacks\Kolobok

File /r data\EmoPacks\Kolobok\*.* ; Копируем все файлы в этой папке, /r - означает что копируем полностью все файлы в этой папке

SetOutPath $INSTDIR\Settings

File /r data\Settings\*.*

SetOutPath $INSTDIR\Settings\Certificates

File /r data\Settings\Certificates\*.*

SetOutPath $INSTDIR\Settings\HubLists

File /r data\Settings\HubLists\*.*

Можно заменить так:

Код:

File /r "data\*.*"

[Master of Magic]

В принципе монжо и так