[Iska]

Попробуйте, например, так:

Код:

@echo off
setlocal

for /f "usebackq delims=" %%i in (
    `@"%systemroot%\system32\mshta.exe" "javascript:try {new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(1).Write(new String(new Enumerator(new ActiveXObject('WbemScripting.SWbemLocator').ConnectServer('.', 'root\\cimv2').ExecQuery('SELECT LocalDateTime FROM Win32_OperatingSystem WHERE Primary = True')).item().LocalDateTime).substr(6, 2))}; catch (e){}; close();" ^
    1^|more`
) do set sDay=%%i

if defined sDay if %sDay% equ 15 (
	echo Something to do...
) else (
	echo Something other...
)

endlocal
exit /b 0

[megaloman]

Код:

@Echo Off
cls
	FOR /F "tokens=2 delims==." %%d in ('WMIC OS GET LOCALDATETIME /VALUE') DO Set "Now=%%d"
	Set /A Day=1%Now:~6,2%-100
	If %Day% EQU 15 Call :DayYes
	If Not %Day% EQU 15 Call :DayNo
Pause
Exit /B

:DayYes
	Echo DayYes
Exit /B

:DayNo
	Echo DayNo
Exit /B

[Solitude]

Спасибо ! то, что надо

[alpap]

Код:

@echo off
for /f %%a in ('powershell "Get-Date -f 'dd'"') do if %%a==15 (call :#%%a) else (call :#No15)
pause& exit

:#15
 echo 15
exit /b

:#No15
 echo No15
exit /b

[DJ Mogarych]

Код:

powershell -command "if ((get-date).Day -eq 15) {echo '15th'} else {echo 'not 15th'}"