[alpap]

Код:

>"Текстовый файл.txt" echo Произвольное количество каких-то там [1,2,5,$,#], знаков

не все знаки удастся вывести таким образом

вопрос при запуске - "введите количество символов" »

set /p /?

[megaloman]

4zz,

не все знаки удастся вывести таким образом »

Плюс

количество символов в батник (допустим 592283), »

такую длинную строку в CMD обработать не удастся.
Поэтому, сакраментальный вопрос: зачем это нужно и почему CMD, а не, допустим, vbs?
Какие символы при этом допустимы?

[yurfed]

megaloman, не силён в написании скриптов, но рандомный вариант может быть использован, отключив неиспользуемые символы.
Только я не представляю зачем это нужно
Очередной BALON?

[megaloman]

4zz,

Вот вариант с клавиатурным набором знаков. Некоторые знаки валили скрипт, я их перечислил и не употребляю.
Не берусь судить, может еще какая-то зюкочка нагадит.

Код:

@Echo Off
cls
	Set "Out=Z:\Box_Out\полная фигня.txt"
	Set /A Max=8765

rem не использовать ^%&|<>"()'=
	Set "Symb=~!#$*_+1234567890-QWERTYUIOP{}qwertyuiop[]ASDFGHJKL:asdfghjkl;\ZXCVBNM?zxcvbnm,./ Ё№ЙЦУКЕНГШЩЗХЪФЫВАПРОЛДЖЭЯЧСМИТЬБЮёйцукенгшщзхъфывапролджэячсмитьбю"
	
	Set /A NS=-1 &FOR /L %%i IN (0,1,255) DO (Call :Substr %%i "S" &&Set /A NS+=1)

	Set "Str="
	Set /A N=0
	Set /A M=0

	Set /A Quant=4000
	2>nul Del "%Out%"
	:Begin
		Set /A N+=1
		Set /A M+=1
		Set /A K=(%NS%+1)*%Random%/32768
		Call :Substr %K% "S"
		Set "Str=%Str%%S%"
		If %N% EQU %Quant% (
			Echo DownLoad %M%
			<Nul Set /P "S=%Str%">>"%Out%"

			Set "Str="
			Set "S="
			Set /A N=0
		)
	If %M% NEQ %Max% GoTo :Begin
	If %N% NEQ 0 <Nul (Echo DownLoad %M% &Set /P S=%Str%>>"%Out%")
Pause
GoTo :Eof

:Substr
	Call Set "@S=%%Symb:~%1,1%%"
	Set "%~2=%@S%"
	If "%@S%"=="" Exit /B 1
Exit /B 0

Длина файла скриптом не ограничивается, весь вопрос - а сколько времени займёт, допустим, генерирование и запись строки из нескольких сот тысяч символов.

[megaloman]

Минимум изменений, но экономия по времени 20-25%.
Отличие - в способе извлечения символа из набора

Код:

@Echo Off
cls
	Set "Out=Z:\Box_Out\полная фигня.txt"
	Set /A Max=8765

rem не использовать ^%&|<>"()'=
	Set "Symb=~!#$*_+1234567890-QWERTYUIOP{}qwertyuiop[]ASDFGHJKL:asdfghjkl;\ZXCVBNM?zxcvbnm,./ Ё№ЙЦУКЕНГШЩЗХЪФЫВАПРОЛДЖЭЯЧСМИТЬБЮёйцукенгшщзхъфывапролджэячсмитьбю"
	
	Set /A NS=-1 &FOR /L %%i IN (0,1,255) DO (Call :Substr %%i "S" &&(Set /A NS+=1 &Call Set "@@@%%NS%%=%%S%%"))

	Set "Str="
	Set /A N=0
	Set /A M=0

	Set /A Quant=4000
	2>nul Del "%Out%"
	:Begin
		Set /A N+=1
		Set /A M+=1
		Set /A K=(%NS%+1)*%Random%/32768
		Call Set "Str=%Str%%%@@@%K%%%"
		If %N% EQU %Quant% (
			Echo DownLoad %M%
			<Nul Set /P "S=%Str%">>"%Out%"

			Set "Str="
			Set "S="
			Set /A N=0
		)
	If %M% NEQ %Max% GoTo :Begin
	If %N% NEQ 0 <Nul (Echo DownLoad %M% &Set /P S=%Str%>>"%Out%")
Pause
GoTo :Eof

:Substr
	Call Set "@S=%%Symb:~%1,1%%"
	Set "%~2=%@S%"
	If "%@S%"=="" Exit /B 1
Exit /B 0

В обоих кодах запись в файл ведётся квантами. Почему-то считал, чем больше квант, тем быстрее работа скрипта. Оказалось, не так однозначно. Буферизация? Но, в любом случае, генерация случайного набора занимает много больше времени.

[4zz]

megaloman,
Спасибо!
Все работает!))
Это нужно для файла в котором должно быть определенное количество символов, в разное время)

[Iska]

Буферизация? »

Скорее всего.

[4zz]

Работает, но очень долго..(
А может это можно ускорить копированием -вставкой?
Или из готового текстового файла посчитать количество символов и оставить необходимое, остальное удалить?

[Iska]

4zz, а может Вы подумаете про переход на WSH/PoSH вместо пакетных файлов?