VBS/WSH/JS - [решено] переименовать файл

Iska · Отправлено: **06:28, 10-01-2019** | #2

Цитата kuzmakzrezv1:

переименовать файл имя из буфера обмена »

Скрытый текст

Код:

Option Explicit

Dim strClipboardContent
Dim strSourceFile
Dim strDestFile


With WScript.CreateObject("Scripting.FileSystemObject")
	strClipboardContent = Trim(WScript.CreateObject("htmlfile").parentWindow.clipboardData.getData("text"))
	strSourceFile       = .GetAbsolutePathName(strClipboardContent)
	
	If .FileExists(strSourceFile) Then
		strDestFile = Trim(InputBox("Enter new file name", "Enter new file name", strSourceFile))
		
		If Len(strDestFile) > 0 Then
			If Not StrComp(strSourceFile, strDestFile, vbTextCompare) = 0 Then
				.MoveFile strSourceFile, strDestFile
			Else
				WScript.Echo "Need new name of file."
				WScript.Quit 3
			End If
		Else
			WScript.Echo "User cancel input."
			WScript.Quit 2
		End If
	Else
		WScript.Echo "Can't determine Clipboard content [" & strClipboardContent & "] as correct name of existing file."
		WScript.Quit 1
	End If
End With

WScript.Quit 0

Цитата kuzmakzrezv1:

создать текстовый файл(txt) имя из буфера обмена »

Скрытый текст

Код:

Option Explicit

Dim strClipboardContent
Dim strSourceFile


With WScript.CreateObject("Scripting.FileSystemObject")
	strClipboardContent = Trim(WScript.CreateObject("htmlfile").parentWindow.clipboardData.getData("text"))
	
	If StrComp(.GetExtensionName(strClipboardContent), "txt", vbTextCompare) = 0 Then
		strSourceFile = .GetAbsolutePathName(strClipboardContent)
	Else
		strSourceFile = .GetAbsolutePathName(strClipboardContent & ".txt")
	End If
	
	If Not .FileExists(strSourceFile) Then
		With .CreateTextFile(strSourceFile)
			.Close
		End With
	Else
		WScript.Echo "Source file [" & strSourceFile & "] already exists."
		WScript.Quit 1
	End If
End With

WScript.Quit 0

Корректность имён особо не проверяется.

kuzmakzrezv1 · Отправлено: **09:37, 10-01-2019** | #3

Спасибо Iska!

- создать текстовый файл - отлично работает,
- переименование пишет: "Can't determine Clipboard content [mainname] as correct name of existing file."

Iska · Отправлено: **12:53, 10-01-2019** | #4

Цитата kuzmakzrezv1:

переименование пишет: "Can't determine Clipboard content [mainname] as correct name of existing file." »

kuzmakzrezv1, покажите скриншот, на котором будет видно, что в текущем для скрипта каталоге наличествует файл с именем «mainname».

kuzmakzrezv1 · Отправлено: **14:07, 10-01-2019** | #5

Iska
я бью из контенстного меню - переименовать папку 1, с mainname в буфере:

Iska · Отправлено: **18:07, 10-01-2019** | #6

Цитата kuzmakzrezv1:

я бью из контенстного меню - переименовать папку 1, с mainname в буфере: »

Вот. Начинают всплывать занятные подробности, о которых ни слова не было в техзадании.

В какой раздел реестра и как именно Вы добавляете скрипт в контекстное меню. Показывайте и рассказывайте. Только показывайте не на Радикале. Есть нормальные хостинги для изображений. Я пользую Imgur.

kuzmakzrezv1 · Отправлено: **19:01, 10-01-2019** | #7

реестр:

HKEY_CLASSES_ROOT\*\shell\newname
HKEY_CLASSES_ROOT\*\shell\newname\command
значение
C:\Users\Valerio\Favorites\script\newname.bat

HKEY_CLASSES_ROOT\Directory\shell\newname
HKEY_CLASSES_ROOT\Directory\shell\newname\command
значение
C:\Users\Valerio\Favorites\script\newname.bat

батник:
@echo off
start /w wscript.exe "C:\Users\Valerio\Favorites\script\newname.vbs"

батник и скрипт лежат:
C:\Users\Valerio\Favorites\script\

kuzmakzrezv1 · Отправлено: **19:17, 10-01-2019** | #8

Iska · Отправлено: **19:50, 10-01-2019** | #9

kuzmakzrezv1, я про скрипт для переименования.

Впрочем, скажу и про NewName. Исключите пакетный файл совсем, он здесь лишний. Используйте просто «wscript.exe "C:\Users\Valerio\Favorites\script\newname.vbs"».

kuzmakzrezv1 · Отправлено: **19:59, 10-01-2019** | #10

Iska,
NewName - у меня переименование

Цитата Iska:

Используйте просто «wscript.exe "C:\Users\Valerio\Favorites\script\newname.vbs"». »

-понял, спасибо