[Anidzuka]

запускать рядом с SADXModLoader.ini или указать полный путь к нему в строках 3 и 14, если есть пробелы взять путь в парные кавычки. »

ни как не хочет

[megaloman]

можно еще как то сделать такое, что бы из ini файла удалялась строка или строки с определённым значением , потом заново нумеровало параметры чтобы не было пропусков

Код:

@Echo Off
	Set "FileIni=Z:\Soft_In\SADXModLoader.ini"
	Set "Key=Mod"
	Set "Val="Perfect Chaos Music Swap" "sadx-frame-limit" "EggCarrierOceanMusic""

	Set /A M=0
	Move /Y "%FileIni%" "%FileIni%.bak" >nul
	>"%FileIni%" (FOR /F "usebackq tokens=1* delims==" %%i IN ("%FileIni%.bak") DO Set "S=%%i" &Call :OutAll "%%i" "%%j" %%S:%Key%=%%)
GoTo :Eof

:OutAll
	Set /A N=0
	Set /A N=%3 2>nul
	If %N% GTR 0 If %1=="%Key%%N%"  Call :Out1 %2 &GoTo :Eof
	(Echo %~1=%~2)
GoTo :Eof

:Out1
	Set "Value=%~1"
	For %%a IN (%Val%) DO Call Set "Value=%%Value:%%~a=%%"
	If Not %1=="%Value%" GoTo :Eof
	Set /A M+=1
	(Echo %Key%%M%=%~1)
GoTo :Eof

Список строк со значением параметров, которые надо убить, в переменной Val

вытянуть значения разрешения экрана дисплея 1 и сохранить их в ini файл последними строками в виде HorizontalResolution=2560 VerticalResolution=1080 »

В представленном образце ini-файла эти строки первые. Или это другой ini-файл? Или надо убить эти строки и записать новые в конец?

Если тупо записать в конец

Код:

@Echo Off
	Set "FileRes=Z:\Soft_In\Res.txt"
	Set "FileIni=Z:\Soft_In\SADXModLoader.ini"
	Set "Res=Settings"

	>>"%FileIni%" (FOR /F "usebackq tokens=1,2,3 delims=:x " %%i IN ("%FileRes%") DO If "%%i"=="%Res%" (
		(Echo HorizontalResolution=%%j) 
		(Echo VerticalResolution=%%k)
		GoTo :Continue
	))
	:Continue
GoTo :Eof

[Anidzuka]

вероятно ваши изменения в ini затрагивают его кодировку, ну никак изменение чередования строк не должны влиять на работоспособность, только изменения в строках ну и их добавление или отсутствие. Интересно бы проверить, но это же все также надо поустанавливать. »

да нет дела как раз в том что если удалить строку то не будет ключа 18,20 видит что нет параметра 19 но есть 20 , всё ошибка, если просто убрать значение тоже ошибка и оставить "mod**=" ошибка , вот и получается что после удаление нужно заново пронумировать Mod**

[alpap]

а так все-таки?

Код:

@echo off
set "f=Диск:\Папка\SADXModLoader.ini"
set "H=HorizontalResolution"
set "V=VerticalResolution"

for /f "delims=" %%a in ('wmic path "win32_desktopmonitor" get ScreenHeight^,ScreenWidth /value^|find "="') do set "%%a"
<"%f%">$ (for /f "delims=" %%a in ('more') do @(
  echo %%a|>nul find "%H%" && echo %H%=%ScreenWidth%
  echo %%a|>nul find "%V%" && echo %V%=%ScreenHeight%
  echo %%a|>nul findstr /v /c:"%H%" /c:"%V%" && echo %%a
 )
)& >nul move $ "%f%"
pause

Здесь путь настоящий укажите: set "f=Диск:\Папка\SADXModLoader.ini"

[Anidzuka]

В представленном образце ini-файла эти строки первые. Или это другой ini-файл? Или надо убить эти строки и записать новые в конец? »

файл тот, просто этих строк изначально не будет ))) просто супер , все как часики работает )))) Хорошо когда мозги в голове есть всё так красиво и просто сделано , красота а не работа ))) Спасибо)))

а так все-таки? »

ошибки нет, но и текста тоже, а он с 64x работает?

[alpap]

и еще я никак не пойму, если было
Mod16=smooth-cam
Mod17=SoundOverhaul
Mod18=SteamAchievements
Mod19=super-sonic
Mod20=DLCs

и станет с изменением по порядку
Mod16=smooth-cam
Mod17=SoundOverhaul
Mod18=super-sonic
Mod19=DLCs

то сразу видно что теперь
значение 'super-sonic' уже имеет Mod18 а не Mod19
и далее все аналогично сбивается (смещается), а это уже точно неправильно, не?

[Anidzuka]

и еще я никак не пойму, если было »

под каким номером значение вписке приложению без разницы ) а вот отсутствия номера уже ошибка

Спасибо, узнал столько нового, вы все просто СУПЕРРРРРР

[Anidzuka]

megaloman, только что понял что значения и обратно нужно будет вставить ((( дико извиняюсь, а можно точно такой же как и с удалением , но только добавление параметра мод с определённым значением ? если возможно сделать так чтобы добавление происходило только если данного значения нет ( простите((

[alpap]

но и текста тоже »

какого... текста вы ждете. Изменения сразу (записываются) происходят в ini, вероятно у вас в искомых строках как раз и записаны ваши дефолтные размеры и не видно изменений. Попробуйте самостоятельно изменить значения на что угодно, а потом запустить код и размеры станут в нужных строках этой машины.

[megaloman]

добавление параметра мод с определённым значением так чтобы добавление происходило только если данного значения нет

Код:

@Echo Off
cls
	Set "FileIni=Z:\Soft_In\SADXModLoader.ini"
	Set "Key=Mod"
	Set "Add="Во поле" "Perfect Chaos Music Swap" "Люли люли" "sadx-frame-limit" "Берёзонька стояла" "EggCarrierOceanMusic""

	Set /A N=1000
	Set "Pref=A"
	FOR /F "usebackq tokens=1* delims==" %%i IN ("%FileIni%") DO Call :In "%%i" "%%j"

	Set /A N=1000
	FOR %%i IN (%Add%) DO Set /A N+=1 &Call Set "Z@@%%N%%=%%~i"

	FOR /F "usebackq tokens=3 delims==" %%i IN (`Set "B@@"`) DO (
		FOR /F "usebackq tokens=1,2 delims==" %%a IN (`Set "Z@@"`) DO If /I "%%~i"=="%%~b" Set "%%~a="
	)

	Set /A N=9000
	FOR /F "usebackq tokens=1,2 delims==" %%a IN (`Set "Z@@"`) DO Set /A N+=1 &Call Set "B@@%%N%%=%Key%99=%%~b"

	Move /Y "%FileIni%" "%FileIni%.bak" >nul

	Set /A N=0
	>"%FileIni%" (
	FOR /F "usebackq tokens=1* delims==" %%i IN (`Set "A@@"`) DO Echo %%j
	FOR /F "usebackq tokens=3 delims==" %%i IN (`Set "B@@"`) DO Set /A N+=1 &Call Echo %Key%%%N%%=%%i
	FOR /F "usebackq tokens=1* delims==" %%i IN (`Set "C@@"`) DO Echo %%j
	)
pause
GoTo :Eof

:In
	Set /A N+=1
	Set /A M=0
	Set "InKey=%~1"
	Call Set "InKey=%%InKey:%Key%=%%"
	Set /A M=%InKey% 2>nul
	If %Pref%==B If "%M%"=="0" Set "Pref=C"
	If %1=="%Key%1" Set "Pref=B"
	Set "%Pref%@@%N%=%~1=%~2" 
GoTo :Eof