[O L E G]

как вариант, опробую, нашел)

Скрытый текст

@echo off
setlocal

for /f "tokens=2 delims=:" %%i in ('chcp') do (
set sPrevCP=%%i
chcp 1251 >nul
)

for /f "usebackq delims=" %%i in (
`@"%systemroot%\system32\mshta.exe" "javascript:var objShellApp = new ActiveXObject('Shell.Application');var Folder = objShellApp.BrowseForFolder(0, 'SELECT FOLDER',1, '::{20D04FE0-3AEA-1069-A2D8-08002B30309D}');try {new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(1).Write(Folder.Self.Path)};catch (e){};close();" ^
1^|more`
) do set sFolderName=%%i

chcp %sPrevCP% >nul

if defined sFolderName (
echo Выбрана папка: %sFolderName%
) else (
echo Папка не была выбрана.
)
pause

[Iska]

copy /y bcdedit.exe %windir%\system32\ »

Зачем в процессе backup копировать bcdedit.exe в системный каталог, где уже есть оригинальный bcdedit.exe?

copy /y HoboCopy.exe %windir%\system32\ »

Для чего копировать туда же нечто стороннее?

hobocopy /y %windir%\system32\config\ %systemdrive%\a1_Backup\CONFIG\_%date%\ SAM > %systemdrive%\a1_Backup\CONFIG\_%date%\config.log hobocopy /y %windir%\system32\config\ %systemdrive%\a1_Backup\CONFIG\_%date%\ DEFAULT >> %systemdrive%\a1_Backup\CONFIG\_%date%\config.log hobocopy /y %windir%\system32\config\ %systemdrive%\a1_Backup\CONFIG\_%date%\ SECURITY >> %systemdrive%\a1_Backup\CONFIG\_%date%\config.log hobocopy /y %windir%\system32\config\ %systemdrive%\a1_Backup\CONFIG\_%date%\ software >> %systemdrive%\a1_Backup\CONFIG\_%date%\config.log hobocopy /y %windir%\system32\config\ %systemdrive%\a1_Backup\CONFIG\_%date%\ system >> %systemdrive%\a1_Backup\CONFIG\_%date%\config.log hobocopy /y %windir%\system32\config\ %systemdrive%\a1_Backup\CONFIG\_%date%\ COMPONENTS >> %systemdrive%\a1_Backup\CONFIG\_%date%\config.log hobocopy /y %windir%\system32\config\ %systemdrive%\a1_Backup\CONFIG\_%date%\ netlogon.ftl >> %systemdrive%\a1_Backup\CONFIG\_%date%\config.log »

Код:

>"%systemdrive%\a1_Backup\CONFIG\_%date%\config.log" (
    for %%i in (SAM DEFAULT SECURITY software system COMPONENTS netlogon.ftl) do hobocopy.exe /y "%SystemRoot%\system32\config\" "%systemdrive%\a1_Backup\CONFIG\_%date%\" "%%~i"
)

[O L E G]

Зачем в процессе backup копировать bcdedit.exe в системный каталог, где уже есть оригинальный bcdedit.exe? »

да уже изменил, просто бывает файл на системе поврежден, думал как резервный. Убрал

Для чего копировать туда же нечто стороннее? »

Такая же ситуация. Оставил модуль hobocopy в контейнере с приложением.

"%systemdrive%\a1_Backup\CONFIG\_%date%\config.log" ( for %%i in (SAM DEFAULT SECURITY software system COMPONENTS netlogon.ftl) do hobocopy.exe /y "%SystemRoot%\system32\config\" "%systemdrive%\a1_Backup\CONFIG\_%date%\" "%%~i" ) »

За это спасибо

[O L E G]

Iska,
Уважаемый Iska, подредактируйте код, если При выборе отмена или нажатии на закрытие окна, скрипт не продолжал работать.
а то получается, выбор выскакиевает, диска, но если нажать отмену, он срабатывает дальше.
СПАСИБО!

Скрытый текст

@echo off
setlocal

for /f "tokens=2 delims=:" %%i in ('chcp') do (
set sPrevCP=%%i
chcp 1251 >nul
)

for /f "usebackq delims=" %%i in (
`@"%systemroot%\system32\mshta.exe" "javascript:var objShellApp = new ActiveXObject('Shell.Application');var Folder = objShellApp.BrowseForFolder(0, 'SELECT FOLDER',1, '::{20D04FE0-3AEA-1069-A2D8-08002B30309D}');try {new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(1).Write(Folder.Self.Path)};catch (e){};close();" ^
1^|more`
) do set sFolderName=%%i

chcp %sPrevCP% >nul

if defined sFolderName (
echo Выбрана папка: %sFolderName%
) else (
echo Папка не была выбрана.
)
pause

[Iska]

O L E G, там нечего редактировать. Покажите Ваш код.

[O L E G]

Iska,

Скрытый текст

@echo off
setlocal

for /f "tokens=2 delims=:" %%i in ('chcp') do (
set sPrevCP=%%i
chcp 1251 >nul
)

for /f "usebackq delims=" %%i in (
`@"%systemroot%\system32\mshta.exe" "javascript:var objShellApp = new ActiveXObject('Shell.Application');var Folder = objShellApp.BrowseForFolder(0, 'SELECT FOLDER',1, '::{20D04FE0-3AEA-1069-A2D8-08002B30309D}');try {new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(1).Write(Folder.Self.Path)};catch (e){};close();" ^
1^|more`
) do set sFolderName=%%i

chcp %sPrevCP% >nul

if defined sFolderName (
echo Выбрана папка: %sFolderName%
) else (
echo Папка не была выбрана.
)

mkdir %sFolderName%\a1_Backup\BCD\%date%\
mkdir %sFolderName%\a1_Backup\CONFIG\%date%\
mkdir %sFolderName%\a1_Backup\NTUSER\%date%\

hobocopy /y %systemdrive%\ %sFolderName%\a1_Backup\BCD\%date%\ bootmgr >> %sFolderName%\a1_Backup\BCD\%date%\bootmgr.log

hobocopy /y %windir%\system32\config\ %sFolderName%\a1_Backup\CONFIG\%date%\ SAM >> %sFolderName%\a1_Backup\CONFIG\%date%\config.log

То есть, если я к примеру закрываю Окно выбора диска, код работает дальше

[Iska]

Код:

…
if defined sFolderName (
    echo Выбрана папка: %sFolderName%
    
    mkdir %sFolderName%\a1_Backup\BCD\%date%\
    mkdir %sFolderName%\a1_Backup\CONFIG\%date%\
    mkdir %sFolderName%\a1_Backup\NTUSER\%date%\
    
    hobocopy /y %systemdrive%\ %sFolderName%\a1_Backup\BCD\%date%\ bootmgr >> %sFolderName%\a1_Backup\BCD\%date%\bootmgr.log
    hobocopy /y %windir%\system32\config\ %sFolderName%\a1_Backup\CONFIG\%date%\ SAM >> %sFolderName%\a1_Backup\CONFIG\%date%\config.log
) else (
    echo Папка не была выбрана.
)
…

[O L E G]

Iska,
Еще раз спасибо!
Н - невнимательность, надо было просто код поставить куда надо