[megaloman]

Код:

@Echo Off                                                                                                 
cls
	If "%~1"=="" (Echo !!! No Input Folder &Pause &Exit /B 2)
	If Not Exist "%~1" (Echo !!! Folder not found "%~1" &Pause &Exit /B 1)
	Tree "%~1"
Exit /B 0

[krisetta]

Код: @Echo Off cls If "%~1"=="" (Echo !!! No Input Folder &Pause &Exit /B 2) If Not Exist "%~1" (Echo !!! Folder not found "%~1" &Pause &Exit /B 1) Tree "%~1" Exit /B 0

только мне не надо делать это с помощью tree, а в виде
dir1
-dir1.1
--dir1.1.1
--dir1.1.2
-dir1.2
-dir1.2.1
dir2
где каждый знак - обозначает степень вложенности файла

[megaloman]

Код:

@Echo Off
cls
	If "%~1"=="" (Echo !!! No Input Folder &Pause &Exit /B 2)
	If Not Exist "%~1" (Echo !!! Folder not found "%~1" &Pause &Exit /B 1)

	Set "BoxIn=%~1"
	If "%BoxIn:~-1%"=="\" Set "BoxIn=%BoxIn:~0,-1%"

	Set "Def="
	Set "Marg=   "
rem	Set "Marg="

	Echo %BoxIn%
	For /F "usebackq delims=" %%d IN (`2^>nul Dir "%BoxIn%" /B /A:D`) DO Call :Out "%BoxIn%\%%d" %Def%- "%Marg%" 
pause
GoTo :Eof

:Out
	Echo %~3%2%~nx1
	For /F "usebackq delims=" %%d IN (`2^>nul Dir %1 /B /A:D`) DO Call :Out "%~1\%%d" %2- "%~3%Marg%"
GoTo :Eof

[alpap]

предложу и свой вариант, тут форматирование немного другое, но именно как у ТС записано:

Код:

@echo off
set "sdir=C:\papka"& if not "%~1"=="" set "sdir=%~1"
if not exist "%sdir%" echo folder not found "%sdir%"& pause& exit

for /f "delims=" %%a in ('dir /ad/b/s "%sdir%"') do set "d=%%a"& call :# "%%d:%sdir%\=%%"
pause& exit

:#
 setlocal enabledelayedexpansion
  set "d=%~1"
  for %%a in ("%d:\=" "%") do set "s=!s!-"
  for /f "delims=" %%a in ("%d%") do echo %s%%%~na
 endlocal
exit /b

[megaloman]

alpap, Мой вариант нагляднее, я напрягался чтобы сделать именно так, но, чтобы полностью соблюсти что в ТС записано, достаточно в моём варианте написать вместо
Set "Marg= "
Set "Marg="

[alpap]

Мой вариант нагляднее »

это да, да и я видел что в Вашем коде легко привести вывод к указанному ТС.

[megaloman]

alpap,

Что-то в консерватории надо менять

Tree

Код:

D:\CMD
└───JS_Host
    ├───Kaz_Copy_Move
    ├───WindowsScript.5v6b6626
    │   ├───Win2k_ru
    │   ├───Win9xMe
    │   └───_Docs
    ├───_Work
    │   ├───Arhiv
    │   ├───Mail
    │   │   ├───In
    │   │   └───Out
    │   ├───Protokol
    │   │   └───Arhiv
    │   ├───Report
    │   │   ├───APK
    │   │   │   ├───Obl
    │   │   │   └───Resp
    │   │   ├───Arhiv
    │   │   └───Buh
    │   │       ├───Obl
    │   │       └───Resp
    │   └───Soft
    │       ├───Arhiv
    │       ├───In
    │       └───Out
    ├───_XLS
    ├───Анализ_лог_файлов_Аргуса
    ├───Дискета_от_книги
    │   ├───Chapter01
    │   ├───Chapter02
    │   ├───Chapter03
    │   ├───Chapter04
    │   ├───Chapter05
    │   │   └───ForFind
    │   ├───Chapter06
    │   ├───Chapter07
    │   ├───Chapter08
    │   ├───Chapter09
    │   ├───Chapter10
    │   └───Chapter11
    ├───Из_интернета
    │   ├───Автоматизация работы с использованием Windows Scripting Host.files
    │   │   └───ConfRefresh.files
    │   ├───Листинг 1.files
    │   │   └───ConfRefresh.files
    │   ├───Основы WSH
    │   └───Сценарии WMI для начинающих.files
    └───Отлажено

Ваш вариант

Код:

-JS_Host
--Kaz_Copy_Move
--WindowsScript
--_Work
--_XLS
--Анализ_лог_файлов_Аргуса
--Дискета_от_книги
--Из_интернета
--Отлажено
---Win2k_ru
---Win9xMe
---_Docs
---Arhiv
---Mail
---Protokol
---Report
---Soft
----In
----Out
----Arhiv
----APK
----Arhiv
----Buh
-----Obl
-----Resp
-----Obl
-----Resp
----Arhiv
----In
----Out
---Chapter01
---Chapter02
---Chapter03
---Chapter04
---Chapter05
---Chapter06
---Chapter07
---Chapter08
---Chapter09
---Chapter10
---Chapter11
----ForFind
---Автоматизация работы с использованием Windows Scripting Host
---Листинг 1
---Основы WSH
---Сценарии WMI для начинающих
----ConfRefresh
----ConfRefresh
Для продолжения нажмите любую клавишу . . .

Вообще-то у Вас много несоответствий, я показал самое простое
Моё творение

Код:

D:\CMD
   -JS_Host
      --Kaz_Copy_Move
      --WindowsScript.5v6b6626
         ---Win2k_ru
         ---Win9xMe
         ---_Docs
      --_Work
         ---Arhiv
         ---Mail
            ----In
            ----Out
         ---Protokol
            ----Arhiv
         ---Report
            ----APK
               -----Obl
               -----Resp
            ----Arhiv
            ----Buh
               -----Obl
               -----Resp
         ---Soft
            ----Arhiv
            ----In
            ----Out
      --_XLS
      --Анализ_лог_файлов_Аргуса
      --Дискета_от_книги
         ---Chapter01
         ---Chapter02
         ---Chapter03
         ---Chapter04
         ---Chapter05
            ----ForFind
         ---Chapter06
         ---Chapter07
         ---Chapter08
         ---Chapter09
         ---Chapter10
         ---Chapter11
      --Из_интернета
         ---Автоматизация работы с использованием Windows Scripting Host.files
            ----ConfRefresh.files
         ---Листинг 1.files
            ----ConfRefresh.files
         ---Основы WSH
         ---Сценарии WMI для начинающих.files
      --Отлажено
Для продолжения нажмите любую клавишу . . .

В свой вариант добавил обработку входного параметра

[alpap]

Вообще-то у Вас много несоответствий »

все просто, у Вас неформатированный (живой, как есть) вывод, у меня нет, я это знаю и не отрицаю, но никто на этом не акцентировал внимания, хотя правильно бы, конечно, соблюсти правильный вывод и именно Ваш вариант в этом случае должен быть правильным.