CMD/BAT

Iska · Отправлено: **07:58, 02-12-2017** | #2

Есть ли в именах файлов «пробельные» символы, что будет, если имена заключить в кавычки:

Код:

ren "%SourceFolder%\%%~nxa" "!ShortName!"

? Покажите код с echo, и что он Вам пишет.

Patroklos · Отправлено: **08:22, 02-12-2017** | #3

Блин, старею

Забыл про скобки. Спасибо.
Переименовало все файлы как надо, кроме тех
у которых в имени есть восклицательный знак.
Что то можно поделать?

megaloman · Отправлено: **09:04, 02-12-2017** | #4

Код:

@Echo Off
set "SourceFolder=E:\20171130"

for %%a in (%SourceFolder%\*.*) do Call :RenFiles "%%a" -12 11
GoTo :Eof

:RenFiles
	Set "OrigName=%~n1"
	Call Set "ShortName=%%OrigName:~%2,%3%%%~x1"
	ren %1 "%ShortName%"
GoTo :Eof

Iska · Отправлено: **10:14, 02-12-2017** | #5

Цитата Patroklos:

Что то можно поделать? »

Убрать «enabledelayedexpansion», делать двойное раскрытие переменных окружения внутри скобок по «call». Готовый пример — в предыдущем сообщении.

alpap · Конфигурация компьютера

на мой взгляд второй раз писать call лишнее, можно одним обойтись:

Код:

@echo off
set "SourceFolder=E:\20171130"

pushd "%SourceFolder%"
 for %%a in (*) do set "name=%%~na"& call :_rn "%%a" "%%name:~-12,11%%%%~xa"
popd
pause& exit

:_rn
 ren "%~1" "%~2"
exit /b

Iska · Отправлено: **14:38, 02-12-2017** | #7

Цитата alpap:

на мой взгляд второй раз писать call лишнее, можно одним обойтись: »

А я недоглядел даже

.

Patroklos · Отправлено: **15:08, 02-12-2017** | #8

Всем огромное спасибо! Я пока проверил способ от megaloman и он работает отлично. Способ от alpap проверю позже но очевидно что он тоже работает

Вы крутые!