CMD/BAT - [решено] BAT считывающий по очереди строки

Fometra · Отправлено: **16:36, 23-08-2017** | #11

Сам разобрался, всем спасибо за внимание)))

Код:

echo !IP! !LOGIN! !PASS! !text! >> results.txt

megaloman · Отправлено: **17:43, 23-08-2017** | #12

Fometra, ИМХО, Брать в качестве разделителя "_" не слишком хорошая идея. Могу ошибаться, но в логине это допустимый символ. А в пароле тем более, плюс "!" тоже, что может привести к неприятностям при работе батника.
Предлагаю взять разделителем пробел.
Для строки вида:
192.168.125.15 User Tra La La

Код:

@Echo Off
Set "FileIn=Z:\Box_In\1.txt"
Set "FileLog=Z:\Box_Out\Results.txt"

FOR /F "usebackq tokens=1,2* delims= " %%A IN ("%FileIn%") DO Call :Connect "%%A" "%%B" "%%C"
GoTo :Eof

:Connect
	cmdkey /generic:TERMSRV/%~1 /user:%~2 /pass:%~3
	mstsc.exe /v %~1
	set /p text="COMMENT: "
	Echo %Date% %Time% %~1 %~2 %~3 %text%>>"%FileLog%" 
Pause
GoTo :Eof

Fometra · Отправлено: **17:49, 23-08-2017** | #13

Да, об этом не подумал, в паролях есть !

mwz · Отправлено: **17:54, 23-08-2017** | #14

Цитата megaloman:

Предлагаю взять разделителем пробел. »

А пробел в паролях тоже можно использовать.

Как раз с неделю назад в другом месте кто-то успешно опробовал, хотя и не на ftp, пароль из восьми пробелов и в шутку поинтересовался, легко ли его сбрутфорсить, в т.ч. словарной атакой.

megaloman · Отправлено: **17:56, 23-08-2017** | #15

Цитата mwz:

А пробел в паролях тоже можно использовать »

Да в этом варианте хоть сто порций пробелов

.
Однако, надо следить, чтобы в конце пароля в строке не было лишних пробелов. Увы, пробелы в начале пароля будут проигнорированы. Для Вашего примера пароля из пробелов скрипт не сработает. В этом случае надо иное решение. Чтобы скрипт отработал, первым в пароле должен быть символ.

alpap · Конфигурация компьютера

если есть возможность самому редактировать txt, то можно и так сделать, удобно, но на любителя

Код:

@echo off
:: Строки в "f.txt"
:: IP=192.168.125.15 User=user_1 Password=parol_1
:: IP=192.168.125.17 User=user_2 Password=parol_2
<f.txt (for /f "tokens=1,2*" %%a in ('more') do set "%%a"& set "%%b"& set "%%c"& call :#)
pause& exit

:#
 echo "%IP%" "%User%" "%Password%"
exit /b

Fometra · Отправлено: **18:26, 23-08-2017** | #17

В моих паролях нету пробелов, поэтому не беда.
Еще бы добавить, чтобы после чтения IP,LOGIN,PASS из файла 1.txt прочитанная строка удалялась

alpap · Конфигурация компьютера

Цитата Fometra:

прочитанная строка удалялась »

а вот это лишнее
удалять проще весь файл, но пока он нужен в нем можно делать изменения да и вообще хранить в качестве шаблона

megaloman · Отправлено: **19:32, 23-08-2017** | #19

Fometra,

Можно "съесть" в память весь файл (если он не слишком большой), удалить его, а затем из памяти брать прочитанные данные.

Код:

@Echo Off
cls

Set "FileIn=Z:\Box_In\1.txt"
Set "FileLog=Z:\Box_Out\Results.txt"

Set /A N=0
FOR /F "usebackq tokens=1,2* delims= " %%A IN ("%FileIn%") DO Call :ToMemory "%%A" "%%B" "%%C" A B C	
Echo Del "%FileIn%"
FOR /L %%i IN (1,1,%N%) DO Call :Connect %%A%%i%%  %%B%%i%%  %%C%%i%%

GoTo :Eof

:ToMemory
	Set /A N+=1
	Set "%4%N%=%1"
	Set "%5%N%=%2"
	Set "%6%N%=%3"
GoTo :Eof

:Connect
 	cmdkey /generic:TERMSRV/%~1 /user:%~2 /pass:%~3
 	mstsc.exe /v %~1
	set /p text="COMMENT: "
 	Echo %Date% %Time% %~1 %~2 %~3 %text%>>"%FileLog%" 
Pause
GoTo :Eof

Для удаления уберите Echo перед Del "%FileIn%"