[Iska]

"Асинхронные запросы Wbem" О! Вот это полезная штука, спасибо большое! Потестю на предмет скорости, если будет быстрее хотя бы раза в 2, чем сейчас »

Будет, коллега, будет. И куда быстрее, чем в два раза . Посмотрите тогда ещё и само обсуждение вот в этой теме: VBScript / WMI : Асинхронный мультипинг — Windows Script Host, HTA (VBScript, JScript) — Общение — Серый форум (именно из неё выросла тема в Коллекции). Там есть и временные оценки, и ещё кое-что, что может быть для Вас интересным.

PowerShell не подходит, так как сервер, где будет работать скрипт - Win2003, и переехать на другой нет возможности, »

PowerShell второй версии есть и для Windows Server 2003. BITS 4.0 будет, конечно, недоступен, но остальное — вполне:
Windows Management Framework (Windows PowerShell 2.0, WinRM 2.0, and BITS 4.0)
Download Update for Windows Server 2003 (KB968930) from Official Microsoft Download Center

Я понимаю, что с БД будет работать быстрее, и , возможно, проще, но БД я не умею от слова "вообще". »

Ну, ключевые слова — ADODB, Recordset, Connection. В принципе, там нет ничего сложного.

[glukin]

Спасибо! Пока попробую асинхронный опрос, по результату отпишусь.

[glukin]

del

[glukin]

Iska, Все отлично! Прирост в скорости примерно в 20 раз. То, что нужно!!
Проблема обнаружилась другая - почему-то не все устройства отдают свой SNMP sysName при абсолютно одинаковых настройках, но это вопрос, наверное, не сюда.
Буду допиливать дальше...

[glukin]

Поясните, пожалуйста, почему не работает конструкция вида:

'=============================================================================
' Процедура асинхронной обработки экземпляра объекта (замечание: в данном конкретном случае
' будет возвращаться единственный объект, однако, в большинстве случаев запросы
' возвращают множество объектов)
Sub Sink_OnObjectReady(objWbemObject, objWbemAsyncContext)
Dim strComputer

strComputer = objWbemAsyncContext.Item("HostName")

If Not IsNull(objWbemObject.StatusCode) Then
If objWbemObject.StatusCode = 0 Then

objWmiNamedValueSet.Add "AgentAddress", strComputer
objWmiNamedValueSet.Add "AgentReadCommunityName", "poll"
'on error resume next
Set colSystem = objWmiServices.InstancesOf("SNMP_RFC1213_MIB_system", , objWmiNamedValueSet)
WSCript.Echo IsNull(objSystem)
If Not IsNull(colSystem) Then
For Each objSystem In colSystem
If (Right(objSystem.sysName,12)="123") Then
objSystem.sysName=Left(objSystem.sysName,Len(objSystem.sysName)-12) + ".m"
Else
objSystem.sysName=objSystem.sysName + ".m"
End If
NFile1.WriteLine objSystem.sysName + " IN A " + strComputer
Next
Else
objWmiNamedValueSet.Add "AgentReadCommunityName", "public"
Set colSystem = objWmiServices.InstancesOf("SNMP_RFC1213_MIB_system", , objWmiNamedValueSet)
If Not IsNull(colSystem) Then
For Each objSystem In colSystem
If (Right(objSystem.sysName,12)="123") Then
objSystem.sysName=Left(objSystem.sysName,Len(objSystem.sysName)-12) + ".m"
Else
objSystem.sysName=objSystem.sysName + ".m"
End If
NFile1.WriteLine objSystem.sysName + " IN A " + strComputer
Next
Else

NoSNMP.WriteLine strComputer

End If
End If

End If
End If
End Sub

Выдаёт ошибку null на "For Each objSystem In colSystem"

[Iska]

glukin, используйте тэг code для оформления кода.

почему не работает конструкция вида: … Выдаёт ошибку null на "For Each objSystem In colSystem" »

Проверяйте так:

Код:

If Not colSystem Is Nothing Then

[glukin]

Iska, Без изменений.
ПС: на устройствах, которые отдают SNMP sysName все работает, не работает только на тех, которые SNMP не умеют.

[Iska]

Тогда детализируйте (ибо гадать не интересно) — на каком из двух:

For Each objSystem In colSystem»

происходит ошибка? Приведите точное сообщение об ошибке (можно просто нажать Ctrl-C в окне сообщения.

[glukin]

Iska, На первом.
---------------------------
Windows Script Host
---------------------------
Script: C:\Documents and Settings\Administrator\Desktop\ping.vbs
Line: 117
Char: 5
Error: 0x80041010
Code: 80041010
Source: (null)

---------------------------
OK
---------------------------
ПС: Я понимаю, что при скане ИП-адресов какой-то из ИП выдает NULL, то есть или не умеет SNMP, или access denied, но почему этот NULL не обрабатывается If'ами?

[Iska]

Ну, это ведь совсем не «null». Судя по описанию, Вы пытаетесь использовать несуществующий класс в указанном пространстве Wbem.

Попробуйте сделать проверку существования класса, наподобие:

Код:

Option Explicit

Dim strComputer

Dim objSWbemLocator
Dim objSWbemServicesEx
Dim collSWbemObjectSet
Dim objSWbemObjectEx


strComputer = "."

Set objSWbemLocator    = WScript.CreateObject("WbemScripting.SWbemLocator")
Set objSWbemServicesEx = objSWbemLocator.ConnectServer(strComputer, "root\cimv2")

WScript.Echo ClassExists(objSWbemServicesEx, "bla-bla-bla")
WScript.Echo ClassExists(objSWbemServicesEx, "Win32_Process")
WScript.Echo ClassExists(objSWbemServicesEx, "CIM_OperatingSystem")
WScript.Echo ClassExists(objSWbemServicesEx, "SNMP_RFC1213_MIB_system")


If ClassExists(objSWbemServicesEx, "SNMP_RFC1213_MIB_system") Then
	Set collSWbemObjectSet = objSWbemServicesEx.InstancesOf("SNMP_RFC1213_MIB_system")
	
	For Each objSWbemObjectEx In collSWbemObjectSet
		'…
	Next
Else
	' …
End If

WScript.Quit 0


Function ClassExists(objSWbemServicesEx, strClassName)
	Dim objSWbemObjectEx
	
	ClassExists = False
	
	For Each objSWbemObjectEx In objSWbemServicesEx.SubclassesOf()
		If StrComp(objSWbemObjectEx.Path_.RelPath, strClassName, vbTextCompare) = 0 Then
			ClassExists = True
			
			Exit Function
		End If
	Next
End Function