[megaloman]

Код:

@Echo off
>nul chcp 1251

Set "From=D:\YandexDisk" 
Set "Backup=E:\Backup"

Set "Pass=123"
If Not "%1"=="" Set "Pass=%~1" 

Set "Rar=C:\Program Files\WinRAR\WinRAR.exe"

If Not Exist "%Backup%" Md "%Backup%"  

Call :CallRar 0,"Мое видео"
Call :CallRar 5,"Мои документы"
Call :CallRar 0,"Мои звукозаписи"
Call :CallRar 5,"Мои программы"
Call :CallRar 5,"Мои рисунки"
Call :CallRar 0,"Мои фотографии"
Call :CallRar 0,"Моя музыка"

GoTo :Eof

:CallRar

    "%Rar%" a -r -m%1 -u -ep1 -p%Pass% -agYYYYMMDD "%Backup%\%~2 " "%From%\%~2\*.*"
rem "%Rar%" a -r -m%1 -u -ep1 -hp%Pass% -agYYYYMMDD "%Backup%\%~2 " "%From%\%~2\*.*"

GoTo :Eof

Текст батника набирайте в кодировке Windows (1251)
Смысл ключей смотрите в справочной системе Winrar.
Пароль может быть введён при запуске батника в параметре, например arhiv.bat tralala
БОльшую защищенность архива с паролем обеспечит применение ключа -hp%Pass% вместо -p%Pass%
либо можно явно прописать его в тексте батника (здесь в примере он 123)
Уровень сжатия указан в первом параметре при вызове проуедуры :CallRar (0 без сжатия, 5 - максимум),
однако я бы не советовал указывать уровень выше 3, существенно растёт время упаковки при небольшом уменьшении архива.

[zhecka]

Спасибо, огромное!!!! Сейчас попробую!!!