[Iska]

Код:

@echo off

>"\\Сервер\СкрытаяШараНаСервере$\%UserName%.txt" (
	<nul set /p sVar=%Time:~0,8% %Date% %ComputerName% 
	
	for /f "usebackq tokens=2 delims=={}" %%i in (
		`wmic.exe NICCONFIG where "IPEnabled='True'" get DNSServerSearchOrder /value ^| find.exe /i "DNSServerSearchOrder"`
	) do for %%j in (%%i) do <nul set /p sVar={%%~j} 
	
	echo.
)

и на всякий, если не сработал писал бы ошибку - типа time date error - error »

«Не сработал» что?

[Fantastish]

проверка доступности файла\шары\возможности записи в файл
и в зависимости от этого записать лог ошибки

[Iska]

и в зависимости от этого записать лог ошибки »

Куда, простите, писать, если этот самый лог недоступен?!

[Fantastish]

ну можно например в темп данной машины и перетирать его или дописывать
возможно отправлять по емаил, как вариант

[Iska]

Код:

@echo off

set sDestPath=\\Сервер\СкрытаяШараНаСервере$

if exist "%sDestPath%\." (
	>"%sDestPath%\%UserName%.txt" (
		<nul set /p sVar=%Time:~0,8% %Date% %ComputerName% 
		
		for /f "usebackq tokens=2 delims=={}" %%i in (
			`wmic.exe NICCONFIG where "IPEnabled='True'" get DNSServerSearchOrder /value ^| find.exe /i "DNSServerSearchOrder"`
		) do for %%j in (%%i) do <nul set /p sVar={%%~j} 
		
		echo.
	)
) else (
	>"%Temp%\%UserName%.txt" echo %Time:~0,8% %Date% %ComputerName% Can't find destination path [%sDestPath%].
)

Ладно, сеть может отвалиться, DC быть недоступен, но «возможность записи в файл» не вижу никакого смысла проверять — данная возможность должна быть обеспечена до исполнения пакетного файла, как необходимое условие для его функционирования.

[Fantastish]

Спасибо за помощь, буду тестировать

[Fantastish]

протестировал
12:46:16 17.12.2015 11111111111111 {показал первый DNS сервер} {показал второй DNS сервер} а можно именно IP адрес машины вывести?

[Iska]

{показал первый DNS сервер} {показал второй DNS сервер} а можно именно IP адрес машины вывести? »

Твою ж дивизию . Это я когда тестировал на наличие нескольких IP-адресов, взял вместо предыдущего свойства IPAddress именно DNSServerSearchOrder и забыл после тестирования вернуть IPAddress вобрат.

Пробуйте:

Код:

@echo off

set sDestPath=\\Сервер\СкрытаяШараНаСервере$

if exist "%sDestPath%\." (
	>"%sDestPath%\%UserName%.txt" (
		<nul set /p sVar=%Time:~0,8% %Date% %ComputerName% 
		
		for /f "usebackq tokens=2 delims=={}" %%i in (
			`wmic.exe NICCONFIG where "IPEnabled='True'" get IPAddress /value ^| find.exe /i "IPAddress"`
		) do for %%j in (%%i) do <nul set /p sVar={%%~j} 
		
		echo.
	)
) else (
	>"%Temp%\%UserName%.txt" echo %Time:~0,8% %Date% %ComputerName% Can't find destination path [%sDestPath%].
)

[Fantastish]

Огромное спасибо
а если не секрет, наличие несколько - это имелось ввиду 2 и более интерфейсов или еще статически прописанных адресов