[megaloman]

Если имена самой папки и её подпапок не начинаются с подчёркивания (кстати, у Вас в задании два подчеркивания - это часом не ошибка, файлы не должны начинаться с двух подчеркиваний?) то так:

Код:

@Echo Off

Set "From=D:\Dir1"
Set "To=D:\Dir2"

Echo \_ >~tmp.tmp

Set "Dt=%Date:~6,4%%Date:~3,2%%Date:~0,2%"

Xcopy "%From%\*.*" "%To%\%Dt%\" /s /y /q /EXCLUDE:~tmp.tmp
Del ~tmp.tmp

Предполагал, что дата в системе отображается как дд.мм.гггг. Копируется в папку ггггммдд.

Комментарии

Содержимое папки Dir1 копируется в папку Dir2 вместе с подпапками командой xcopy. Смысл её ключей смотрите при запуске команды xcopy /? в командном окне. Чтобы исключить копирование файлов, начинающихся на _ , до копирования организуем командой echo текстовый файл ~tmp.tmp со строкой c частью полного имени исключаемых файлов \_ . Этот файл указываем в ключе exclude в xcopy и после копирования удаляем.

[Fanbeer]

Спасибо. Я завтра посмотрю точно но возможно файлы и с двумя подчеркиваниями. Если не трудно можете прокомментировать что есть что в этом файле?

[Fanbeer]

Спасибо Вам огромное за помощь! Если можно, последний вопрос, как исключить копирование каталогов находящихся в той же директории?
Пардон, с этим разобрался сам Вопрос встал, как архивировать файлы при копировании или копировать сразу в архив с текущей датой?

[Fanbeer]

Да нужно заархивировать из корневой папки файлы в архив с текущей датой, исключая файлы начинающиеся с подчеркивания. Из подкаталогаов по хорошему нужно архивировать в отдельную папку файлы созданные вчерашним днем

[Fanbeer]

-там файлы только созданные в текущем дне или надо архивировать только файлы текущего дня, или всё что там есть (исключая _) в архив с именем текущей даты? »

Из корневого каталога архивировать все файлы исключая те которые начинаются с ( _ ) и исключая папки которые находятся в этом каталоге.

Из папок которые находятся в корневом каталоге, копировать в отдельную папку ( например "Журнал" ) файлы созданные предыдущем днем.

Файлы небольшого размера.

[megaloman]

Из корневого каталога архивировать все файлы исключая те которые начинаются с ( _ ) и исключая папки которые находятся в этом каталоге.

Код:

@Echo Off

Set "From=D:\Dir1"
Set "ToT=D:\Dir2\Today_"

Set "MaskOff=_*.*"

Set "Arc=%ProgramFiles%\winrar\winrar.exe"
rem Set "Arc=%ProgramFiles%\winrar\rar.exe"

md "%ToT%" 2>nul

"%Arc%" a -x%MaskOff% -agYYYYMMDD "%ToT%\.rar" "D:\Dir1\*.*"

Из папок которые находятся в корневом каталоге, копировать в отдельную папку ( например "Журнал" ) файлы созданные предыдущем днем.

Код:

@Echo Off

Set "From=D:\Dir1"
Set "ToY=D:\Dir2\Yesterday_"

Set "MaskOff=_*.*"

Set "Arc=%ProgramFiles%\winrar\winrar.exe"
REM Set "Arc=%ProgramFiles%\winrar\rar.exe"

md "%ToY%" 2>nul

Set "Dt=%Date:~6,4%%Date:~3,2%%Date:~0,2%"
FOR /F "usebackq delims=" %%i IN (`Dir "%From%\*.*" /b /A:D 2^>nul`) Do (
	"%Arc%" a -tn2d -tb%Dt%0000 -x%MaskOff% -agYYYYMMDD "%ToY%\.rar" "D:\Dir1\%%i\*.*"
)

Обе задачи в одном флаконе.

Код:

@Echo Off

Set "From=D:\Dir1"
Set "ToT=D:\Dir2\Today_"
Set "ToY=D:\Dir2\Yesterday_"

Set "MaskOff=_*.*"

Set "Arc=%ProgramFiles%\winrar\winrar.exe"
rem Set "Arc=%ProgramFiles%\winrar\rar.exe" >nul

md "%ToT%" 2>nul
md "%ToY%" 2>nul

"%Arc%" a -x%MaskOff% -agYYYYMMDD "%ToT%\.rar" "D:\Dir1\*.*"

Set "Dt=%Date:~6,4%%Date:~3,2%%Date:~0,2%"
FOR /F "usebackq delims=" %%i IN (`Dir "%From%\*.*" /b /A:D 2^>nul`) Do (
	"%Arc%" a -tn2d -tb%Dt%0000 -x%MaskOff% -agYYYYMMDD "%ToY%\.rar" "D:\Dir1\%%i\*.*"
)

[Fanbeer]

Архив получился но вот из подкаталога файл за вчерашний день не скопировался!

[megaloman]

Fanbeer, Естественно, это вторая задача. Уже сделал.

[Fanbeer]

megaloman, Спасибо огромное, реально выручили, дома попробовал все отлично работает