CMD/BAT - [решено] Поиск, замена текста в *.txt и вывод результата в другой каталог

Iska · Отправлено: **00:26, 02-11-2015** | #2

Цитата Vi3aliy:

поиск в папке файлов *.txt. В них ищем, допустим, "не готов" »

Упакуйте образцы двух-трёх файлов в архив, каковой приложите к сообщению.

Georgio · Отправлено: **01:08, 02-11-2015** | #3

Код:

@echo off

>nul chcp 1251

set "source=C:\папка А"
set "destination=C:\папка Б"
set "pattern=*.txt"

>nul chcp 866

set "original=Не готов"
set "final=отправлен"

for /f "delims=" %%i in ('
 ^>.tmp cmd/v/c echo.!original!^& 2^>nul findstr/milg:.tmp "%source%\%pattern%"^& del .tmp
') do 2>nul (
 for /f %%j in ('^<"%%i" find/c /v ""') do <"%%i">"%destination%\%%~nxi" (
  for /l %%k in (1 1 %%j) do @(
   set x=& set/p x=& if defined x (
    for /f "delims=" %%l in ('cmd/v/c echo "!x:%original%=%final%!"') do @(
     echo.%%~l
    ) 
   ) else (
    echo.
   )
  )
 )
)

exit/b

.

Предупреждение:

1) пакетный файл с данным кодом ни в коем случае не сохраняйте в кодировке OEM-866;

2) в случае замены строки, содержащей буквы русского алфавита, чётко соблюдайте регистр этих букв при задании переменной "original" (например, если в Вашем тексте надо заменить фразу "Не готов", то надо писать именно "Не готов", а не "не готов".

Iska · Отправлено: **05:48, 02-11-2015** | #4

Цитата Georgio:

1) пакетный файл с данным кодом ни в коем случае не сохраняйте в кодировке OEM-866; »

Никак Вы не хотите народ приобщать к разумному-доброму-вечному

.

Georgio · Отправлено: **08:02, 02-11-2015** | #5

Цитата Iska:

Никак Вы не хотите народ приобщать к разумному-доброму-вечному

. »

~~Не виноватая я! Он сам пришёл!~~ Да я уж не такой злодей, это опять она, команда "FINDSTR"

, виновата

.

Vi3aliy · Отправлено: **21:30, 02-11-2015** | #6

Огромное спасибо. Все работает.
Насчет кодировки все понял, меняем (Не готов - Not ready и отправлен - has been sent)
Еще просьба - можно сделать поиск и во вложеных папках, и как то сделать чтобы переодически все повторялось(раз в час или полчаса)?

Iska · Отправлено: **21:36, 02-11-2015** | #7

Цитата Vi3aliy:

и как то сделать чтобы переодически все повторялось(раз в час или полчаса)? »

Назначенные задания/Планировщик задач. Главное, чтоб обработанные файлы у Вас куда-то убирались из исходной папки.

Georgio · Отправлено: **22:10, 02-11-2015** | #8

Цитата Vi3aliy:

... сделать поиск и во вложеных папках... »

Можно. Добавьте ключ "/S" для команды "FINDSTR":

Код:

 ^>.tmp cmd/v/c echo.!original!^& 2^>nul findstr/msilg:.tmp "%source%\%pattern%"^& del .tmp

.

Цитата Vi3aliy:

... сделать чтобы переодически все повторялось(раз в час или полчаса)... »

Зациклить тоже можно. Но лучше делайте, как коллега Iska советует.

Vi3aliy · Отправлено: **21:46, 03-11-2015** | #9

Всё получилось.Спасибо.