CMD/BAT

Iska · Отправлено: **05:29, 22-07-2015** | #2

Цитата Ingvar2:

оставить только восьмую строчку … из четвертой строки »

?!

Без проверок существования исходного файла и целевого каталога:

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

set sSourceFile=out.txt

<"%sSourceFile%" (
	for /l %%i in (1, 1, 7) do >nul set /p sVar=
	>nul set /p sVar=
)

set sDestFile=%sVar:~7,4%.txt
set sContent=%sVar:~26,1%%sVar:~36,1%

>"%sDestFile%" echo %sContent%

del "%sSourceFile%"

>>"log.txt" (
	if exist "old\%sDestFile%" (
		echo [%sDestFile%] fail.
	) else (
		>nul move "%sDestFile%" "old\%sDestFile%"
		echo [%sDestFile%] ok.
		
		if "%sContent%" equ "35" (
			echo одна запись в лог
		) else (
			echo другая
		)
	)
)

endlocal
exit /b 0

Ingvar2 · Отправлено: **10:08, 22-07-2015** | #3

Цитата Iska:

?! »

поправил описание, в обоих случаях речь идет о восьмой строке.

Цитата Iska:

Код:

set sSourceFile=out.txt

<"%sSourceFile%" (
	for /l %%i in (1, 1, 7) do >nul set /p sVar=
	>nul set /p sVar=
)

set sDestFile=%sVar:~7,4%.txt
set sContent=%sVar:~26,1%%sVar:~36,1%

>"%sDestFile%" echo %sContent%

»

Когда выполняю данный код, то обрабатывается первая строка, а нужна восьмая.

Georgio · Отправлено: **12:11, 22-07-2015** | #4

Код:

@echo off

set "fname=out.txt"
set "number=8"

for /f "delims=" %%i in ('type "%fname%"^| findstr/n "^"^| findstr/b %number%:^& del "%fname%"') do (
 set x=%%i
 for /f "delims=" %%j in ('cmd/v/c echo "!x:*:=!"') do (
  set x=%%~j
  for /f "tokens=1,2 delims=$" %%k in ('cmd/v/c "echo !x:~7,4!$!x:~26,1!!x:~36,1!"') do (
   if exist "old\%%k.txt" (
    >"%%k.txt" echo.%%l
    >>"log.txt" echo %%l fail
   ) else (
    >"old\%%k.txt" echo.%%l
    >>"log.txt" (
    echo %%k ok
    if "%%l" equ "35" (
     echo %%k - %%l
    ) else (
     echo Другая запись с "%%k" и "%%l".
    )
    )
   )     
  )
 )
)

exit/b

Iska · Отправлено: **13:06, 22-07-2015** | #5

Цитата Ingvar2:

Когда выполняю данный код, то обрабатывается первая строка, а нужна восьмая. »

Попробуйте выполнять не «данный», а приведённый мною код. Целиком. А не только процитированную часть.

Georgio · Отправлено: **16:01, 22-07-2015** | #6

Iska, лучше сбрасывать предыдущие значения переменной sVar:

Код:

<"%sSourceFile%" (for /l %%i in (1 1 8) do set sVar=& set/p sVar=)

if defined sVar echo !sVar!

.

Иначе, если искомая (восьмая) строка пуста, то значением переменной sVar станет именно предыдущее значение, полученное в результате чтения предыдущей непустой строки.

Iska · Отправлено: **19:22, 22-07-2015** | #7

Цитата Georgio:

Iska, лучше сбрасывать предыдущие значения переменной sVar … Иначе, если искомая (восьмая) строка пуста, »

Угу. Тут я обусловился именно тем, что она не пуста. А вот то, что, в общем-то, нет никакой насущной необходимости как-то отдельно выделять чтение восьмой строки — не сообразил: сразу решил, что надо «пропустить» семь строк и «прочитать» восьмую. Так и осталось

.

Ingvar2 · Отправлено: **12:12, 23-07-2015** | #8

Спасибо, все получилось