[Iska]

DJIOAN, появление файла не означает начала печати, а лишь начало постановки в очередь. Впрочем…

На WSH:

Скрытый текст

Код:

Option Explicit

Dim strComputer

Dim objSWbemLocator
Dim objSWbemServicesEx
Dim objSWbemSink


strComputer = "."

Set objSWbemLocator    = WScript.CreateObject("WbemScripting.SWbemLocator")
Set objSWbemServicesEx = objSWbemLocator.ConnectServer(strComputer, "root\cimv2")
Set objSWbemSink       = WScript.CreateObject("WbemScripting.SWbemSink","Sink_")

objSWbemServicesEx.ExecNotificationQueryAsync objSWbemSink, _
	"SELECT * FROM __InstanceOperationEvent WITHIN 1 " & _
	"WHERE TargetInstance ISA 'Win32_PrintJob'"

WScript.Echo "Waiting for print job..."

Do
	WScript.Sleep 100
Loop

objSWbemSink.Cancel

Set objSWbemSink       = Nothing
Set objSWbemServicesEx = Nothing
Set objSWbemLocator    = Nothing

WScript.Quit 0
'=============================================================================

'=============================================================================
Sub Sink_OnObjectReady(objSWbemObject, objSWbemAsyncContext)
	With objSWbemObject
		'WScript.Echo Now(), vbTab, .Path_.Class, vbTab, .TargetInstance.Name, vbTab, .TargetInstance.Owner, vbTab, .TargetInstance.TotalPages
		
		Select Case .Path_.Class
			Case "__InstanceCreationEvent"
				With WScript.CreateObject("SAPI.SpVoice")
					.Volume = 100
					.Rate = 2
					
					.Speak "Print job started!"
				End With
			Case "__InstanceDeletionEvent"
				With WScript.CreateObject("SAPI.SpVoice")
					.Volume = 100
					.Rate = 2
					
					.Speak "Print job finished!"
				End With
			Case Else
				' Nothing to do
		End Select
	End With
End Sub
'=============================================================================

Если у Вас установлен русский движок — можете попробовать и русский текст.

[DJIOAN]

Iska Спасибо за помощь! Есть еще несколько вопросов:
-это wsh скрипт (его необходимо запускать или же добавить в винду там где Вход/Выход в сценарии) либо можно в автозагрузку?
-к примеру как быть если у меня 2 ринтера?
- (я так понял озвучка "Print job finished!" происходит стандартными средствами винды)
-можно ли к примеру сделать батник который предварительно скопирует пару звуковых файлов (к примеру в папку Windows в корень, файл pirnStart.wav и printStop.wav), а затем если его необходимо добавить оге в выполнение сценариев

или же можно это все объеденить в один BAT\CMD и просто добавить в Автозагрузку

[Iska]

его необходимо запускать или же добавить в винду там где Вход/Выход в сценарии) либо можно в автозагрузку? »

И так, и сяк, и даже этак можно.

-к примеру как быть если у меня 2 ринтера? »

Класс «Win32_PrintJob» должен обрабатывать любое число установленных принтеров.

- (я так понял озвучка "Print job finished!" происходит стандартными средствами винды) »

Отчасти. Штатным данный объект стал, кажись, только с Windows XP. И не в курсе насчёт его наличия в новых версиях. Пробуйте.

-можно ли к примеру сделать батник который предварительно скопирует пару звуковых файлов (к примеру в папку Windows в корень, файл pirnStart.wav и printStop.wav), а затем если его необходимо добавить оге в выполнение сценариев »

Упакуйте оба этих файла в архив и выложите на RGhost. Я посмотрю, что можно сделать.

[DJIOAN]

ок. Спасибо я дома выложу там в основном мой весь материал. Извиняюсь может я слишком банальное вообще спрашиваю, просто я не учился и сам по возможности учусь. Материала много хорошего но он раскидан по инету.

[Iska]

Учиться — это как раз нормально, не к чему извиняться. Жду.

[DJIOAN]

я конечно не понял что за RGhost, я прикреплю здесь Вам для просмотра что я написал по степени поступления знаний

[DJIOAN]

http://forum.oszone.net/attachment.p...1&d=1417543761

[DJIOAN]

Здравствуйте ! извиняюсь что поздно вчера прислал на сразу заметил что у нас с вами разница 2 часа. У нас сейчас 8,22. Я сегодня попробовал добавить в груповую политику скрипт что вы написали, после перезагрузки выдал ошибку что-то типа "Скрипт не запущен"

[DJIOAN]

А если быть точным то выскакивает окошко Windows Script Host с ошибко следующего содержания: "Сценарий не указан"
Хотя я сценарий указал в груповой политике во Вход в систему