[Georgio]

Systems, пробуйте:

Код:

@echo off

:: Обрабатываемый диск
set "drive=E:"

:: Папка назначения
set "out=E:\_Backup_"

for /f "delims=" %%i in ('2^>nul dir /ad/b "%drive%\Cam_*"') do (
 for /f "delims=" %%j in ('2^>nul dir /a-d/b/s "%drive%\%%i\*.avi"') do (
  set file=%%~nj
  call set "folder=%%file:~-20,4%%\%%file:~-27,6%%\%%file:~-16,2%%\%%file:~-14,2%%"
  2>nul call md "%out%\%%folder%%"
  >nul call move "%%j" "%out%\%%folder%%"
  )
 )

exit /b

.

[Systems]

Спасибо огромное, все работает просто замечательно!

[Systems]

Добрый день, еще небольшая просьба, после переноса файлов остаються папки с файлами *.log, для прмера evt_20141001_151835022.log
Можно в этом же скрипте после переноса *.avi удалить все папки с оставшимися файлами.
Удалить нужно папки которые находятся по вложению после e:\Cam_02\Video\Event, для примера
e:\Cam_01\Video\Event\20141001\09 - нужно удалить все папки с оставшимися в них файлами 20141001\09, 20141001\10, 20141002\08, 20141002\11 и так далее
e:\Cam_02\Video\Event\20141001\09 - нужно удалить все папки с оставшимися в них файлами 20141001\08, 20141001\13, 20141002\12, 20141002\14 и так далее

[Georgio]

Systems, дополнил:

Код:

@echo off

:: Обрабатываемый диск
set "drive=E:"

:: Папка назначения
set "out=E:\_Backup_"

for /f "delims=" %%i in ('2^>nul dir /ad/b "%drive%\Cam_*"') do (
 for /f "delims=" %%j in ('2^>nul dir /a-d/b/s "%drive%\%%i\*.avi"') do (
  set file=%%~nj
  call set "folder=%%file:~-20,4%%\%%file:~-27,6%%\%%file:~-16,2%%\%%file:~-14,2%%"
  2>nul call md "%out%\%%folder%%"
  >nul call move "%%j" "%out%\%%folder%%"
  )
 for /f "delims=" %%j in ('2^>nul dir /ad/b "%drive%\%%i\Video\Events"') do (
  rd /q/s "%drive%\%%i\Video\Events\%%j"
  )
 )

exit /b

.

[Systems]

Ничего неизменилось в работе, файлы перенес а папки с мусором остальсь.

[Georgio]

Systems, я просто из-за невнимательности вместо "Event" написал "Events". Вот так правильно:

Код:

@echo off

:: Обрабатываемый диск
set "drive=E:"

:: Папка назначения
set "out=E:\_Backup_"

for /f "delims=" %%i in ('2^>nul dir /ad/b "%drive%\Cam_*"') do (
 for /f "delims=" %%j in ('2^>nul dir /a-d/b/s "%drive%\%%i\*.avi"') do (
  set file=%%~nj
  call set "folder=%%file:~-20,4%%\%%file:~-27,6%%\%%file:~-16,2%%\%%file:~-14,2%%"
  2>nul call md "%out%\%%folder%%"
  >nul call move "%%j" "%out%\%%folder%%"
  )
 for /f "delims=" %%j in ('2^>nul dir /ad/b "%drive%\%%i\Video\Event"') do (
  rd /q/s "%drive%\%%i\Video\Event\%%j"
  )
 )

exit /b

.

[Systems]

Спасибо огромное, все работает.
Со своей стороны я то же недосмотрел что в некоторых каталогах есть еще одна папка Record - которую нужно очищать по тому же принципу что и Event
e:\Cam_01\Video\Record\20141001\09 - нужно удалить все папки с оставшимися в них файлами 20141001\09, 20141001\10, 20141002\08, 20141002\11 и так далее
Можно еще и это добавить в скрипт

[Georgio]

Код:

@echo off

:: Обрабатываемый диск
set "drive=E:"

:: Папка назначения
set "out=E:\_Backup_"

for /f "delims=" %%i in ('2^>nul dir /ad/b "%drive%\Cam_*"') do (
 for /f "delims=" %%j in ('2^>nul dir /a-d/b/s "%drive%\%%i\*.avi"') do (
  set file=%%~nj
  call set "folder=%%file:~-20,4%%\%%file:~-27,6%%\%%file:~-16,2%%\%%file:~-14,2%%"
  2>nul call md "%out%\%%folder%%"
  >nul call move "%%j" "%out%\%%folder%%"
  )
 for /f "delims=" %%j in ('2^>nul dir /ad/b "%drive%\%%i\Video\Event" "%drive%\%%i\Video\Record"') do (
  2>nul rd /q/s "%drive%\%%i\Video\Event\%%j"
  2>nul rd /q/s "%drive%\%%i\Video\Record\%%j"
  )
 )

exit /b

[Systems]

Спасибо огромное