CMD/BAT - bat который будет дописывать строки в конец файла

Iska · Отправлено: **13:56, 10-06-2014** | #2

Вставьте первой строкой:

Код:

>>"d:\123.txt" echo.

Georgio · Отправлено: **14:55, 10-06-2014** | #3

Код:

@echo off
for /f %%i in ('
 find /c /v ""^<"123.txt"
') do (
 set m=%%i
 )
for /f "delims=:" %%i in ('
 findstr /n $ "123.txt"
') do (
 set n=%%i
 )
if not %m%==%n% (
 echo.>>"123.txt"
 )
for %%i in (
 "tekst tekst tekst tekst "
 "tekst tekst tekst tekst tekst tekst tekst "
 "tekst tekst tekst "
 "tekst tekst tekst tekst "
 ) do (
 echo %%~i>>"123.txt"
 )
exit /b

infoman1@vk · Отправлено: **15:59, 10-06-2014** | #4

Цитата Georgio:
Код:

Код:

@echo off
for /f %%i in ('
 find /c /v ""^<"123.txt"
') do (
 set m=%%i
 )
for /f "delims=:" %%i in ('
 findstr /n $ "123.txt"
') do (
 set n=%%i
 )
if not %m%==%n% (
 echo.>>"123.txt"
 )
for %%i in (
 "tekst tekst tekst tekst "
 "tekst tekst tekst tekst tekst tekst tekst "
 "tekst tekst tekst "
 "tekst tekst tekst tekst "
 ) do (
 echo %%~i>>"123.txt"
 )
exit /b

»
вовсе ничего не делает

я создал 2 файла

22.bat

Код:

@echo off
for /f %%i in ('
 find /c /v ""^<"123.txt"
') do (
 set m=%%i
 )
for /f "delims=:" %%i in ('
 findstr /n $ "123.txt"
') do (
 set n=%%i
 )
if not %m%==%n% (
 echo.>>"123.txt"
 )
for %%i in (
 "tekst tekst tekst tekst "
 "tekst tekst tekst tekst tekst tekst tekst "
 "tekst tekst tekst "
 "tekst tekst tekst tekst "
 ) do (
 echo %%~i>>"123.txt"
 )
exit /b

123.txt

Код:

file 123

запустил 22.bat
и файл 123.txt так и остался не тронутым а по идеи должно было получится

Код:

file 123
tekst tekst tekst tekst
tekst tekst tekst tekst tekst tekst tekst
tekst tekst tekst
tekst tekst tekst tekst

Georgio · Отправлено: **16:12, 10-06-2014** | #5

Код:

@echo off
for /f %%i in ('
 find /c /v ""^<"123.txt"
') do (
 set m=%%i
 )
for /f "delims=:" %%i in ('
 findstr /n $ "123.txt"
') do (
 set n=%%i
 )
if not "%m%"=="%n%" (
 echo.>>"123.txt"
 )
for %%i in (
 "tekst tekst tekst tekst "
 "tekst tekst tekst tekst tekst tekst tekst "
 "tekst tekst tekst "
 "tekst tekst tekst tekst "
 ) do (
 echo %%~i>>"123.txt"
 )
exit /b

infoman1@vk · Отправлено: **16:57, 10-06-2014** | #6

супер то что нужно

Georgio · Отправлено: **00:19, 11-06-2014** | #7

infoman1@vk, вот так ещё точнее:

Код:

@echo off
(
for /f %%i in ('
 find /c /v ""^<"123.txt"
') do (
 set m=%%i
 )
)|| set m=0
(
for /f "delims=:" %%i in ('
 findstr /n $ "123.txt"
') do (
 set n=%%i
 )
)|| set n=0
if %n% lss %m% (
 echo.>>"123.txt"
 )
for %%i in (
 "tekst tekst tekst tekst "
 "tekst tekst tekst tekst tekst tekst tekst "
 "tekst tekst tekst "
 "tekst tekst tekst tekst "
 ) do (
 echo %%~i>>"123.txt"
 )
exit /b

.

alkogoliksasha · Отправлено: **20:31, 11-07-2014** | #8

а как сделать так так чтобы скрипт рекурсивно искал по маске файла(*.txt ) и дописывал в конец строку текста?

Georgio · Отправлено: **21:45, 11-07-2014** | #9

Код:

@echo off
for /r "D:\Test" %%i in (*.txt) do (
 (
 for /f %%j in ('
  find /c /v ""^<"%%i"
 ') do (
  set m=%%j
  )
 )|| set m=0
 (
 for /f "delims=:" %%j in ('
  findstr /n $ "%%i"
 ') do (
  set n=%%j
  )
 )|| set n=0
 for /f "tokens=1,2" %%j in ('
  call echo %%m%% %%n%%
 ') do (
  if %%k lss %%j (
   echo.>>"%%i"
   )
  )
 chcp 1251>nul
 for /f "eol= delims=" %%j in ("строка текста") do (
  chcp 866>nul
  echo %%j>>"%%i"
  )
 )
exit /b

alkogoliksasha · Отправлено: **22:21, 11-07-2014** | #10

Большое спасибо,все работает.