CMD/BAT - Проверка файлов в сетевом каталоге, и создание списка из тех которые по размеру < N

Iska · Отправлено: **14:39, 13-03-2014** | #2

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

set sRootFolder=\\some_dir\local_dir
set /a lLimit = 50*1^<^<20

if exist "%sRootFolder%\." (
	>"poisk.txt" (
		for /f "usebackq delims=" %%i in (
			`dir "%sRootFolder%\*.*" /b /s /a:-d`
		) do if %%~zi gtr %lLimit% echo %%i
	)
) else (
	echo Can't find root folder [%sRootFolder%].
	exit /b 1
)

endlocal
exit /b 0

«50*1^<^<20» — «50×2²⁰», 50 Мб.

gora · Конфигурация компьютера

Цитата wonted:

оптимально путь к файлу + размер »

Код:

@Echo Off
(for /f "delims=" %%i in ('dir "E:\My Downloads" /b /s /a-d') do if %%~zi gtr 50000000 Echo %%i %%~zi)>>poisk.txt

wonted · Отправлено: **14:53, 13-03-2014** | #4

Спасибо огромное! Все работает, осталось подружить с кириллицей, но это все мелочи

Iska · Отправлено: **14:53, 13-03-2014** | #5

А, недоглядел:

Цитата wonted:

+ размер »

добавьте вывод, как у коллеги:

Цитата gora:

Код:

… Echo %%i %%~zi …

»

Цитата wonted:

осталось подружить с кириллицей, »

Сохраните пакетный файл в кодировке OEM/866. Вывод будет в той же кодировке. Это нормально. Для корректного отображения используйте редактор, который понимает эту кодировку.

wonted · Отправлено: **15:05, 13-03-2014** | #6

Цитата Iska:

%%i %%~zi »

прошу прощения но похоже даже в копиосте умудряюсь допустить ошибки)

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

set sRootFolder=E:\Downloads
set /a lLimit = 50*1^<^<20

if exist "%sRootFolder%\." (
	>"poisk.txt" (
		for /f "usebackq delims=" %%i in (
			`dir "%sRootFolder%\*.*" /b /s /a:-d`
		) do if %%~zi gtr %lLimit% echo %%i %%~zi
	)
) else (
	echo Can't find root folder [%sRootFolder%].
	exit /b 1
)

endlocal
exit /b 0

результат, до того как втулил параметр работало, а сейчас все файлы кидает

Код:

E:\>if 73820995 GTR 52428800 echo E:\Downloads\111.zip 73820995 
E:\Downloads\111.zip 73820995

E:\>if 159281 GTR 52428800 echo E:\Downloads\Manual.pdf 159281 

E:\>if 992864 GTR 52428800 echo E:\Downloads\Msvbvm50.exe 992864 

E:\>if 702253 GTR 52428800 echo E:\Downloads\msvbvm50.zip 702253 

E:\>if 73820995 GTR 52428800 echo E:\Downloads\Ќ®ў*п Ї*ЇЄ*\111.zip 73820995 
E:\Downloads\Ќ®ў*п Ї*ЇЄ*\111.zip 73820995

E:\>if 159281 GTR 52428800 echo E:\Downloads\Ќ®ў*п Ї*ЇЄ*\Manual.pdf 159281 

E:\>if 992864 GTR 52428800 echo E:\Downloads\Ќ®ў*п Ї*ЇЄ*\Msvbvm50.exe 992864 

E:\>if 702253 GTR 52428800 echo E:\Downloads\Ќ®ў*п Ї*ЇЄ*\msvbvm50.zip 702253 

E:\>if 73820995 GTR 52428800 echo E:\Downloads\Ќ®ў*п Ї*ЇЄ*\Ќ®ў*п Ї*ЇЄ*\111.zip 73820995 
E:\Downloads\Ќ®ў*п Ї*ЇЄ*\Ќ®ў*п Ї*ЇЄ*\111.zip 73820995

E:\>if 159281 GTR 52428800 echo E:\Downloads\Ќ®ў*п Ї*ЇЄ*\Ќ®ў*п Ї*ЇЄ*\Manual.pdf 159281 

E:\>if 992864 GTR 52428800 echo E:\Downloads\Ќ®ў*п Ї*ЇЄ*\Ќ®ў*п Ї*ЇЄ*\Msvbvm50.exe 992864 

E:\>if 702253 GTR 52428800 echo E:\Downloads\Ќ®ў*п Ї*ЇЄ*\Ќ®ў*п Ї*ЇЄ*\msvbvm50.zip 702253

п.с. понял что дело в echo, вся строка отмечается как текст...

оишбка была в кодировке, осталось найти OEM/866 блокнот

Georgio · Отправлено: **15:18, 13-03-2014** | #7

Iska, а почему не

Код:

set /a lLimit = 50^<^<20

?

wonted · Отправлено: **15:24, 13-03-2014** | #8

Огромное спасибо парни! Вопрос полностью решен!
Может кому понадобится...
Итоговый код:

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

set sRootFolder=E:\Downloads
set /a lLimit = 50*1^<^<20

if exist "%sRootFolder%\." (
	>"poisk.txt" (
		for /f "usebackq delims=" %%i in (
			`dir "%sRootFolder%\*.*" /b /s /a:-d`
		) do if %%~zi gtr %lLimit% echo %%i %%~zi )
) else (
	echo Can't find root folder [%sRootFolder%].
	exit /b 1
)

endlocal
exit /b 0

Результат работы:

Код:

E:\Downloads\111.zip 73820995 
E:\Downloads\Новая папка\111.zip 73820995 
E:\Downloads\Новая папка\Новая папка\111.zip 73820995

Цитата Georgio:

50*1^<^<20 »

исходя из математики должно отработать...
так и получилось, выдает идентичный ответ

Iska · Отправлено: **16:16, 13-03-2014** | #9

Цитата Georgio:

Iska, а почему не »

Просто для понятности. «a на b в степени n» привычней.

wonted · Отправлено: **09:35, 14-03-2014** | #10

к сожалению возникла новая проблема

Код:

Microsoft Windows [Version 6.1.7601]
(c) Корпорация Майкрософт (Microsoft Corp.), 2009. Все права защищены.

C:\Users\it_support>E:\поиск.bat
Имя папки \\192.168.8.10\public\Проверить на сохранение\Мероприятия\лучшая школа
 России\нарезать1\нарезка для конкурса Образование\9Дополнительная информация и
приложения к Программе развития\17 дополнительные материалы к паспорту образоват
ельного учреждения\дополнительная информация об образовательном учреждении слишк
ом длинно.
Имя папки \\192.168.8.10\public\Проверить на сохранение\Мероприятия\лучшая школа
 России\нарезка для конкурса Образование\9Дополнительная информация и приложения
 к Программе развития\17 дополнительные материалы к паспорту образовательного уч
реждения\дополнительная информация об образовательном учреждении слишком длинно.

и как результат файл пуст батник висит, файлов конечно жутко много, но за пару часов думаю 50+ мб парочку точно нашлось бы. Возможно у кого есть идеи или догадки?
п.с. предполагаю что из за ошибки он попросту остановился на последнем каталоге, т.е. на каталоге с ошибкой