[santey007]

еще раз перепроверил: в папке(имя на латинице) лежит один файл name.bak, копирует в папку (названа тоже на латинице) без проблем. но стоит любую папку переименовать на русский... и все, батник не работает. переименовываю назад все, на латиницу-работает.

[Iska]

Начнём с такого вопроса: в какой кодировке у Вас сохранён пакетный файл?

[santey007]

изначально был в ANSI
потом в юникод, ютф-8

[Iska]

изначально был в ANSI потом в юникод, ютф-8 »

А надо — в OEM/866.

[santey007]

Iska все здорово, кодировку исправил, копирует нормально, по сети работает тоже хорошо.
теперь второй батник, что бы он например через 36 часов удалял старый файл(наверно можно поставить выполнение батника по времени, например раз в день или два дня), оставляя только самый новый из папки "E:\Песочница\0334\Destination\"
т.е. в папке Destination за 36 часов накопится 2-3 файла, надо что бы он оставил только один, самый новый по дате создания. как реализовать?

[Iska]

santey007, от какого момента нужно отсчитывать эти 36 часов?

[santey007]

Iska от момента когда в папке Destination будет более одного файла

[santey007]

можно хотя бы просто, что бы он удалял все файлы с папки, кроме одного-самого нового. я уж там в задании поставлю время

[Iska]

я уж там в задании поставлю время »

Где «в задании»? Каким образом задание сможет определить момент:

когда в папке Destination будет более одного файла »

Реализовать можно на WSH:

читать дальше »

Код:

Option Explicit

Const adDate    =   7
Const adVarChar = 200


Dim strSourceFolder

Dim objFSO
Dim objFile

Dim strComputer

Dim objSWbemLocator
Dim objSWbemServicesEx
Dim collSWbemObjectSet
Dim objSWbemObjectEx


strSourceFolder = "E:\Песочница\0334\Destination"

Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")

If objFSO.FolderExists(strSourceFolder) Then
	strComputer = "."
	
	Set objSWbemLocator    = WScript.CreateObject("WbemScripting.SWbemLocator")
	Set objSWbemServicesEx = objSWbemLocator.ConnectServer(strComputer, "root\cimv2")
	
	Set collSWbemObjectSet = objSWbemServicesEx.ExecNotificationQuery( _
		"SELECT * FROM __InstanceCreationEvent WITHIN 1 WHERE " &_
		"TargetInstance ISA 'CIM_DirectoryContainsFile' AND " &_
		"TargetInstance.GroupComponent = 'Win32_Directory.Name=""" & Replace(strSourceFolder, "\", "\\\\") & """'" _
	)
	
	Do
		Set objSWbemObjectEx = collSWbemObjectSet.NextEvent
		
		If objFSO.GetFolder(strSourceFolder).Files.Count > 1 Then
			Exit Do
		End If
	Loop
	
	WScript.Sleep 1000 * 60 * 60 ' 36 часов
	
	With WScript.CreateObject("ADODB.Recordset")
		With .Fields
			.Append "Path",        adVarChar, 2^15 - 1
			.Append "DateCreated", adDate
		End With
		
		.Open
		.Sort = "DateCreated DESC"
		
		For Each objFile In objFSO.GetFolder(strSourceFolder).Files
			.AddNew Array("Path", "DateCreated"), Array(objFile.Path, objFile.DateCreated)
		Next
		
		If .RecordCount >= 2 Then
			.MoveFirst
			.MoveNext
			
			Do Until .EOF
				With .Fields
					objFSO.DeleteFile .Item("Path").Value, True
				End With
				
				.MoveNext
			Loop
		Else
			' Nothing to do
		End If
		
		.Close
	End With
	
	Set objSWbemObjectEx   = Nothing
	Set collSWbemObjectSet = Nothing
	Set objSWbemServicesEx = Nothing
	Set objSWbemLocator    = Nothing
Else
	WScript.Echo "Source folder [" & strSourceFolder & "] not found."
	WScript.Quit 1
End If

Set objFSO = Nothing

WScript.Quit 0

но смысла в подобной организации автоматизации я не вижу ни малейшего.

[santey007]

подниму темку, ситуация немного изменилась, вернее тех задание. нужно все тоже самое, НО чтоб копировал на фтп
1-копирование крайнего по дате бэкапа скл, маска такая base_backup_2013_08_27_020001_6443075.bak на фтп
2-раз в неделю чистка бэкапов на фтп-ке, т.е. удаляем все, кроме самого крайнего по дате

я понимаю что на wsh легко наверняка подправить, но не силен в этом вообще