[galclerik]

Вы правы,в этом получается и есть проблема что "час" генерируется однозначным числом, а нужно чтобы всегда было двузначное число.

[Iska]

Давайте проделаем ещё раз то же самое с таким кодом:

читать дальше »

Код:

Option Explicit

With WScript.CreateObject("Scripting.FileSystemObject")
	With .CreateTextFile(.BuildPath(.GetParentFolderName(WScript.ScriptFullName), "list.txt"), True)
		.WriteLine SetLocale("ru")
		.WriteLine DateAdd("s", 1, 0)
		
		.WriteLine SetLocale("en-us")
		.WriteLine DateAdd("s", 1, 0)
		.WriteLine GetLocale()
	End With
End With

WScript.Quit 0

[galclerik]

Вот...

[Iska]

Мда. Возможно, я настолько привык к тому, что у меня hh:mm:ss, что и не помню, как оно должно быть по умолчанию.

Ладно, давайте будем тупо добавлять впереди «0» и обрезать:

читать дальше »

Код:

Option Explicit

Dim strSourceFile

Dim lngDayOnSeconds
Dim objRegExp
Dim arrContent
Dim i


If WScript.Arguments.Count = 1 Then
	strSourceFile = WScript.Arguments.Item(0)
	
	With WScript.CreateObject("Scripting.FileSystemObject")
		If .FileExists(strSourceFile) Then
			Randomize Timer
			
			lngDayOnSeconds = 24 * 60 * 60
			
			Set objRegExp = WScript.CreateObject("VBScript.RegExp")
			
			objRegExp.Pattern = "^(\d{2}\|\d{8}\|\d{8})(\d{6})(\|.*)$"
			
			With .OpenTextFile(strSourceFile)
				arrContent = Split(.ReadAll(), vbLf)
				.Close
			End With
			
			For i = LBound(arrContent) To UBound(arrContent)
				If objRegExp.Test(arrContent(i)) Then
					arrContent(i) = objRegExp.Replace(arrContent(i), "$1" & Right("0" & Replace(DateAdd("s", Rnd() * lngDayOnSeconds, 0), ":", ""), 6) & "$3")
				End If
			Next
			
			.CopyFile strSourceFile, .BuildPath(.GetParentFolderName(strSourceFile), .GetBaseName(strSourceFile) & ".bak"), True
			
			With .CreateTextFile(strSourceFile, True)
				.Write Join(arrContent, vbLf)
				.Close
			End With
			
			Set objRegExp = Nothing
		Else
			WScript.Echo "Source file [" & strSourceFile & "] not found."
			WScript.Quit 2
		End If
	End With
Else
	WScript.Echo "Usage: cscript.exe //nologo " & WScript.ScriptName & " <Source file>"
	WScript.Quit 1
End If

WScript.Quit 0

[galclerik]

Всё работает! Огромнейшее Вам спасибо!!!

[galclerik]

Добрый день! Подскажите, существует возможность настроить этот скрипт так, чтобы он обрабатывал сразу папку с файлами?

[Iska]

Подскажите, существует возможность настроить этот скрипт так, чтобы он обрабатывал сразу папку с файлами? »

Нет. Надо переписывать:

читать дальше »

Код:

Option Explicit

Dim strFolder

Dim lngDayOnSeconds
Dim objRegExp
Dim objFile
Dim arrContent
Dim i


If WScript.Arguments.Count = 1 Then
	strFolder = WScript.Arguments.Item(0)
	
	With WScript.CreateObject("Scripting.FileSystemObject")
		If .FolderExists(strFolder) Then
			Randomize Timer
			
			lngDayOnSeconds = 24 * 60 * 60
			
			Set objRegExp = WScript.CreateObject("VBScript.RegExp")
			
			objRegExp.Pattern = "^(\d{2}\|\d{8}\|\d{8})(\d{6})(\|.*)$"
			
			For Each objFile In .GetFolder(strFolder).Files
				If LCase(.GetExtensionName(objFile.Name)) <> "bak" Then
					WScript.Echo objFile.Path
					
					With .OpenTextFile(objFile.Path)
						arrContent = Split(.ReadAll(), vbLf)
						.Close
					End With
					
					For i = LBound(arrContent) To UBound(arrContent)
						If objRegExp.Test(arrContent(i)) Then
							arrContent(i) = objRegExp.Replace(arrContent(i), "$1" & Right("0" & Replace(DateAdd("s", Rnd() * lngDayOnSeconds, 0), ":", ""), 6) & "$3")
						End If
					Next
					
					objFile.Copy .BuildPath(objFile.ParentFolder.Path, .GetBaseName(objFile.Name) & ".bak"), True
					
					With .CreateTextFile(objFile.Path, True)
						.Write Join(arrContent, vbLf)
						.Close
					End With
				End If
			Next
			
			Set objRegExp = Nothing
		Else
			WScript.Echo "Folder [" & strFolder & "] not found."
			WScript.Quit 2
		End If
	End With
Else
	WScript.Echo "Usage: cscript.exe //nologo " & WScript.ScriptName & " <Folder>"
	WScript.Quit 1
End If

WScript.Quit 0

Файлы резервных копий «*.bak» пропускаются при обработке папки.

[galclerik]

Спасибо!