VBS/WSH/JS - [решено] Скрипт vbs который отображает картинку (Логотип.gif) на экране

Iska · Отправлено: **06:56, 30-06-2013** | #2

angel_lyucifer, зачем?

В WSH нет средств для создания окон. Если использовать IE — будут границы и надпись в заголовке. Используйте HTA, наподобие:

Код:

<html id="appHTA">
	<head>
		<meta charset="windows-1251">
		<meta http-equiv="Content-Type" content="text/html; charset=windows-1251">
		<meta http-equiv="Content-Language" content="ru">
		<title>My HTA application</title>
		<hta:Application
			Id="oHTA"
			ApplicationName="My HTA application"
			Border="none"
			Caption="no"
			ContextMenu="no"
			InnerBorder="no"
			MaximizeButton="no"
			MinimizeButton="no"
			Navigable="no"
			Scroll="no"
			ScrollFlat="no"
			Selection="no"
			ShowInTaskbar="yes"
			SingleInstance="yes"
			SysMenu="no"
			Version="0.1"
			WindowState="normal"
		/>
		<style type="text/css">
			BODY {
				color: WindowText;
				background-color: ButtonFace;
				margin: 0em;
			}
		</style>
	<html>
	
	<body id="tagBody">
		<img id="Splash" width="100%" height="100%">
	</body>
	
	<script language="VBScript">
		Dim strImgSource
		Dim objStdPicture
		
		strImgSource = "c:\My Path\bla-bla-bla.gif"
		
		Set objStdPicture = LoadPicture(strImgSource)
		Splash.src = "file://" & strImgSource

		With window
			.resizeTo Round(objStdPicture.Width / 26.47), Round(objStdPicture.Height / 26.47)
			.moveTo (.screen.availWidth - tagBody.offsetWidth) \ 2, (.screen.availHeight - tagBody.offsetHeight) \ 2
		End With
	</script>
</html>

angel_lyucifer · Конфигурация компьютера

Цитата Iska:

Используйте HTA, наподобие: »

Спасибо но ваш исходник не работает.
Окно есть а картинки нет, хотя я адрес изменил (Сократил).

PHP код:


<script language="VBScript">
        Dim strImgSource
        Dim objStdPicture
        
        strImgSource = "logotip.gif"
        
        Set objStdPicture = LoadPicture(strImgSource)
        Splash.src = "file://" & strImgSource

        With window
            .resizeTo Round(objStdPicture.Width / 26.47), Round(objStdPicture.Height / 26.47)
            .moveTo (.screen.availWidth - tagBody.offsetWidth)  2, (.screen.availHeight - tagBody.offsetHeight)  2
        End With
    </script>
</html>

mwz · Отправлено: **21:59, 30-06-2013** | #4

Цитата angel_lyucifer:

strImgSource = "logotip.gif" »

Если не указать logotip.gif с полным путём, то результатом может быть невозможность чтения файла скриптом.
Если путь содержит пробелы, то полное имя надо передавать в кавычках.

angel_lyucifer · Конфигурация компьютера

Цитата mwz:

Если не указать logotip.gif с полным путём, то результатом может быть невозможность чтения файла скриптом. »

А можно ли использовать переменную %CD% ?
Потому что путь и буква диска могут разными.

Iska · Отправлено: **07:54, 01-07-2013** | #6

Цитата angel_lyucifer:

Спасибо но ваш исходник не работает. »

Мой — работает.

Цитата angel_lyucifer:

Окно есть а картинки нет, хотя я адрес изменил (Сократил). »

Я Вас поздравляю. Но, если Вы не в ладах с html, какие ко мне претензии?

Цитата mwz:

Если не указать logotip.gif с полным путём, то результатом может быть невозможность чтения файла скриптом. »

Не совсем так: невозможность использовать протокол «file://».

Цитата mwz:

Если путь содержит пробелы, то полное имя надо передавать в кавычках. »

Не надо.

Цитата angel_lyucifer:

А можно ли использовать переменную %CD% ? »

Можно. Только бессмысленно. Используйте:

Код:

CreateObject("WScript.Shell").CurrentDirectory

Но, полагаю, Вас интересует отнюдь не текущий каталог, а каталог, в котором содержится сам ~~скрипт~~ файл *.hta — а это разные вещи (хотя могут и совпадать):

Код:

	<script language="VBScript">
		Option Explicit
		
		Dim strImgSource
		Dim objStdPicture
		
		With CreateObject("Scripting.FileSystemObject")
			strImgSource = .BuildPath(Replace(.GetParentFolderName(oHTA.commandLine), """", ""), "My file.gif")
			
			If .FileExists(strImgSource) Then
				Set objStdPicture = LoadPicture(strImgSource)
				Splash.src = "file://" & strImgSource
		
				With window
					.resizeTo Round(objStdPicture.Width / 26.47), Round(objStdPicture.Height / 26.47)
					.moveTo (.screen.availWidth - tagBody.offsetWidth) \ 2, (.screen.availHeight - tagBody.offsetHeight) \ 2
				End With
			Else
				MsgBox "Can't find path [" & strImgSource & "].", vbOKOnly & vbExclamation
			End If
		End With
	</script>