[Creat0R]

Хук отлавливания активного окна:

Код:

#NoTrayIcon
#include <WinAPI.au3>

Opt("WinWaitDelay", 0)
HotKeySet('{ESC}', '_Exit')

Global Const $HSHELL_WINDOWACTIVATED = 4
Global Const $HSHELL_RUDEAPPACTIVATED = 32772

$iMsg = _WinAPI_RegisterWindowMessage('SHELLHOOK')
GUIRegisterMsg($iMsg, 'HShellWndProc')
DllCall('user32.dll', 'int', 'RegisterShellHookWindow', 'hwnd', GUICreate(''))

While 1
    Sleep(100)
WEnd

Func _Exit()
    Exit
EndFunc

Func HShellWndProc($hWnd, $Msg, $wParam, $lParam)
    Switch $wParam
        Case $HSHELL_WINDOWACTIVATED, $HSHELL_RUDEAPPACTIVATED
            ToolTip(WinGetTitle($lParam), -1, -1, 'Active Window Title')
    EndSwitch
EndFunc

[madmasles]

Creat0R,
У меня на Win7x86 Ваш код не работает.
$wParam возвращает только HSHELL_WINDOWDESTROYED (0x00000002) и HSHELL_REDRAW (0x00000006).

Разобрался. У меня работает скрипт, который создает скрытые окна IE. Если его отключить, то Ваш код отлавливает активные окна, если скрипт работает, то нет. Почему? Не понятно.

[Creat0R]

У меня работает скрипт, который создает скрытые окна IE »

Возможно он как то использует хук...
Можно на него посмотреть?

[madmasles]

Возможно он как то использует хук... »

Нет, он не использует хук, он использует полноэкранный режим IE. Если в Вашу функцию добавить

Код:

;...
		Case $HSHELL_WINDOWACTIVATED, $HSHELL_RUDEAPPACTIVATED ;($HSHELL_RUDEAPPACTIVATED = 32772)
		;...

то все работает. (читал об этом здесь.)

[Creat0R]

Если в Вашу функцию добавить »

Обновил свой код выше.