[Iska]

Georgio, почему не просто:

Код:

findstr.exe /r /e /c:"Сумм:[0-9][0-9]" /c:"Сумм:[0-9][0-9]\.[0-9]" "%%~i"

?

[Georgio]

Iska, зта "сволочь", именуемая утилитой findstr.exe, никак не хочет напрямую воспринимать кириллицу. Ни смена кодовой страницы, ни перекодирование BAT-файла не приносят результата. Но, как видите, выход существует. Кстати, так и думал, что кто-нибудь спросит.

[Iska]

У меня — воспринимает:

Код:

E:\Песочница\0269>chcp
Текущая кодовая страница: 866

E:\Песочница\0269>findstr.exe /r /e /c:"Сумм:[0-9][0-9]" /c:"Сумм:[0-9][0-9]\.[0-9]" E:\Песочница\0269\*.txt
E:\Песочница\0269\112.txt:Сумм:30
E:\Песочница\0269\112.txt:Сумм:10.1

? Windows XP SP3.

[foma24]

Всем спасибо все прекрасно работает.

Подскажите еще, в том же файле еще есть строки вида <КоллПлат>45<\КоллПлат> с которыми нужно сделать тоже самое. На PS все прекрасно работает, а вот CMD не хочет воспринимать символы <> можно ли что то с этим сделать ?

[Georgio]

нужно сделать тоже самое »

-- то есть оставить беэ изменения?

Если так, то сделаем.

[foma24]

Простите что не уточнил. Лучше всего было бы и то и то. Т.е. тоже один батник ищет файлы с такой строкой в папке, другой батник корректирует файл и сохраняет в другой файл. Извините что надоедаю со своей проблемой

[Georgio]

Код:

@ECHO OFF
ECHO ^<КоллПлат^>>temp.txt
FOR %%I IN ("E:\Folder 1\*") DO (
 FINDSTR /G:temp.txt "%%~I">nul&&^
COPY "%%~I" "E:\Folder 2\">nul
)
DEL temp.txt

Зтот BAT-файл будет искать в файлах строки, содержащие "<КоллПлат>" и, если таковые найдёт, то скопирует зтот файл в назначенную папку.

Второй BAT-файл, котрый будет обрабатывать такие файлы, дописываю.

[Georgio]

Данный BAT-файл обрабатывает нужные файлы в пакетном режиме, причём обрабатываются все строки, включая и строки с угловыми скобками, так что необходимость в предыдущем BAT-файле может отпасть. Этот скрипт можно даже использовать сразу, без сортировки файлов, так как, если в файле не нужно делать замены, то такой файл будет переписан без изменений. Так что проверяйте.

Код:

@ECHO OFF
SETLOCAL ENABLEDELAYEDEXPANSION
::Выставляем папку, файлы в которой нужно обработать (без кавычек):::
SET In=E:\Folder 1
::Выставляем папку (также без кавычек), в которую будут помещаться ::
::обработанные файлы (можно установить ту же самую папку, т. к. ::
::файлы будут сораняться с добавлением "_new" к старому имени):::
SET Out=E:\Folder 2
(
 FOR %%I IN ("%In%\*.txt") DO (
  FOR /F "usebackq tokens=*" %%J IN ("%%~I") DO (
    FOR /F "tokens=1,3 delims=:." %%K IN ("%%J") DO (
     IF %%K==Сумм (
      SET VAR1=%%L
      IF DEFINED VAR1 (
       SET VAR2=!VAR1:~1!
       IF DEFINED VAR2 (
        ECHO %%J>>"%Out%\%%~nI_new.txt"
     ) ELSE (
        ECHO %%J0>>"%Out%\%%~nI_new.txt"
   )) ELSE (
       ECHO %%J.00>>"%Out%\%%~nI_new.txt"
  )) ELSE (
      SET /P VAR="%%J" 0>nul 1>>"%Out%\%%~nI_new.txt"
      ECHO.>>"%Out%\%%~nI_new.txt"
)))))&&^
ECHO All's ready. Press any key to exit.&&PAUSE>nul

Единственное, что может вызвать ошибку,-- это наличие в строке непарных кавычек, но такие случаи на практике редки.


Ещё о некоторых нюансах.

1. Пустые строки не переписываются.
2. Пробелы в начале строк также не сохраняются.
3. Если строка целиком заключена в кавычки, то кавычки отбрасываются.
4. Если ещё вдруг что-нибудь заметите, сообщите.

[Georgio]

У меня — воспринимает »

Windows XP SP3 »

Вот скрипт, который я протестировал в своей Windows 7 Starter:

Код:

CHCP
findstr.exe /r /e /c:"Сумм:[0-9][0-9]" /c:"Сумм:[0-9][0-9]\.[0-9]" "E:\Folder 1\111.txt"
findstr.exe /r /e /c:"‘㬬:[0-9][0-9]" /c:"‘㬬:[0-9][0-9]\.[0-9]" "E:\Folder 1\111.txt"
findstr.exe /G:"E:\Folder 1\111.txt" "E:\Folder 1\111.txt"

CHCP 1251
findstr.exe /r /e /c:"Сумм:[0-9][0-9]" /c:"Сумм:[0-9][0-9]\.[0-9]" "E:\Folder 1\111.txt"
findstr.exe /r /e /c:"‘㬬:[0-9][0-9]" /c:"‘㬬:[0-9][0-9]\.[0-9]" "E:\Folder 1\111.txt"
findstr.exe /G:"E:\Folder 1\111.txt" "E:\Folder 1\111.txt"

PAUSE>nul

Последние строки для каждой кодировки просто показывают содержимое файла.



А вот результат выполнения:


2013-06-07_181350.jpg



Жаль, что в данный момент больше не на чем проверить, но, если мне не изменяет память, в тех версиях Windows XP и Windows Vista, на которых я работал, проблем с кириллицей для findstr.exe не было. Очевидно, в Windows 7 Starter другая редакция этой утилиты. Так что тот вариант скрипта универсален.

[Iska]

А вот результат выполнения: »

Почему не текстом?

Вот скрипт…»

Кодировка его не OEM/866, а ANSI/1251, так?

в тех версиях Windows XP … на которых я работал, проблем с кириллицей для findstr.exe не было. »

Были [выделение моё].