[Georgio]

opravdin, вот так:

Код:

@ECHO OFF

SETLOCAL ENABLEDELAYEDEXPANSION

set c=0
for /f "eol=# delims== tokens=1,2" %%i in (out.qrs) do (
	set /a c=!c!+1
	set com_!c!=%%i
        set arg_!c!=%%j
)

SET com_
SET arg_

PAUSE>nul

[Iska]

opravdin, Georgio:

Код:

	set /a c = c + 1

«set /a» всегда раскрывает переменные окружения. «Отложенно», т.е. непосредственно в момент исполнения команды.

Указанную же команду вообще можно сократить до:

Код:

	set /a c += 1

[opravdin]

Georgio, Iska, спасибо большое!
EnableDelayedExpansion уже был включен, напутал с % и !. Так же спасибо за упрощенную форму команды set

[Georgio]

Указанную же команду вообще можно сократить до: Код: set /a c += 1 »

Так и есть, только уточню: вместо команд

Код:

set c=0

и

Код:

set /a c=c+1

применять только

Код:

set /a c+=1

.

Код: set com_%c%=%%i set arg_%c%=%%j »

А что здесь делать, если не

Код:

SETLOCAL ENABLEDELAYEDEXPANSION

?

[kiripanda]

Код:

	call set com_%%c%%=%%i
	call set arg_%%c%%=%%j

[Georgio]

Код: call set com_%%c%%=%%i call set arg_%%c%%=%%j »

-- поясните.

[Iska]

Так и есть, только уточню: вместо команд … применять только »

Корректнее всё-таки предварительно обнулять переменную, в которой накапливается сумма:

Код:

set /a c = 0

дабы быть уверенным, что используемая переменная где-то ранее не получила числового значения.

поясните. »

Используется двойное раскрытие:

Код:

call set arg_%%c%%=%%j

Другие, напротив, говорят, что здесь «%» используется как экранирующий символ:

Код:

call set arg_%%c%%=%%j

Так или иначе, после вызова call в новый контекст на исполнение передаётся команда:

Код:

set arg_%c%=<значение переменной цикла разбора «i»>

[kiripanda]

поясните »

Код:

@ECHO OFF &SETLOCAL

set /a c=0
for /f "eol=# delims== tokens=1,2" %%i in (out.qrs) do (
	set /a c=c+1
	call set com_%%c%%=%%i
	call set arg_%%c%%=%%j
)

SET com_
SET arg_
PAUSE