[mataranga]

Покопался в интернете нашел вот что:

PHP код:

set fname=NIKOLAY.txt
findstr /c:"Имя узла:" /c:"Название ОС" /c:"Версия ОС" %fname% > log.txt
del %fname%
move log.txt %fname% 

Как я правильно понял, он находит строку где есть "Название ОС" , "Версия ОС" и так далее
Пишет во временный файл, и переписывает старый...
Одно но, у меня конечный файл пустой...

[Iska]

Возможные причины:

1. Несоответствие кодировок.
2. Некоторые версии «findstr.exe» не всегда корректно работают с кириллицей.

[mataranga]

for /f "tokens=*" %%i in ('more +0 "1.txt"') do (echo %%i&exit) > out1.txt

как поменять, чтобы он не только первую строку брал, а еще какие я скажу?

for /f "tokens=*" %%i in ('more +0+1+2+3+4+5 "1.txt"') do (echo %%i&exit) > out1.txt
не работает

[Iska]

как поменять, чтобы он не только первую строку брал, а еще какие я скажу? »

Например, так:

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

for %%i in (1 3 5 8) do (
	for /f "usebackq delims=" %%j in (`more.com +%%i "E:\Песочница\0198\test.txt"`) do (
		if not defined sFirstLine (
			set sFirstLine=defined
			echo %%j
		)
	)
	set sFirstLine=
)

endlocal
exit /b 0

Но намного быстрее — так:

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

for /f "usebackq delims=[] tokens=1*" %%j in (`type "E:\Песочница\0198\test.txt" ^| find.exe /n /v ""`) do (
	for %%i in (1 3 5 8) do (
		if %%i equ %%j echo.%%k
	)
)

endlocal
exit /b 0

[mataranga]

Благодарствую