[решено] Вопрос по GUICtrlCreateEdit

madmasles · Конфигурация компьютера

HFShak,
Смотрите пример к функции

Код:

_GUICtrlEdit_GetLine()

Кликните по функции.

HFShak · Отправлено: **09:52, 16-10-2012** | #3

Спасибо.
А подскажите, как написать цикл, чтобы данная функция возвращала переменной все не пустые строки в текстовом поле.
Например, я вставляю в текстовое поле имена ПК, а_GUICtrlEdit_GetLine() возвращала переменнов $p в функции Ping($p) значения не пустых строк.

madmasles · Конфигурация компьютера

HFShak,
Попробуйте примерно так.

Код:

#include <GuiConstantsEx.au3>

$sText = 'google.ru' & @CRLF & @CRLF & 'mail.ru' & @CRLF & @CRLF & @CRLF & @CRLF & 'yandex.ru' & @CRLF & @CRLF & @CRLF & @CRLF
GUICreate('Test', 400, 300)
$nEdit = GUICtrlCreateEdit('', 2, 2, 394, 168)
GUICtrlSetData(-1, $sText)
$sText = ''
$nButton = GUICtrlCreateButton('Ping', 150, 180, 100, 30)
GUICtrlSetState(-1, $GUI_FOCUS)
GUISetState()
While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $nButton
            Local $sText = ''
            Local $iCount = 0
            Local $aText = StringSplit(StringStripCR(GUICtrlRead($nEdit)), @LF)
            For $i = 1 To $aText[0]
                If $aText[$i] Then
                    $iCount += 1
                    ConsoleWrite('String num ' & $iCount & @TAB & $aText[$i] & @LF)
                    $sText &= $aText[$i] & @TAB & 'Ping:' & Ping($aText[$i]) & ' msec' & @CRLF
                EndIf
            Next
            $aText = 0
            If $sText Then
                ConsoleWrite('Strings count: ' & $iCount & @LF)
                GUICtrlSetData($nEdit, StringTrimRight($sText, 2))
                $sText = ''
                $iCount = 0
            Else
                GUICtrlSetData($nEdit, '')
            EndIf
            GUICtrlDelete($nButton)
    EndSwitch
WEnd