[Ragnazar]

но почему-то немогут. Когда ставил там InputBox то все вводилось но в конце была ошибка
Нужно заполнить хотя-бы одно поле From или To

[Iska]

А что именно Вы вводили в ответ на эти запросы?

[Ragnazar]

InputBox("Кому","Ttile")

[Iska]

Я имею в виду, что Вы вводили в ответ на запрос:



?

[Ragnazar]

don.yari@yandex.ru

[Iska]

Всё работает.

читать дальше »

Код:

Option Explicit

Const cdoSendUsingPort = 2
Const cdoBasic         = 1

Const strPartSchema    = "http://schemas.microsoft.com/cdo/configuration/"

Dim strValue


With WScript.CreateObject("CDO.Message")
	With .Configuration.Fields
		.Item(strPartSchema & "sendusing")        = cdoSendUsingPort
		.Item(strPartSchema & "smtpauthenticate") = cdoBasic
		.Item(strPartSchema & "smtpserver")       = "smtp.mail.ru"
		.Item(strPartSchema & "smtpserverport")   = 25
		.Item(strPartSchema & "sendusername")     = "login"
		.Item(strPartSchema & "sendpassword")     = "password"
		
		.Update
	End With
	
	.To          = InputBox("Кому:",            "Отправка почтового сообщения", "to@yandex.ru")
	.From        = InputBox("От кого:",         "Отправка почтового сообщения", "from@mail.ru")
	.Subject     = InputBox("Тема:",            "Отправка почтового сообщения", "Subject")
	
	Do
		strValue = InputBox("Текст сообщения:", "Отправка почтового сообщения", "(пустая строка завершает ввод текста)")
		
		If Len(strValue) = 0 Then
			Exit Do
		Else
			.TextBody = .TextBody & vbCrLf & strValue
		End If
	Loop
	
	.Send
End With

WScript.Quit 0

[Ragnazar]

Да. Работает

Но я не понимаю принцип строчек (strPartSchema & "sendusing") и других подобных.
Как они разъединились из той первоначальной длинной строки?

[Iska]

Но я не понимаю принцип строчек (strPartSchema & "sendusing") и других подобных. Как они разъединились из той первоначальной длинной строки? »

Я просто вынес отдельно общую часть всех этих строк, только и всего. Можно было и просто:

Код:

		.Item("http://schemas.microsoft.com/cdo/configuration/sendusing")        = cdoSendUsingPort
		.Item("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = cdoBasic
		.Item("http://schemas.microsoft.com/cdo/configuration/smtpserver")       = "smtp.mail.ru"
		.Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport")   = 25
		.Item("http://schemas.microsoft.com/cdo/configuration/sendusername")     = "login"
		.Item("http://schemas.microsoft.com/cdo/configuration/sendpassword")     = "password"

[Ragnazar]

А.
Да. Понял. Не разглядел Set
А зачем do - loop в конце?

[Ragnazar]

Для нескольких строк. Да