[Iska]

Ragnazar, ключевое слово «Const», описывающее последующую за ним константу, не предполагает наличия каких-либо выражений в определяющей части инструкции (после знака равенства).

Так что, используйте «Dim». Тем паче, что, в данном случае, сие и по смыслу должно быть так.

Код:

Dim AnyHere

AnyHere = InputBox("Сообщение", "Заголовок")

[Ragnazar]

Просто пытаюсь сделать, что-бы пользователь определял функцию
CDO.Message.Configuration.Fields.Item
Обычная переменная не работает.

Точнее не эту функцию а
CDO.Message.From

[Iska]

Ragnazar, ничего не понятно. Покажите код, который должен работать, но не работает.

[Ragnazar]

Код:

Const EmailFrom = "От кого"
Const EmailPassword = InputBox "Пароль"
Const strSmtpServer = InputBox "smtp server"
Const EmailTo = InputBox "Кому"
Set objEmail = CreateObject("CDO.Message")  
objEmail.From = EmailFrom 
objEmail.To = EmailTo 
objEmail.Subject = InputBox "Тема"
objEmail.Textbody = InputBox "Сообщение"
objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2 objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1 
objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendusername") = EmailFrom 
objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendpassword") = EmailPassword 
objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpserver") = strSmtpServer 
objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25 
objEmail.Configuration.Fields.Update 
objEmail.Send 
WScript.Quit

Заменить константы DIMом и SETом не получилось

[Iska]

Это называется «смешались в кучу кони, люди». Исправлять не стал.

Не проверялось:

Код:

Option Explicit

Dim EmailFrom
Dim EmailPassword
Dim strSmtpServer
Dim EmailTo
Dim objEmail

EmailFrom     = "От кого"
EmailPassword = InputBox("Пароль")
strSmtpServer = InputBox("smtp server")
EmailTo       = InputBox("Кому")

Set objEmail = CreateObject("CDO.Message")

With objEmail
	.From     = EmailFrom
	.To       = EmailTo
	.Subject  = InputBox("Тема")
	.Textbody = InputBox("Сообщение")
	
	With .Configuration.Fields
		.Item("http://schemas.microsoft.com/cdo/configuration/sendusing")        = 2
		.Item("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1
		.Item("http://schemas.microsoft.com/cdo/configuration/sendusername")     = EmailFrom
		.Item("http://schemas.microsoft.com/cdo/configuration/sendpassword")     = EmailPassword
		.Item("http://schemas.microsoft.com/cdo/configuration/smtpserver")       = strSmtpServer
		.Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport")   = 25
		
		.Update
	End With
	
	.Send
End With

Set objEmail = Nothing

WScript.Quit

[Ragnazar]

Узнал много нового про With
А Set ObjEmail = Nothing обязательно?
И что такое option explicit?

[Iska]

А Set ObjEmail = Nothing обязательно? »

Старайтесь сразу привыкать освобождать объектные переменные, когда они более не требуются. В данном конкретном случае скрипт всё одно завершает свою работу, так что большой разницы нет. Но в других случаях сие может стать критичным. Так что, как я уже говорил, лучше привыкать делать сие сразу. Привычка — вторая натура.

Вы как бы «говорите», что объектная переменная более не ссылается на область памяти, занятую созданным ранее экземпляром объекта «CDO.Message», и сборщик мусора (Сборка мусора — Википедия) во время очередного прохода сможет освободить эту память и вернуть её в распоряжение системы.

И что такое option explicit? »

Это инструкция, декларирующая, что все переменные, содержащиеся в коде, должны быть предварительно объявлены (например, при помощи оператора Dim). Использование данной инструкции позволяет избегать глупых ошибок, возникающих при ошибках написания имён переменных.

[Ragnazar]

А вот вопрос
Почему
CDO.Message.subject и .textbody
Могут использовать InputBox
А .From .To
Нет? (Сообщалась ошибка "Нужно заполнить хотя-бы одно поле From или To)

[Iska]

Почему CDO.Message.subject и .textbody могут использовать InputBox а .From .To нет? (Сообщалась ошибка "Нужно заполнить хотя-бы одно поле From или To) »

«.From» и «.To» тоже могут.