CMD/BAT

sov44 · Конфигурация компьютера

При исполнении кода

Код:

@echo off
SetLocal enabledelayedexpansion

set "dr=%USERPROFILE%\Recent"
for /f "delims=" %%i in ('dir /b/s/a-d "%dr%\*.lnk" 2^>nul') do del /f/q "%%i"
pause

неожиданно обнаружился файл "Письмо «Re_ программа для ПК» — Dmitry Maksimov — Яндекс.Почта.lnk", который не удалился. Подскажите, как унифицировать код, чтобы удалялись файлы, в именах которых есть спецсимволы.

Foreigner · Отправлено: **07:51, 04-09-2012** | #12

sov44, А зачем через "dir" удалять? Не проще:

Код:

del /s /a /f "%dr%\*.lnk"

sov44 · Конфигурация компьютера

Цитата Foreigner:

А зачем через "dir" удалять? »

скрипт ещё считает размер удаляемых файлов. Не показал на примере.

Foreigner · Отправлено: **10:33, 04-09-2012** | #14

sov44,
Тогда попробуй так:

Код:

@echo off
SetLocal enabledelayedexpansion

pushd "%USERPROFILE%\Recent" || goto:eof
for /f "tokens=3,4" %%i in ('dir /x /-c /a-d ^| findstr "\.LNK\>"') do (

    echo размер для подсчета: %%i
    del /f /q "%%~fsj"

)
popd
pause

sov44 · Конфигурация компьютера

Foreigner, спасибо! То, что надо!

К сожалению не удаётся отладить код, подскажите, в чём ошибка

Код:

@echo off
SetLocal enabledelayedexpansion

set "dr=%USERPROFILE%\Recent"& call :Calc "!dr!" *.lnk
echo !iSumT!
pause
exit

:Calc
pushd "%1" || goto:eof
for /f "tokens=3,4" %%i in ('dir /x /-c /a-d "%~1" ^| findstr "\%2\>"') do (
       set /a iSumT +=%%i        
       del /f /q "%%~fsj"
)
popd
GoTo :EOF

Foreigner · Отправлено: **16:23, 04-09-2012** | #16

sov44, а что конкретно не работает? Пару замечаний:
1. Зачем все писать в одну строку? Такой необходимости вообще нет:

Код:

set "dr=%USERPROFILE%\Recent"
call :Calc "%dr%" *.lnk

2. Где уверенность, что сумма "iSum" в итоге не превышает 2147483648, что является предельным для cmd.exe? Если надо посчитать, то придется складывать поразрядно. Например так:

Код:

@echo off
setlocal enabledelayedexpansion

set "num1=0"
set "num2=0"
set "num3=0"

set "num1=000000000000000%1"
set "num1=%num1:~-15%"
set "num2=000000000000000%2"
set "num2=%num2:~-15%"

for /l %%i in (1,1,15) do (

    set /a "sum=!num1:~-%%i,1!+!num2:~-%%i,1!+num3"
    if !sum! geq 10 (set "num3=1" && set /a "sum-=10") else (set "num3=0")
    set "res=!sum!!res!"

)

:zerout
if "%res:~0,1%"=="0" set "res=%res:~1%" && goto:zerout

echo %res%