Любой язык

Anonymоus · Отправлено: **16:01, 03-06-2012** | #2

Baranius, попробуйте вот это.

Код:

@Echo Off
Set File=test.txt

rem Разбираем файл построчно
For /F "usebackq delims=" %%S In ("%File%") Do (
    rem Проводим в нём же поиск по отдельно взятой строке и получаем количество совпадений
    For /F "tokens=3 delims=: " %%C In ('Find /C "%%S" "%File%"') Do (
        rem Сортируем строки по разным спискам
        If "%%C"=="1" (
            Echo %%S>>"checked.txt"
        ) Else (
            Echo %%S>>"duplicated.txt"
        )
    )
)

В качестве файла допустимо указывать только относительный путь (чтобы избежать появления в строке, выдаваемой Find ещё одного двоеточия). Кроме того, есть некоторая неточность в поиске данным методом - например, Find найдет и пометит, как дубликат строку "123", если в файле ещё будут присутствовать строки "1234" и "a123"
Впрочем, для вашей задачи (поиск дубликатов песен по их длительности) это особой роли не играет, вероятность совпадения из-за такого поведения Find крайне ничтожна.

Iska · Отправлено: **22:54, 03-06-2012** | #3

Цитата Baranius:

найти повторяющиеся значения - дубликаты. »

И что с ними делать?

Baranius · Отправлено: **01:42, 04-06-2012** | #4

Цитата Iska:

найти повторяющиеся значения - дубликаты. »
И что с ними делать? »

- да Вы просто их найдите, и дайте об этом знать хоть списочком каким, хоть другим способом. Вопрос - возможно ли это силами CMD\BAT, VBS скриптов?

Baranius · Отправлено: **03:55, 04-06-2012** | #5

Уважаемый Anonymоus, я рад Вас видеть в этой теме, которая навеяна нашим неравноправным общением по вопросу... "как не потерять старый плейлист после наведения порядка на диске" И чтобы не настаивать на

хотелке

мне подумалось, что легче, для начала, избавиться от дубликатов, а потом уж приводить в порядок старый плейлист. Поэтому и появилась эта тема (я постеснялся вновь обращаться к Вам, к тому же правила форума - "один вопрос - одна тема")

Baranius · Отправлено: **15:01, 04-06-2012** | #6

Спасибо, Anonymоus! Всё чудесно работает (взял только один столбец с длительностью и представил его как "test.txt"). Но вот с этим:

Цитата Anonymоus:

В качестве файла допустимо указывать только относительный путь »

я не справился, уж как я его (относительный путь) не подставлял. Подскажите, какого вида должна быть строка, чтобы я увидел результат содержащий уже и путь к файлу!?

Anonymоus · Отправлено: **15:47, 04-06-2012** | #7

Просто положите файл рядом со скриптом, и там, где указано "Set File=test.txt" - поставьте своё имя файла. Это и есть относительный путь, в отличии от абсолютного, когда путь полный, и начинается с указания диска.

Baranius · Отправлено: **16:37, 04-06-2012** | #8

Я имел в виду другое, как теперь с помощью Вашего скрипта обнаружить дубликаты в моём списке состоящим из трёх столбцов-полей
"1|путь к файлу|длительность" ?
Ведь Ваш скрипт я проверял на списке , состоящем только из одного столбца - "длительность"

Baranius · Отправлено: **13:50, 05-06-2012** | #9

Попробую ещё раз обратиться.
Ув. Anonymоus не сможете ли Вы подправить свой скрипт из 2 поста под список "test.txt" не с одним полем - "длительность", а с тремя полями вида:
"1|путь к файлу|длительность", чтобы я смог в результате увидеть дубликаты уже с их путями.
Благодарю.

Anonymоus · Отправлено: **19:17, 05-06-2012** | #10

Код:

@Echo Off
Set File=test.txt
rem Разбираем файл построчно
For /F "usebackq delims=" %%S In ("%File%") Do (
    rem Выделяем из строки длительность
    For /F "tokens=3 delims=^|" %%L In ("%%S") Do (
        rem Проводим поиск по файлу в поисках такой же длительности
        For /F "tokens=3 delims=: " %%C In ('Find /C "|%%L" "%File%"') Do (
            rem Раскидываем строки по разным спискам
            If "%%C"=="1" (
                Echo %%S>>"checked.txt"
            ) Else (
                Echo %%S>>"duplicated.txt"
            )
        )
    )
)

Все дубликаты пишет в "duplicated.txt", а не повторяющиеся строки в "checked.txt". Для вашего удобства я сделал вывод не только повторяющейся длительности, а строки целиком - включая путь.