[kotkovets]

Чтобы так не извращаться... »

В справке в указателе вводим - LineFind

Код:

OutFile "example.exe"
!include "MUI2.nsh"
!include "TextFunc.nsh"
ShowInstDetails show
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_LANGUAGE Russian

Section
 ${LineFind} "$EXEDIR\file.txt" "" "1:-1" "LineRead"
 IfErrors 0 +3
   MessageBox MB_OK "Файла не существует!" IDOK
   Abort

   MessageBox MB_OK "$R1" IDOK
SectionEnd

Function LineRead
  DetailPrint $R9
  StrCpy $R0 $R9 4
  ${IfThen} $R0 == 0400 ${|} StrCpy $R1 $R0 ${|}
  Push $0
FunctionEnd

[wolkow70]

Сделал так:

Код:

!define MUI_PAGE_CUSTOMFUNCTION_PRE PRELICENSE
!define MUI_PAGE_CUSTOMFUNCTION_PRE PRESTARTMENU

Function PRELICENSE
${If} $GMODE = 1 
Abort
${EndIf}
FunctionEnd

Function PRESTARTMENU
${If} $GMODE = 1 
Abort
${EndIf}
FunctionEnd

Теперь думаю как сделать , чтобы при $GMODE = 1

на финишной странице не отображалось:
!define MUI_FINISHPAGE_RUN "$INSTDIR\winamp.exe"
!define MUI_FINISHPAGE_RUN_TEXT "Запустить Winamp"
!define MUI_FINISHPAGE_RUN_NOTCHECKED
и не выполнялось:
!define MUI_FINISHPAGE_NOAUTOCLOSE


При этом имеется функция :

Код:

Function SHOWFINISH
${If} $GMODE = 1 
${NSD_SetText} $mui.FinishPage.Title "Завершение работы Мастера создания файла ответов."
${NSD_SetText} $mui.FinishPage.Text "Файл ответов готов!"
${EndIf}
FunctionEnd

Кто-нибудь подскажет?

[kotkovets]

Кто-нибудь подскажет? »

Меняйте значение $GMODE и увидете разницу...

читать дальше »

Код:

OutFile "example.exe"
!include "MUI2.nsh"
ShowInstDetails show

var GMODE
!define MUI_FINISHPAGE_RUN "$EXEDIR\winamp.exe"
!define MUI_FINISHPAGE_RUN_TEXT "Запустить Winamp"
!define MUI_FINISHPAGE_RUN_NOTCHECKED
!define MUI_FINISHPAGE_NOAUTOCLOSE

!insertmacro MUI_PAGE_WELCOME
     !define MUI_PAGE_CUSTOMFUNCTION_LEAVE INSTFILESLEAVE
!insertmacro MUI_PAGE_INSTFILES
     !define MUI_PAGE_CUSTOMFUNCTION_SHOW SHOWFINISH
!insertmacro MUI_PAGE_FINISH
!insertmacro MUI_LANGUAGE Russian

Section
  StrCpy $GMODE 1
SectionEnd

Function INSTFILESLEAVE
    StrCmp $GMODE 1 0 +2
    SetAutoclose true
FunctionEnd

Function SHOWFINISH
${If} $GMODE == 1
   ShowWindow $mui.FinishPage.Run ${SW_HIDE}
   ${NSD_SetText} $mui.FinishPage.Title "Завершение работы Мастера создания файла ответов."
   ${NSD_SetText} $mui.FinishPage.Text "Файл ответов готов!"
${EndIf}
FunctionEnd

[wolkow70]

kotkovets,

Да, работает.

Я было пошел по другому пути, нашел где-то так:

Функция Show_PageFinish_custom

GetDlgItem $ R9 $ MUI_HWND 1203;

ShowWindow $ R9 $ {} SW_HIDE

MessageBox MB_OK $ R9

# MessageBox MB_OK $ MUI_HWND

FunctionEnd

Но нужно было узнать номер поля из ioSpecial.ini , но я у себя такого файла не нашел во временной папке NSIS.

[kotkovets]

Но нужно было узнать номер поля из ioSpecial.ini , »

MUI2 (nsdialogs.dll) не использует ioSpecial.ini,
его использует MUI (InstallOptions.dll) - ИМХО ! устаревшая и неудобная вещь(плаг).

[diakov]

kotkovets, подскажи

Код:

Section "-установка"
  ${If} $Check == 1
    ${If} $Radio == 1
    ${AndIf} ${RunningX64}
 CreateShortCut "$Desktop\${PRODUCT_NAME}.lnk" "$INSTDIR\TOTALCMD64.EXE"
 ${Else}
 CreateShortCut "$Desktop\${PRODUCT_NAME}.lnk" "$INSTDIR\TOTALCMD.EXE"
 ${EndIf}
  ${If} $Radio1 == 1
   CreateShortCut "$Desktop\${PRODUCT_NAME}.lnk" "$INSTDIR\TOTALCMD.EXE"
    ${EndIf}
       ${EndIf}
   SectionEnd

Вообщем надо что бы если отмечен чек и радиобутон то на системе х64 ярлык был TOTALCMD64.EXE а на х86 TOTALCMD.EXE, а если отмечен чек и радиобутон1 то на любой системе создавалсо TOTALCMD.EXE!

[kotkovets]

kotkovets, подскажи »

Код:

  ${If} $Check == 1
  ${AndIf} $Radio == 1
      ${If} ${RunningX64}
           MessageBox MB_OK "TOTALCMD64.EXE"
      ${Else}
           MessageBox MB_OK "TOTALCMD.EXE"
      ${EndIf}
  ${EndIf}

[diakov]

Эт я в курсе! Но надо чтобы еще если выбран другой радиобутон $Radio1 и этот же чекбокс и на х86 и на х64 создавался ярлык на файл TOTALCMD.EXE!

[kotkovets]

Эт я в курсе! Но надо чтобы еще если выбран другой радиобутон $Radio1 »

Код:

   
   ${If} $Check == 1
   ${AndIf} $Radio == 1
        ${If} ${RunningX64}
               MessageBox MB_OK "TOTALCMD64.EXE"
        ${Else}
               MessageBox MB_OK "TOTALCMD.EXE"
        ${EndIf}
   ${ElseIf} $Radio1 == 1
   ${AndIf} $Check == 1
           MessageBox MB_OK "Radio1: TOTALCMD.EXE"
   ${EndIf}

[diakov]

kotkovets, как сделать в nsDialogs такую рамку например вокруг групи чекбоксов?