[wolkow70]

вроде бы по русскому говорю... »

Не "по русскому", а "по русски" .
А сделал я все ориентируясь на пример из справки.

[wolkow70]

ну тут же очевидно, идет запись в реестр, сам макрос MUI_STARTMENU_WRITE_END »

Я так сделал, все работает как надо.

Код:

Section "Создать ярлыки в меню Пуск" StartMenu
${If} ${RunningX64}
SetRegView 64
SetShellVarContext all
!insertmacro MUI_STARTMENU_WRITE_BEGIN Application
CreateDirectory "$SMPROGRAMS\$StartMenuFolder"
CreateShortCut "$SMPROGRAMS\$StartMenuFolder\Удалить ${PRODUCT_NAME}.lnk" "$INSTDIR\Uninstall.exe" 0
CreateShortCut "$SMPROGRAMS\$StartMenuFolder\${PRODUCT_NAME}.lnk" "$INSTDIR\MyApp.exe"
!insertmacro MUI_STARTMENU_WRITE_END
SetRegView 32
${Else}
SetShellVarContext all
!insertmacro MUI_STARTMENU_WRITE_BEGIN Application
CreateDirectory "$SMPROGRAMS\$StartMenuFolder"
CreateShortCut "$SMPROGRAMS\$StartMenuFolder\Удалить ${PRODUCT_NAME}.lnk" "$INSTDIR\Uninstall.exe" 0
CreateShortCut "$SMPROGRAMS\$StartMenuFolder\${PRODUCT_NAME}.lnk" "$INSTDIR\MyApp.exe"
!insertmacro MUI_STARTMENU_WRITE_END
${EndIf}
SectionEnd

[kotkovets]

wolkow70, можно проще, зачем повторно прописывать команды?

Код:

Section "Создать ярлыки в меню Пуск" StartMenu
         ${IfThen} ${RunningX64} ${|}SetRegView 64${|}
         SetShellVarContext all
         !insertmacro MUI_STARTMENU_WRITE_BEGIN Application
         CreateDirectory "$SMPROGRAMS\$StartMenuFolder"
         CreateShortCut "$SMPROGRAMS\$StartMenuFolder\Удалить ${PRODUCT_NAME}.lnk" "$INSTDIR\Uninstall.exe" 0
         CreateShortCut "$SMPROGRAMS\$StartMenuFolder\${PRODUCT_NAME}.lnk" "$INSTDIR\MyApp.exe"
         !insertmacro MUI_STARTMENU_WRITE_END
        ${IfThen} ${RunningX64} ${|}SetRegView 32${|}
SectionEnd

[Olef2387]

Привет.

Продолжаю изучение NSIS... Задачка

Есть 20 компонентов. При установке юзер должен выбрать 1 из этих 20.
На эту тему нашёл информацию в справке. И всё работает.
Пример на 6 компонентах

читать дальше »

Код:

Section /o "Компонент №1" ID_1
SectionEnd

Section /o "Компонент №2" ID_2
SectionEnd

Section /o "Компонент №3" ID_3
SectionEnd

Section /o "Компонент №4" ID_4
SectionEnd

Section /o "Компонент №5" ID_5
SectionEnd

Section /o "Компонент №6" ID_6
SectionEnd

Function .onSelChange

!insertmacro StartRadioButtons $1
    !insertmacro RadioButton ${ID_1}
    !insertmacro RadioButton ${ID_2}
    !insertmacro RadioButton ${ID_3}
 !insertmacro RadioButton ${ID_4}
!insertmacro RadioButton ${ID_5}
    !insertmacro RadioButton ${ID_6}
  !insertmacro EndRadioButtons

FunctionEnd

Нужно дополнить...
1. Чтобы кнопка ДАЛЕЕ была неактивна пока не будет выбран 1 из компонентов.
2. Так как компонентов много, хотелось бы их объединить в группу... Команда SectionGroup объединяет их в группу, но там если галочку нажать - выбираются сразу все компоненты в группе... А у меня в данном случае только 1 компонент должен быть выбран.

Вот так. Извиняюсь, если опять что-то наиэлементарнейшее спросил

[kotkovets]

1. Чтобы кнопка ДАЛЕЕ была неактивна пока не будет выбран 1 из компонентов. 2. Так как компонентов много, хотелось бы их объединить в группу... Команда SectionGroup объединяет их в группу, но там если галочку нажать - выбираются сразу все компоненты в группе... А у меня в данном случае только 1 компонент должен быть выбран »

ну можно как-то так на скорую руку:

читать дальше »

Код:

OutFile "example.exe"

var hInst

!include "MUI2.nsh"

!insertmacro MUI_PAGE_WELCOME
   ;функция во время открытия странички компонентов
   !define MUI_PAGE_CUSTOMFUNCTION_SHOW COMPONENTS_SHOW
   ;---------------------------------------------------
!insertmacro MUI_PAGE_COMPONENTS
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_LANGUAGE Russian

;макрос проверки секций, если одна из секций отмечена возврат - 1, иначе - 0;
;в intsec - указываем количество секций в скрипте
!macro CheckSection intsec ret
   Push ${intsec}
   System::Store SR2
   ${For} $R0 1 $R2
       SectionGetFlags $R0 $R1
       ${IfThen} $R1 == 1 ${|}${Break}${|}
   ${Next}
   Push $R1
   System::Store L
   Pop ${ret}
!macroend


SubSection /e test IDS_1

Section  /o "Компонент №1" ID_1
SectionEnd

Section /o "Компонент №2" ID_2
SectionEnd

Section /o "Компонент №3" ID_3
SectionEnd

Section /o "Компонент №4" ID_4
SectionEnd

Section /o "Компонент №5" ID_5
SectionEnd

Section /o "Компонент №6" ID_6
SectionEnd

SubSectionEnd

Function .onSelChange
!insertmacro StartRadioButtons $1
    !insertmacro RadioButton ${ID_1}
    !insertmacro RadioButton ${ID_2}
    !insertmacro RadioButton ${ID_3}
    !insertmacro RadioButton ${ID_4}
    !insertmacro RadioButton ${ID_5}
    !insertmacro RadioButton ${ID_6}
  !insertmacro EndRadioButtons
  !insertmacro CheckSection 6 $R0
  StrCmp $R0 0 0 +2
  EnableWindow $hInst ${SW_HIDE} ;отключаем кнопку "установить"
  StrCmp $R0 1 0 +2
  EnableWindow $hInst ${SW_SHOW} ;включаем кнопку "установить"
FunctionEnd

Function .OnInit
  StrCpy $1 ${ID_1}
  SectionSetFlags ${IDS_1} ${SECTION_OFF} ;фиктивно отключаем группу
FunctionEnd

Function COMPONENTS_SHOW
  GetDlgItem $hInst $HWNDPARENT 1 ;находим HWND кнопки "установить"
  !insertmacro CheckSection 6 $R0
  StrCmp $R0 0 0 +2
  EnableWindow $hInst ${SW_HIDE} ;отключаем кнопку "установить"
  StrCmp $R0 1 0 +2
  EnableWindow $hInst ${SW_SHOW} ;включаем кнопку "установить"
FunctionEnd

[Olef2387]

Блестяще, что тут ещё сказать. Большое спасибо

Правда, компоненты в группе раскрыты, как можно сделать чтоб по умолчанию они были свёрнуты?
Команду SubSection /e test IDS_1
изменил на SubSection test IDS_1

всё равно раскрыты компоненты..

[kotkovets]

всё равно раскрыты компоненты.. »

вместо:

Код:

SectionSetFlags ${IDS_1} ${SECTION_OFF}

прописать:

Код:

SectionSetFlags ${IDS_1} -290

[wolkow70]

kotkovets,

Можете помочь в таком вопросе:

Работает такая конструкция:

ReadRegStr $R6 HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\Opera 11.64.1403" "InstallLocation"
RMDir /r "$R6"

Стоит задача найти директорию установки независимо от версии и удалить.

Пробую так:

Код:

Function EnumReg
${If} $5 == "Opera"
;
DetailPrint "Раздел реестра: $1"
DetailPrint "Имя параметра: $2"
DetailPrint "Тип параметра: $4"
DetailPrint "Значение параметра: $3"
StrCpy "$5" "$1"
StrCpy $0 StopRegFind
${EndIf}
FunctionEnd

Не срабатывает.


${RegFind} "${HKLM}\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall" "/T=REG_SZ /V=1" EnumReg

[kotkovets]

Не срабатывает. ${RegFind} "${HKLM}\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall" "/T=REG_SZ /V=1" EnumReg »

А с какого перепугу????!!! нет же в реестре ключа -SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\Opera
зато есть - SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\Opera****
---
Читайте и изучайте - StrCpy - там все по полочкам с примерами расписано.
---

Код:

Section
   ${RegFind} "${HKLM}\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall" "/T=REG_SZ /V=1" EnumReg
   MessageBox MB_OK "$5" IDOK
SectionEnd

Function EnumReg
   StrCpy $5 $1 5 52
   ${If} $5 == "Opera"
   ${AndIf} $2 == "InstallLocation"
     StrCpy $5 $3
     StrCpy $0 "StopRegFind"
   ${EndIf}
FunctionEnd

[bugmenotagain]

Доброй ночи. Пожалуйста, помогите разобраться. Пытаюсь с помощью плагина AccessControl зачистить хвосты от драйвера:

Код:

  AccessControl::GrantOnRegKey \
  HKLM "SYSTEM\CurrentControlSet\Enum\Root\LEGACY_SIMPLE" "(BU)" "Delete"

Код работает, но только под XP, а надо бы конечно мультиплатформу. Желательно бы XP-Vista-7.