[wolkow70]

Берёте прописываете свою команду на запись в реестр и сохраняете значение этой переменной во время установки: »

Я знаю , что так можно сделать, я не пойму зачем это делать, когда MUI2 сам должен это уметь.

Вот же там есть:

!macro MUI_STARTMENU_GETFOLDER ID VAR

!verbose push
!verbose ${MUI_VERBOSE}

;Get Start Menu folder from registry
;Can be called from the script in the uninstaller

!ifdef MUI_STARTMENUPAGE_${ID}_REGISTRY_ROOT & MUI_STARTMENUPAGE_${ID}_REGISTRY_KEY & MUI_STARTMENUPAGE_${ID}_REGISTRY_VALUENAME

ReadRegStr $mui.StartMenuPage.RegistryLocation "${MUI_STARTMENUPAGE_${ID}_REGISTRY_ROOT}" "${MUI_STARTMENUPAGE_${ID}_REGISTRY_KEY}" "${MUI_STARTMENUPAGE_${ID}_REGISTRY_VALUENAME}"

${if} $mui.StartMenuPage.RegistryLocation != ""
StrCpy "${VAR}" $mui.StartMenuPage.RegistryLocation
${else}
StrCpy "${VAR}" "${MUI_STARTMENUPAGE_${ID}_DEFAULTFOLDER}"
${endif}

!else

StrCpy "${VAR}" "${MUI_STARTMENUPAGE_${ID}_DEFAULTFOLDER}"

!endif

!verbose pop

!macroend

[K.A.V.]

wolkow70, у вас

Код:

!define MUI_STARTMENUPAGE_DEFAULTFOLDER

прописано? (может пустое значение пишет в реестр?)
Значение записывается вообще в реестр или нет?? Вы проверяли?
Где именно ошибка, может даже и запись в реестр не происходит, а мы тут читать пытаемся

[wolkow70]

Вот как прописано:

Var MENU

!insertmacro MUI_PAGE_WELCOME
!insertmacro MUI_PAGE_LICENSE "${pkgdir}\USB Safely Remove\License.txt"
!insertmacro MUI_PAGE_DIRECTORY
!insertmacro MUI_PAGE_COMPONENTS
!insertmacro MUI_PAGE_STARTMENU Application $MENU
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_PAGE_FINISH

Section "Создать группу ярлыков в меню Пуск" StartMenu
!insertmacro MUI_STARTMENU_WRITE_BEGIN Application
SetShellVarContext all
CreateDirectory "$SMPROGRAMS\$MENU"
CreateShortCut "$SMPROGRAMS\$MENU\${PRODUCT_NAME}.lnk" "$INSTDIR\USBSafelyRemove.exe"
CreateShortCut "$SMPROGRAMS\$MENU\Справка ${PRODUCT_NAME}.lnk" "$INSTDIR\USBSafelyRemoveRu.chm"
CreateShortCut "$SMPROGRAMS\$MENU\Удалить ${PRODUCT_NAME}.lnk" "$INSTDIR\uninstall.exe"

!insertmacro MUI_STARTMENU_WRITE_END
SectionEnd

В деинсталляторе:

!insertmacro MUI_STARTMENU_GETFOLDER "Application" $MENU
SetShellVarContext all
RMDir /r "$SMPROGRAMS\$MENU"

[K.A.V.]

Var MENU !insertmacro MUI_PAGE_WELCOME !insertmacro MUI_PAGE_LICENSE "${pkgdir}\USB Safely Remove\License.txt" !insertmacro MUI_PAGE_DIRECTORY !insertmacro MUI_PAGE_COMPONENTS !insertmacro MUI_PAGE_STARTMENU Application $MENU !insertmacro MUI_PAGE_INSTFILES !insertmacro MUI_PAGE_FINISH »

....
Вы мне скажите, у вас значение записывает в реестр?? Сами откройте редактор реестра и посмотрите!
На рабочем столе папка создаётся с именем в меню пуск??

У меня код рабочий...
Попробуйте вот так написать...

Код:

Var MENU

!define MUI_STARTMENUPAGE_DEFAULTFOLDER "Моя программа"

!insertmacro MUI_PAGE_WELCOME
 !insertmacro MUI_PAGE_LICENSE "${pkgdir}\USB Safely Remove\License.txt"
 !insertmacro MUI_PAGE_DIRECTORY
 !insertmacro MUI_PAGE_COMPONENTS
 !insertmacro MUI_PAGE_STARTMENU Application $MENU
 !insertmacro MUI_PAGE_INSTFILES
 !insertmacro MUI_PAGE_FINISH

у меня кстати MUI подключается, а не MUI2, может из-за этого работает, не знаю

[wolkow70]

Да, прописывается в реестр

Windows Registry Editor Version 5.00

[HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\MenuOrder\Start Menu2\Programs\Утилиты\USB Safely Remove]
"Order"=hex:08(большое значение).

[K.A.V.]

"Order"=hex:08(большое значение). »

Что-то у вас не сходится...
Записывается в реестр как будто это тип ключа REB_BINARY или REG_EXPAND_SZ

По умолчанию должно прописывать в:

Код:

Software\Microsoft\Windows\CurrentVersion\Uninstall

Смотрите значит ваш код, вы видно сами там что-то прописывали

[wolkow70]

В Software\Microsoft\Windows\CurrentVersion\Uninstall создается запись деинсталляции

HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\USB Safely Remove (но там пути создания ярлыков нет, только то, что прописано в секции создания деинсталлятора.).

Еще заметил, если создавать ярлыки в самом StartMenu, то стало удаляться, а если поместить в подгруппу "Утилиты" , то не удаляется. Значит $MENU не пустое.

[K.A.V.]

wolkow70, пропишите в скрипт запись значения $MENU при установке и при вызове деинсталлятора во внешний файл, чтобы понять, что у вас там назначается этой переменной...

[wolkow70]

Сделал так:

Section Uninstall
!insertmacro MUI_STARTMENU_GETFOLDER "Application" $MENU
MessageBox MB_OK "$MENU" IDOK
SetShellVarContext all
RMDir /r "$SMPROGRAMS\$MENU"

Пробовал ставить непосредственно в "Программы" - мессадж - в "$MENU" USB Safely Remove (при этом все нормально удаляется).
Ставлю в "Программы\Утилиты" - мессадж - тоже в "$MENU" USB Safely Remove (но при этом не удяляется). То есть, полный путь (относительно "Программы") не прописывается в "$MENU". Только сама папка.

Еще сделал проверку при установке:

Section "Создать группу ярлыков в меню Пуск" StartMenu

!insertmacro MUI_STARTMENU_WRITE_BEGIN Application

MessageBox MB_OK "$MENU" IDOK

;
SetShellVarContext all
CreateDirectory "$SMPROGRAMS\$MENU"

Все нормально в мессаджах записывается.

В первом случае:
USB Safely Remove

Во втором случае:
Утилиты\USB Safely Remove

[kotkovets]

kotkovets, внеси в шапку ссылку на плагины, либо я её не вижу, либо её там реально нет »

внес в: Расширение функциональности -> Плагины и полезности к NSIS
wolkow70, классический пример:

читать дальше »

Код:

 !include "MUI2.nsh"
  Name "Modern UI Test"
  OutFile "StartMenu.exe"
  InstallDir "$EXEDIR\Modern UI Test"

  Var StartMenuFolder

  !define MUI_STARTMENUPAGE_REGISTRY_ROOT "HKCU"
  !define MUI_STARTMENUPAGE_REGISTRY_KEY "Software\Modern UI Test"
  !define MUI_STARTMENUPAGE_REGISTRY_VALUENAME "Start Menu Folder"
  !insertmacro MUI_PAGE_STARTMENU Application $StartMenuFolder
  !insertmacro MUI_PAGE_INSTFILES
  
  !insertmacro MUI_UNPAGE_CONFIRM
  !insertmacro MUI_UNPAGE_INSTFILES
  !insertmacro MUI_LANGUAGE "English"

Section "Dummy Section"
  SetOutPath "$INSTDIR"
  WriteUninstaller "$INSTDIR\Uninstall.exe"
  SetShellVarContext all
  !insertmacro MUI_STARTMENU_WRITE_BEGIN Application
    CreateDirectory "$SMPROGRAMS\$StartMenuFolder"
    CreateShortCut "$SMPROGRAMS\$StartMenuFolder\Uninstall.lnk" "$INSTDIR\Uninstall.exe"
  !insertmacro MUI_STARTMENU_WRITE_END
SectionEnd

Section "Uninstall"
  !insertmacro MUI_STARTMENU_GETFOLDER Application $StartMenuFolder
    SetShellVarContext all
    MessageBox MB_OK "$SMPROGRAMS\$StartMenuFolder" IDOK
  DeleteRegKey HKCU "Software\Modern UI Test"
  Delete "$SMPROGRAMS\$StartMenuFolder\Uninstall.lnk"
  RMDir /r "$SMPROGRAMS\$StartMenuFolder"
  RMDir /r "$INSTDIR"
SectionEnd