[diakov]

kotkovets, вот такая ситуация, есть 5 чекбоксов, для 3 надо сделать так чтобы выбирался только один из них (языки установки).

[kotkovets]

Насколько я понял, имеются в виду радиобутоны на своей страничке
http://nsis.sourceforge.net/NsDialogs_FAQ
Объединяем чебоксы в "свои" группы переключений:

читать дальше »

Код:

!include "MUI2.nsh"

OutFile "radio"
ShowInstDetails Show

Page custom CreatePage
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_LANGUAGE "English"

Section ""
SectionEnd

var dlg
var radiobox1
var radiobox2
var radiobox3
var radiobox4
var radiobox5

Function CreatePage
    nsDialogs::Create 1018
    Pop $dlg
    ${NSD_CreateRadioButton} 0u 0u 120u 12u "RadioButton1"
    Pop $radiobox1
    ${NSD_CreateRadioButton} 0u 15u 120u 12u "RadioButton2"
    Pop $radiobox2
    ${NSD_SetState} $radiobox1 1
    ${NSD_AddStyle} $radiobox1 ${WS_GROUP}
    ;----
    ${NSD_CreateRadioButton} 0u 40u 120u 12u "RadioButton3"
    Pop $radiobox3
    ${NSD_CreateRadioButton} 0u 55u 120u 12u "RadioButton4"
    Pop $radiobox4
    ${NSD_CreateRadioButton} 0u 70u 120u 12u "RadioButton5"
    Pop $radiobox5
    ${NSD_SetState} $radiobox3 1
    ${NSD_AddStyle} $radiobox3 ${WS_GROUP}
    nsDialogs::Show
FunctionEnd

[diakov]

Ага тоесть оперировать, именно радиобутонами...ато я хотел так

[kotkovets]

...ато я хотел так »

большая куча кода и много потеряного времени...

[diakov]

будем пробовать...

[BuZzOFF]

kotkovets,
Опять я с поиском в файле
Есть файл "Adobe After Effects CS5*.log" (* - это дата).
Нужно найти строчку "Exit Code:", начинать искать с 27 строчки.
И чтоб когда нашлось вылазило окно "Exit Code: и то что после этого написано" "Ok" ( к примеру "Exit Code: 0 - No error")
Но при этом нужно оставить ещё вот это.

[kotkovets]

Нужно найти строчку "Exit Code:", начинать искать с 27 строчки. И чтоб когда нашлось вылазило окно "Exit Code: и то что после этого написано" "Ok" ( к примеру "Exit Code: 0 - No error") »

Макрос позваляет читать файл с нужной строки, заданный интервал строк

Код:

;27 - прочитать только 27 строку сначала файла
;-27 - прочитать только 27 строку с конца файла
;5:9 - прочитать с 5 по 9 строку включительно
;27:-1 - прочитать с 27 строки до конца

${LineFind} "txt.txt" "/NUL" "27:-1" "LineFind"

Function "LineFind"
  ;в переменную $R0 помещаем первые 10 символов строки
  StrCpy $R0 $R9 10 
  ;Exit Code: --> 10 символов
  ${If} $R0 == "Exit Code:"
       MessageBox MB_OK "$R9" IDOK
       ;StrCpy $0 StopLineFind ;если нужно делаем прерывание чтения
  ${EndIf} 
  Push $0
FunctionEnd

[diakov]

kotkovets, такой вопрос

Код:

Section "Установить надстройку"
   ${If} $Check5 == 1
    CreateDirectory "$PROGRAMFILES\Minilyrics"
     SetOutPath "$PROGRAMFILES\Minilyrics"
     File /r "D:\Aimp\MiniLyric\*.*"
     CreateDirectory "$APPDATA\MiniLyrics"
  SetOutPath "$APPDATA\MiniLyrics"
    File /r "D:\Aimp\MiniLyrics\*.*"
     ${If} ${RunningX64}
     SetOutPath "$INSTDIR\Plugins"
     File /r "D:\Aimp\gen_MiniLyrics.dll"
     File /r "D:\ystanovka\MLPlugin.ini"
     ${Else}
     SetOutPath "$INSTDIR\Plugins"
     File /r "D:\Aimp\MLPlugin.ini"
     File /r "D:\Aimp\gen_MiniLyrics.dll"
     ${EndIf}
         SetShellVarContext all
     WriteRegStr HKCU "MUI_LANGDLL_REGISTRY_KEY" "MUI_LANGDLL_REGISTRY_VALUENAME" "1033"
     WriteRegStr HKCU "Software\MiniLyrics" "InstallerLanguage" "1033"
CreateShortCut "$SMPROGRAMS\${PRODUCT_NAME}\Запустить Minilyrics.lnk" "$PROGRAMFILES\Minilyrics\Minilyrics.exe"
  ${EndIf}
SectionEnd

Не создает папку $APPDATA\MiniLyrics и не копирует туда D:\Aimp\MiniLyrics\*.* что тут не так?

[kotkovets]

такой вопрос

Правильнее так:

читать дальше »

Код:

Section "Установить надстройку"
   SetShellVarContext all 
   ${If} $Check5 == 1
       SetOutPath "$PROGRAMFILES\Minilyrics"
       File /r "D:\Aimp\MiniLyric\*.*"
       SetOutPath "$APPDATA\MiniLyrics"
       File /r "D:\Aimp\MiniLyrics\*.*"
       ${If} ${RunningX64}
          SetOutPath "$INSTDIR\Plugins"
          File "D:\Aimp\gen_MiniLyrics.dll"
          File "D:\ystanovka\MLPlugin.ini"
       ${Else}
          SetOutPath "$INSTDIR\Plugins"
          File "D:\Aimp\MLPlugin.ini"
          File "D:\Aimp\gen_MiniLyrics.dll"
       ${EndIf}
       WriteRegStr HKCU "MUI_LANGDLL_REGISTRY_KEY" "MUI_LANGDLL_REGISTRY_VALUENAME" "1033"
       WriteRegStr HKCU "Software\MiniLyrics" "InstallerLanguage" "1033"
       CreateShortCut "$SMPROGRAMS\${PRODUCT_NAME}\Запустить Minilyrics.lnk" "$PROGRAMFILES\Minilyrics\Minilyrics.exe"
  ${EndIf}
SectionEnd

А может надо

Код:

SetShellVarContext current

[diakov]

Счас попробую...