CMD/BAT - [решено] Запуск программы с разными параметрами

El Sanchez · Конфигурация компьютера

root221, на примере Notepad

Код:

@Echo Off
SetLocal
Rem _Number=Parameters;Description
Set _1=%WinDir%\setuplog.txt;Открыть setuplog.txt
Set _2=%WinDir%\setupact.log;Открыть setupact.log

For /F %%A In ('Set _') Do Set /A Cnt+=1
For /L %%A In (1,1,%Cnt%) Do Call Echo %%A. %%_%%A:*;=%%
Echo:
Set /P "i=Выберите пункт меню: "
If Defined _%i% For /F "Tokens=2 Delims==;" %%A In ('Set _%i%') Do Start "" "Notepad" "%%~A"

upd:
Доработал вывод меню, а то при количестве пунктов больше 100 были бы приколы

root221 · Отправлено: **23:33, 25-01-2012** | #3

Если не трудно, переделай, что бы в консоли маргал только курсор а параметры видны небыли.
Сам выберу по памяти эти параметры, просто слишком большой список получается...

в консоли вид , желательно такой

Код:

Выберите параметр: _

El Sanchez · Конфигурация компьютера

Цитата root221:

что бы в консоли маргал только курсор а параметры видны небыли »

root221, удалить\закомментировать строки:

Код:

For /F %%A In ('Set _') Do Set /A Cnt+=1
For /L %%A In (1,1,%Cnt%) Do Call Echo %%A. %%_%%A:*;=%%
Echo:

Либо батник можно упростить:

Код:

@Echo Off
SetLocal
Rem _Number=Parameters
Set _1=%WinDir%\setuplog.txt
Set _2=%WinDir%\setupact.log

Set /P "i=Выберите параметр: "
If Defined _%i% Call Start "" "Notepad" "%%_%i%%%"

root221 · Отправлено: **17:24, 02-02-2012** | #5

ПОМОГИТЕ)

Код:

@echo off
:eom
Set _1=123456789

Set /P "i=     ‚ўҐ¤ЁвҐ *®¬Ґа Є®¬ЇмовҐа*: "

If Defined _%i% (
Call program.exe -s beggin"" "%%_%i%%%" > nul
Endlocal
goto EOM
) else (
Test.vbs
goto EOM
)

В общем мне нужно сделать что бы можно было ввести Test и выполнялся Test.vbs

В данном примере у меня он просто через Else. - то есть если просто не ввести ничего и нажать Ввод то выполнится Test.vbs а если ввести команду 1 то выполнится

Код:

program.exe -s beggin 123456789

Anonymоus · Отправлено: **19:03, 02-02-2012** | #6

Код:

@Echo Off
SetLocal
Rem _Number=Parameters
Set _1=%WinDir%\setuplog.txt
Set _2=%WinDir%\setupact.log

:EOM
Set i=
Set /P "i=Выберите параметр: "
If /I %i%==test (test.vbs&Cls&GoTo :EOM)
If Defined _%i% (Call Start "" "Notepad" "%%_%i%%%") Else (Cls&GoTo :EOM)

Отредактировал пост, сделал так, как вам нужно. Если ввести test - выполнится test.vbs и произойдет возврат к выбору пункта, если ввести нужный номер - запустится программа с этими параметрами, если ввести неправильный номер - снова возврат к выбору пункта.

root221 · Отправлено: **19:16, 02-02-2012** | #7

Anonymоus, свой пост отредактировал пока вы отвечали(((....

В общем нужно то что сейчас написано в 5 посту.

root221 · Отправлено: **19:51, 02-02-2012** | #8

Спасибо, я знал что вы мне сможете помочь.

Если не трудно, добавьте ещё, что бы если просто ничего не введёшь и нажмёшь, то что бы писало через cls, вы не ввели ничего и возврат на GoTo :EOM.

Anonymоus · Отправлено: **19:58, 02-02-2012** | #9

Сделано.

Код:

@Echo Off
SetLocal
Rem _Number=Parameters
Set _1=%WinDir%\setuplog.txt
Set _2=%WinDir%\setupact.log

:EOM
Set i=
Set /P "i=Выберите параметр: "
If "%i%"=="" Cls&Echo Вы ничего не ввели.&GoTo :EOM
If /I %i%==test (test.vbs&Cls&GoTo :EOM)
If Defined _%i% (Call Start "" "Notepad" "%%_%i%%%") Else (Cls&GoTo :EOM)