[wolkow70]

Так правильно будет? »

Все скопом регистрировать не лучший вариант. Для каждого расширения лучше отдельную секцию делать. Потом меньше проблем с деинсталляцией будет.
Вот посмотрите как у меня в скрипте Winamp сделано:
http://forum.oszone.net/post-1754972-257.html

[diakov]

Для каждого расширения лучше отдельную секцию делать. »

мне не подходит сколько чекбоксов не влезит))))

Потом меньше проблем с деинсталляцией будет. »

Операционная система Windows перестает считать тип файла ассоциированным, если в реестре отсутствует описание приложения-обработчика. Таким образом, применительно к вышеуказанному примеру, достаточно удалить раздел HKLM\Software\Classes\Aimp.File для снятия всех ассоциация при удалении Aimp. Можно эту операцию оформить вызовом команды DeleteRegKey в секции деисталлятора:

Код:

Section Uninstall 
    ... 
    DeleteRegKey HKLM "Software\Classes\Aimp.File" 
    ... 
    SectionEnd

[kotkovets]

и хочу чтобы был чекбокс Установить ассоциации для аудио файлов, тоесть пользователь мог выбрать ассоциировать или просто установить аимп... »

Макрос предполагает аргумент, в качестве передаваемого расширения файла для ассоциации с приложением

читать дальше »

Код:

!macro RegisterExtension extenstion 
WriteRegStr HKLM "Software\Classes\.${extenstion}" "" "Aimp.File" 
WriteRegStr HKLM "Software\Classes\Aimp.File" "" "Aimp Media File" 
WriteRegStr HKLM "Software\Classes\Aimp.File\DefaultIcon" "" "$INSTDIR\Aimp.exe,1" 
WriteRegStr HKLM "Software\Classes\Aimp.File\shell" "" "Play" 
WriteRegStr HKLM "Software\Classes\Aimp.File\shell\Play" "" "&Play in Aimp" 
WriteRegStr HKLM "Software\Classes\Aimp.File\shell\Play\command" "" "$\"$INSTDIR\Aimp.exe$\" $\"%1$\"" 
WriteRegStr HKLM "Software\Classes\Aimp.File\shell\open\command" "" "$\"$INSTDIR\Aimp.exe$\" $\"%1$\"" 
WriteRegStr HKLM "Software\Classes\Aimp.File\shell\ListBookmark" "" "Add to Aipm's &Bookmark list" 
WriteRegStr HKLM "Software\Classes\Aimp.File\shell\ListBookmark\command" "" "$\"$INSTDIR\Aimp.exe$\"/BOOKMARK $\"%1$\"" 
WriteRegStr HKLM "Software\Classes\Aimp.File\shell\Enqueue" "" "&Enqueue in Aipm" 
WriteRegStr HKLM "Software\Classes\Aimp.File\shell\Enqueue\command" "" "$\"$INSTDIR\Aimp.exe$\"/ADD $\"%1$\"" 
; ставим приложением по умолчанию для текущего пользователя 
DeleteRegKey HKCU "Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.${extenstion}\UserChoice" 
WriteRegStr HKCU "Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.${extenstion}\UserChoice" "Progid" "Aimp.File" 
!macroend

И запуск макроса:

Код:

!insertmacro RegisterExtension mp3
!insertmacro RegisterExtension acc
;и так далее

Все скопом регистрировать не лучший вариант. Для каждого расширения лучше отдельную секцию делать. »

wolkow70 прав, но хозяин барин, хочет все - пожалуйста

[diakov]

Тоесть так

Код:

Section "ассоциации для аудио файлов"
${If} $Check == 1
  SetShellVarContext all
!insertmacro RegisterExtension mp3
!insertmacro RegisterExtension acc
;и так далее
${EndIf}

Я правильно понял?

[kotkovets]

diakov, Правильно, пишете запуск макроса, столько, сколько вам нужно ассоциаций с связанным приложением

мне не подходит сколько чекбоксов не влезит)))) »

Всегда можно нарисовать еще свои странички, но это будет слишком сложно для вас.

[diakov]

окейно, счас бду пробовать)

[wolkow70]

Операционная система Windows перестает считать тип файла ассоциированным, если в реестре отсутствует описание приложения-обработчика. Таким образом, применительно к вышеуказанному примеру, достаточно удалить раздел HKLM\Software\Classes\Aimp.File для снятия всех ассоциация при удалении Aimp. Можно эту операцию оформить вызовом команды DeleteRegKey в секции деисталлятора »

Но сами то расширения файлов при этом останутся по умолчанию закрепленными за отсутствующим приложением, а это мусор в реестре, который в конце концов обманывает и саму операционную систему.
Считаю, что нужно удалять значения расширений по умолчанию, причем в обеих разделах реестра.
Кроме того, в windows 7 есть еще значения ключей, передающие системе сведения о программах, связанных с определенными расширениями.

[diakov]

kotkovets, как теперь изменить иконку для зарегистрированных файлов?

[kotkovets]

изменить иконку для зарегистрированных файлов? »

После применения всех регистраций,обновляем кэш иконок, пишем:

Код:

${RefreshShellIcons}

Этот макрос описан в FileFunc.nsh, естественно если этот хедер не подключен к телу скрипта, то в самом начале пишем:

Код:

!include "FileFunc.nsh"

[diakov]

Что то я не правильно делаю смотри:

Код:

!macro RegisterExtension extenstion
  SetShellVarContext all
WriteRegStr HKLM "Software\Classes\.mp3" "" "Aimp.File"
WriteRegStr HKLM "Software\Classes\Aimp.File" "" "Aimp Media File"
WriteRegStr HKLM "Software\Classes\Aimp.File\DefaultIcon" "" "$INSTDIR\AIMP2.exe,1"
WriteRegStr HKLM "Software\Classes\Aimp.File\shell" "" "Play"
WriteRegStr HKLM "Software\Classes\Aimp.File\shell\Play" "" "&Play in Aimp"
WriteRegStr HKLM "Software\Classes\Aimp.File\shell\Play\command" "" "$\"$INSTDIR\AIMP2.exe$\" $\"%1$\""
WriteRegStr HKLM "Software\Classes\Aimp.File\shell\open\command" "" "$\"$INSTDIR\AIMP2.exe$\" $\"%1$\""
WriteRegStr HKLM "Software\Classes\Aimp.File\shell\ListBookmark" "" "Add to Aipm's &Bookmark list"
WriteRegStr HKLM "Software\Classes\Aimp.File\shell\ListBookmark\command" "" "$\"$INSTDIR\AIMP2.exe$\"/BOOKMARK $\"%1$\""
WriteRegStr HKLM "Software\Classes\Aimp.File\shell\Enqueue" "" "&Enqueue in Aipm"
WriteRegStr HKLM "Software\Classes\Aimp.File\shell\Enqueue\command" "" "$\"$INSTDIR\AIMP2.exe$\"/ADD $\"%1$\""
; ставим приложением по умолчанию для текущего пользователя
DeleteRegKey HKCU "Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.mp3\UserChoice"
WriteRegStr HKCU "Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.mp3\UserChoice" "Progid" "Aimp.File"
${RefreshShellIcons}
!macroend

А иконки стают вот такими