[kylt_lichnosti]

И опять добрый всем день.
Вопрос - можно ли как то реализовать задержку? По типу Wait и время в миллисекундах например.

Запускаю инсталятор в сайленте из программы, что бы он ее обновил. И нет твердой уверенности, что она успеет закрыться?

[kotkovets]

Вопрос - можно ли как то реализовать задержку? По типу Wait и время в миллисекундах например »

Sleep 3000 - установщик отправится в паузу на 3с
Если нужно ожидать завершение чужого процесса, то в шапке темы найдите
ссылку на справочник по NSIS и в справочнике найдете:
Работа с процессами с помощью NSIS>>Ожидание завершения запущенного процесса заданное время

[kylt_lichnosti]

kotkovets, большое спасибо - то что нужно.
Странно - я вчера час по инету шарился - не нашел.

[diakov]

Доброго времени суток уважаемые господа!) Возникла идея перепаковать ccleaner под себя и интегрировать CCEnhancer

Вообщем все нормально с х86, а с х64 траблы

вот скрин идеи



вот код

Код:

!define PRODUCT_NAME "CCleaner"
!define PRODUCT_VERSION "3.1.4.1616"
!define PRODUCT_UNINST_KEY "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCT_NAME}"
!define PRODUCT_UNINST_ROOT_KEY "HKLM"
!include "MUI2.nsh"
!include "x64.nsh"
SetCompressor /SOLID lzma

!define MUI_ABORTWARNING
!define MUI_ICON "D:\ccleaner.ico"
!define MUI_UNICON "D:\ccleaner.ico"
!define MUI_HEADERIMAGE
!define MUI_CUSTOMFUNCTION_GUIINIT myGuiInit
!define BRANDING "RePack by D!akov"

var dlg
var Label
var Check
var Check1
var Check2
var Check3
var CheckBox
var CheckBox1
var CheckBox2
var CheckBox3
var Radio
var Radio1
var RadioButton
var RadioButton1
var ImageHandle
var Image
Var product_version

!insertmacro MUI_PAGE_WELCOME
Page custom PageInit PageDestroy
!insertmacro MUI_PAGE_DIRECTORY
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_PAGE_FINISH
!insertmacro MUI_UNPAGE_CONFIRM
!insertmacro MUI_UNPAGE_INSTFILES
!insertmacro MUI_UNPAGE_FINISH
!insertmacro MUI_LANGUAGE "Russian"

; Описание фаqла
VIProductVersion "${PRODUCT_VERSION}"
  VIAddVersionKey /LANG=${LANG_Russian} "CompanyName" "RePack by D!akov"
  VIAddVersionKey /LANG=${LANG_Russian} "FileDescription" "${PRODUCT_NAME} ${PRODUCT_VERSION}"
  VIAddVersionKey /LANG=${LANG_Russian} "FileVersion" "${PRODUCT_VERSION}"
; Конец описания файла

Name "${PRODUCT_NAME}"
Caption "Установка ${PRODUCT_NAME} ${PRODUCT_VERSION}"
UninstallCaption "Удаление ${PRODUCT_NAME} ${PRODUCT_VERSION}"
OutFile "${PRODUCT_NAME}-${PRODUCT_VERSION}.exe"
InstallDir "$PROGRAMFILES\CCleaner"
;ShowInstDetails show
;ShowUnInstDetails show
BrandingText "${BRANDING}"

Var SysDrive
Function .onInit
    ${If} ${RunningX64}
        StrCpy $product_version "CCleaner64 x64"
    ${Else}
        StrCpy $product_version "CCleaner x86"
    ${EndIf}
    StrCpy $SysDrive $WINDIR 2
    StrCpy $INSTDIR "$SysDrive\$PROGRAMFILES\CCleaner"
FunctionEnd


Function .onInit
  InitPluginsDir ;иницилизируем рабочую папку, куда будут распакованы картинки
  File "/oname=$PLUGINSDIR\nsis-r.bmp" "${NSISDIR}\Contrib\Graphics\Header\nsis-r.bmp"
  File "/oname=$PLUGINSDIR\orange-r.bmp" "${NSISDIR}\Contrib\Graphics\Header\orange-r.bmp"
FunctionEnd

Function PageInit
  !insertmacro MUI_HEADER_TEXT "Выбор типа и компонентов установки" "..."
  nsDialogs::Create 1018
  Pop $dlg
  ${NSD_CreateLabel} 0u 0u 120u 12u "Пожалуйста, сделайте выбор:"
  Pop $Label
  ;;
  ${NSD_CreateRadioButton} 0u 14u 150u 12u "Установка CCleaner 3.14.1616"
  Pop $RadioButton
  ${NSD_SetState} $RadioButton 1            ;делаем радиобутон отмеченным
  ${NSD_OnClick} $RadioButton RadioButton   ;событие отметки радиобутона
  ;;
  ${NSD_CreateRadioButton} 0u 28u 160u 12u "Распаковка CCleaner 3.14.1616"
  Pop $RadioButton1
  ${NSD_OnClick} $RadioButton1 RadioButton1 ;событие отметки радиобутона
  ;;
  ${NSD_CreateCheckBox} 0u 85u 120u 12u "Ярлык(и) на рабочем столе"
  Pop $CheckBox
  ${NSD_SetState} $CheckBox 1
  ;;
  ${NSD_CreateCheckBox} 0u 100u 100u 12u "Ярлыки в меню «Пуск»"
  Pop $CheckBox1
  ${NSD_SetState} $CheckBox1 1
  ;;;;;;;;;;
   ${NSD_CreateCheckBox} 0u 115u 300u 12u "Добавить пункт меню корзины 'Открыть/Запустить CCleaner'"
  Pop $CheckBox2
  ${NSD_SetState} $CheckBox2 1
  ;;;;;;;;
   ${NSD_CreateCheckBox} 0u 70u 120u 12u "Установить CCEnhancer"
  Pop $CheckBox3
  ${NSD_SetState} $CheckBox3 1
  ;;;;;;;;;;;;4
  ${NSD_CreateBitmap} 180u 0u 100% 100% "" ;создаем контрол для картинок
  Pop $Image
  ${NSD_SetImage} $Image "$PLUGINSDIR\nsis-r.bmp" $ImageHandle ;загружаем картинку
  nsDialogs::Show
  ${NSD_FreeImage} $ImageHandle ;удаляем картинку
FunctionEnd

Function switching
  ${NSD_GetState} $RadioButton $Radio ;снимаем статус отметки радиобуттона
  ${If} $Radio == 1                   ;если радибуттон "Установка обычной версии" отмеченный то...
      EnableWindow $CheckBox 1
      EnableWindow $CheckBox1 1
      EnableWindow $CheckBox2 1
       EnableWindow $CheckBox3 1
      ${NSD_SetState} $CheckBox 1
      ${NSD_SetState} $CheckBox1 1
      ${NSD_SetState} $CheckBox2 1
      ${NSD_SetState} $CheckBox3 1
      ${NSD_FreeImage} $ImageHandle                   ;удаляем картинку
      ${NSD_SetImage} $Image "$PLUGINSDIR\nsis-r.bmp" $ImageHandle  ;загружаем картинку
  ${Else}                          ;если радибуттон "Установка обычной версии" неотмеченный то...
      EnableWindow $CheckBox 0     ;затеняем чекбокс
      EnableWindow $CheckBox1 0    ;затеняем чекбокс
      EnableWindow $CheckBox2 0    ;затеняем чекбокс
      EnableWindow $CheckBox3 0
      ${NSD_SetState} $CheckBox 0  ;делаем чекбокс неотмеченным
      ${NSD_SetState} $CheckBox1 0 ;делаем чекбокс неотмеченным
      ${NSD_SetState} $CheckBox2 0
      ${NSD_SetState} $CheckBox3 0
      ${NSD_FreeImage} $ImageHandle               ;удаляем картинку
      ${NSD_SetImage} $Image "$PLUGINSDIR\orange-r.bmp" $ImageHandle  ;загружаем картинку
  ${EndIf}
FunctionEnd
 ;функции события отметки радиобуттонов
Function RadioButton
  Pop $RadioButton
  Call switching
FunctionEnd
Function RadioButton1
  Pop $RadioButton1
  Call switching
FunctionEnd

Function PageDestroy
  ;функция которая выполняется при закрытии кастомной станички
  ;снимаем статусы отметок радиобуттонов и чекбоксов
  ${NSD_GetState} $RadioButton $Radio
  ${NSD_GetState} $RadioButton1 $Radio1
  ${NSD_GetState} $CheckBox $Check
  ${NSD_GetState} $CheckBox1 $Check1
  ${NSD_GetState} $CheckBox2 $Check2
  ${NSD_GetState} $CheckBox3 $Check3
FunctionEnd

Section "-Обычная установка"
  ${If} $Radio == 1
  SetOutPath "$INSTDIR"
${If} ${RunningX64}
File /r "D:\CCleaner\*.*"
 CreateDirectory "${PRODUCT_NAME}"
 SetShellVarContext all
;здесь я так понимаю ключи которые надо прописать при установке на х64, которые я получаю путем сравнивания снимков системы до и после инсталяции на 64 битную ось ССклинера
  WriteUninstaller "$INSTDIR\Удалить CCleaner.exe"
  WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayName" "$INSTDIR\CCleaner.exe"
  WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "UninstallString" "$INSTDIR\Удалить CCleaner.exe"
  WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayVersion" "${PRODUCT_VERSION}"
  WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayIcon" "${PRODUCT_VERSION}"
  ${Else}
  File /r "D:\CCleaner1\*.*"
 CreateDirectory "${PRODUCT_NAME}"
 SetShellVarContext all
WriteRegStr HKEY_CURRENT_USER "Software\Piriform" "" ""
WriteRegStr HKEY_CURRENT_USER "Software\Piriform\CCleaner" "UpdateKey" "12/21/2011 03:28:56 PM"
WriteRegStr HKEY_CURRENT_USER "Software\Piriform\CCleaner" "Language" "1049"
WriteRegStr HKEY_LOCAL_MACHINE "SOFTWARE\Classes\cclaunch" "" "URL: CCleaner Protocol"
WriteRegStr HKEY_LOCAL_MACHINE "SOFTWARE\Classes\cclaunch" "URL Protocol" ""
WriteRegStr HKEY_LOCAL_MACHINE "SOFTWARE\Classes\cclaunch\shell" "" ""
WriteRegStr HKEY_LOCAL_MACHINE "SOFTWARE\Classes\cclaunch\shell\open" "" ""
WriteRegStr HKEY_LOCAL_MACHINE "SOFTWARE\Classes\cclaunch\shell\open\command" "" "$\"$PROGRAMFILES\CCleaner\ccleaner.exe$\" /%1"
WriteRegDWORD HKEY_LOCAL_MACHINE "SOFTWARE\Microsoft\Tracing\ccsetup314_RASAPI32" "EnableFileTracing" 0x0
WriteRegDWORD HKEY_LOCAL_MACHINE "SOFTWARE\Microsoft\Tracing\ccsetup314_RASAPI32" "EnableConsoleTracing" 0x0
WriteRegDWORD HKEY_LOCAL_MACHINE "SOFTWARE\Microsoft\Tracing\ccsetup314_RASAPI32" "FileTracingMask" 0xffff0000
WriteRegDWORD HKEY_LOCAL_MACHINE "SOFTWARE\Microsoft\Tracing\ccsetup314_RASAPI32" "ConsoleTracingMask" 0xffff0000
WriteRegDWORD HKEY_LOCAL_MACHINE "SOFTWARE\Microsoft\Tracing\ccsetup314_RASAPI32" "MaxFileSize" 0x100000
WriteRegBin HKEY_LOCAL_MACHINE "SOFTWARE\Microsoft\Tracing\ccsetup314_RASAPI32" "FileDirectory" 2500770069006e0064006900720025005c00740072006100630069006e0067000000
  WriteUninstaller "$INSTDIR\Удалить CCleaner.exe"
  WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayName" "$INSTDIR\CCleaner.exe"
  WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "UninstallString" "$INSTDIR\Удалить CCleaner.exe"
  WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayVersion" "${PRODUCT_VERSION}"
  WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayIcon" "${PRODUCT_VERSION}"
  ${EndIf}
      ;;;
      ;тут пишем все команды при обычной установке
      ;DetailPrint "Обычная установка"
      ;;;
  ${EndIf}
SectionEnd

Section "-Распаковка портативной версии"
  ${If} $Radio1 == 1
  SetOutPath "$INSTDIR"
  File /r "D:\CCleanerPortable\*.*"
   SetShellVarContext all
      ;тут пишем все команды при распаковки портативной версии
      MessageBox MB_OK "Портативная версия ${PRODUCT_NAME} ${PRODUCT_VERSION} распакована в текущую папку."
      ;;;
  ${EndIf}
SectionEnd

Section "-Ярлыки"
  ${If} $Check == 1
 CreateShortCut "$Desktop\${PRODUCT_NAME}.lnk" "$INSTDIR\CCleaner.exe"
      ;;;
      DetailPrint "Ярлык на рабочий стол"
      ;;;

  ${EndIf}
  ${If} $Check1 == 1
CreateDirectory "$SMPROGRAMS\${PRODUCT_NAME}"
CreateShortCut "$SMPROGRAMS\${PRODUCT_NAME}\${PRODUCT_NAME}.lnk" "$INSTDIR\CCleaner.exe"
CreateShortCut "$SMPROGRAMS\${PRODUCT_NAME}\Удалить ${PRODUCT_NAME}.lnk" "$INSTDIR\Удалить CCleaner.exe"
      ;;;
      DetailPrint "Ярлык в меню Пуск"
      ;;;
      ${EndIf}
SectionEnd

Section "-Надстройка"
   ${If} $Check3 == 1
SetOutPath "$INSTDIR"
File /r "D:\iNTEGER\*.*"
SetShellVarContext all
CreateShortCut "$SMPROGRAMS\${PRODUCT_NAME}\Запустить CCEnhancer.lnk" "$INSTDIR\CCEnhancer.exe"
      ;;;
  ${EndIf}
SectionEnd

Section "-Корзина"
   ${If} $Check2 == 1
WriteRegDWORD HKEY_LOCAL_MACHINE "SOFTWARE\Classes\CLSID\{645FF040-5081-101B-9F08-00AA002F954E}\shell\Открыть CCleaner..." "CCRBType" 0x2
WriteRegStr HKEY_LOCAL_MACHINE "SOFTWARE\Classes\CLSID\{645FF040-5081-101B-9F08-00AA002F954E}\shell\Открыть CCleaner...\command" "" "$PROGRAMFILES\CCleaner\CCleaner.exe"
WriteRegDWORD HKEY_LOCAL_MACHINE "SOFTWARE\Classes\CLSID\{645FF040-5081-101B-9F08-00AA002F954E}\shell\Запустить CCleaner" "CCRBType" 0x1
WriteRegStr HKEY_LOCAL_MACHINE "SOFTWARE\Classes\CLSID\{645FF040-5081-101B-9F08-00AA002F954E}\shell\Запустить CCleaner\command" "" "$PROGRAMFILES\CCleaner\CCleaner.exe /AUTO"
      ;;;
  ${EndIf}
SectionEnd

Section Uninstall
  RMDir /r "$INSTDIR"
  SetShellVarContext all
  RMDir /r "$SMPROGRAMS\${PRODUCT_NAME}"
  Delete  "$Desktop\${PRODUCT_NAME}.lnk"
  Delete "$SMPROGRAMS\${PRODUCT_NAME}\${PRODUCT_NAME}.lnk"
  Delete "$SMPROGRAMS\${PRODUCT_NAME}\Удалить ${PRODUCT_NAME}.lnk"
  DeleteRegKey HKLM "SOFTWARE\Classes\CLSID\{645FF040-5081-101B-9F08-00AA002F954E}\shell\Открыть CCleaner..."
  DeleteRegKey HKLM "SOFTWARE\Classes\CLSID\{645FF040-5081-101B-9F08-00AA002F954E}\shell\Открыть CCleaner...\command"
  DeleteRegKey HKLM "SOFTWARE\Classes\CLSID\{645FF040-5081-101B-9F08-00AA002F954E}\shell\Запустить CCleaner"
  DeleteRegKey HKLM "SOFTWARE\Classes\CLSID\{645FF040-5081-101B-9F08-00AA002F954E}\shell\Запустить CCleaner\command"
  DeleteRegKey ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}"
  DeleteRegKey HKCU "Software\Piriform"
  DeleteRegKey HKLM "SOFTWARE\Classes\cclaunch"
  DeleteRegKey HKLM "SOFTWARE\Microsoft\Tracing\ccsetup314_RASAPI32"
MessageBox MB_OK "Удаление ${PRODUCT_NAME} ${PRODUCT_VERSION} успешно завершено!"
  SetAutoClose true
SectionEnd

Прочитал статью Создание своего инсталлятора на NSIS. Один инсталлятор для x86 и х64 систем сразу создал

Код:

!include "x64.nsh" 
Var product_version

-----

Var SysDrive 
Function .onInit 
    ${If} ${RunningX64} 
        StrCpy $product_version "0.18 x64" 
    ${Else}     
        StrCpy $product_version "0.21 x86" 
    ${EndIf} 
    StrCpy $SysDrive $WINDIR 2 
    StrCpy $INSTDIR "$SysDrive\Greylink" 
FunctionEnd

-------

Section ""  
    SetOutPath "$INSTDIR" 
    ${If} ${RunningX64}   
        File /r "${pkgdir}\greylink\x64\" 
    ${Else}     
        File /r "${pkgdir}\greylink\x86\" 
    ${EndIf}

-------
Вообщем все в коде но не фурычит....
Суть проблемы такова на х64 не создаються контекст корзины запустить/открыть Ссклеанер, и ставиться соотвественно CCleaner.exe а не CCleaner64.exe вот....

Как допустим перепаковывать такие проги...я допустим так распаковал на х86 машину а потом на х64, потом просканировал реестр сравнил снимки со старыми, а теперь как реализовать если х86 то ставить файлы х86 + записи реестра под х86, а если х64 то ставить файлы х64 + записи реестра под х64.

Уважаемый kotkovets обьясните пожалуйста на примере CCleaner! Спасибо за помощь!

[kotkovets]

если х86 то ставить файлы х86 + записи реестра под х86, а если х64 то ставить файлы х64 + записи реестра под х64 »

Ну все же очевидно:

читать дальше »

Код:

Section 
${If} ${RunningX64}   
        SetOutPath "$ProgramFiles64\greylink"
        File /r "${pkgdir}\greylink\x64\"
        ;;
        ;до конструкции Else - будет выполнено в х64 Windows
        ;;
${Else}
        SetOutPath "$ProgramFiles\greylink"
        File /r "${pkgdir}\greylink\x86\"
        ;;
        ;до конструкции EndIf - будет выполнено в х32 Windows
        ;;
${EndIf}
SectionEnd

Скачайте в шапке темы справочник по NSIS - много полезного найдете!
» SetRegView: использование реестра от разрядности ОС

Код:

!include x64.nsh
;;
Section
${If} ${RunningX64}
   SetRegView 32
   ReadRegStr $0 HKLM Software\Microsoft\Windows\CurrentVersion ProgramFilesDir
   MessageBox MB_OK $0 # C:\Program Files (x86)
   SetRegView 64
   ReadRegStr $0 HKLM Software\Microsoft\Windows\CurrentVersion ProgramFilesDir
   MessageBox MB_OK $0 # C:\Program Files
${Else}
   ReadRegStr $0 HKLM Software\Microsoft\Windows\CurrentVersion ProgramFilesDir
   MessageBox MB_OK $0 # C:\Program Files
${EndIf}
SectionEnd

Откройте хедер x64.nsh - дает еще возможность:
"перенаправляться" к папкам 64-битных программ и 32-бытных

Код:

   
  SetOutPath $SYSDIR
  ${DisableX64FSRedirection}
  File some.dll # extracts to C:\Windows\System32
  ${EnableX64FSRedirection}
  File some.dll # extracts to C:\Windows\SysWOW64

[diakov]

Спасибо буду шаманить...отпишусь!

kotkovets, с извлечения файлов все понятно, а вот реестр...

!include x64.nsh
;;
Section
${If} ${RunningX64}
SetRegView 32
ReadRegStr $0 HKLM Software\Microsoft\Windows\CurrentVersion ProgramFilesDir
MessageBox MB_OK $0 # C:\Program Files (x86)
SetRegView 64
ReadRegStr $0 HKLM Software\Microsoft\Windows\CurrentVersion ProgramFilesDir
MessageBox MB_OK $0 # C:\Program Files
; И ТУТ ПИСАТЬ ВСЕ КЛЮЧИ ЧТО ДОЛЖНЫ БЫТЬ ПРОПИСАНЫ В Х64
${Else}
ReadRegStr $0 HKLM Software\Microsoft\Windows\CurrentVersion ProgramFilesDir
MessageBox MB_OK $0 # C:\Program Files
; А ТУТ ПИСАТЬ ВСЕ КЛЮЧИ ЧТО ДОЛЖНЫ БЫТЬ ПРОПИСАНЫ В Х86
${EndIf}
SectionEnd

я правильно понял?

[kotkovets]

я правильно понял? »

Почти и не обязательно плодить кучу секций в скриптах:

читать дальше »

Код:

Section "-Обычная установка"
${If} $Radio == 1
   ${If} ${RunningX64}   
          SetOutPath "$ProgramFiles64\greylink"
          File /r "${pkgdir}\greylink\x64\"
          ;;
          ;до конструкции Else - будет выполнено в х64 Windows
          SetRegView 64
          ; И ТУТ ПИСАТЬ ВСЕ КЛЮЧИ ЧТО ДОЛЖНЫ БЫТЬ ПРОПИСАНЫ В Х64
          ;;
   ${Else}
          SetOutPath "$ProgramFiles\greylink"
          File /r "${pkgdir}\greylink\x86\"
          ;;
          ;до конструкции EndIf - будет выполнено в х32 Windows
           SetRegView 32
          ; А ТУТ ПИСАТЬ ВСЕ КЛЮЧИ ЧТО ДОЛЖНЫ БЫТЬ ПРОПИСАНЫ В Х86
          ;;
  ${EndIf}
       ; А ТУТ ПИСАТЬ МОЖНО ВСЕ ОБЩИЕ КЛЮЧИ ДЛЯ х64 и х32
       ;;
${EndIf}
SectionEnd

[diakov]

Понятно я просто вынес эти ключи для создание контекста корзины

Код:

Section "-Корзина"
   ${If} $Check2 == 1
WriteRegDWORD HKEY_LOCAL_MACHINE "SOFTWARE\Classes\CLSID\{645FF040-5081-101B-9F08-00AA002F954E}\shell\Открыть CCleaner..." "CCRBType" 0x2
WriteRegStr HKEY_LOCAL_MACHINE "SOFTWARE\Classes\CLSID\{645FF040-5081-101B-9F08-00AA002F954E}\shell\Открыть CCleaner...\command" "" "$PROGRAMFILES\CCleaner\CCleaner.exe"
WriteRegDWORD HKEY_LOCAL_MACHINE "SOFTWARE\Classes\CLSID\{645FF040-5081-101B-9F08-00AA002F954E}\shell\Запустить CCleaner" "CCRBType" 0x1
WriteRegStr HKEY_LOCAL_MACHINE "SOFTWARE\Classes\CLSID\{645FF040-5081-101B-9F08-00AA002F954E}\shell\Запустить CCleaner\command" "" "$PROGRAMFILES\CCleaner\CCleaner.exe /AUTO"
      ;;;
  ${EndIf}
SectionEnd

И еще такое теперь получается, если х64 то

Section "-Ярлыки"
${If} $Check == 1
${If} ${RunningX64}
CreateShortCut "$Desktop\${PRODUCT_NAME}.lnk" "$INSTDIR\CCleaner.exe" сответственно будет $INSTDIR\CCleaner64.exe"
;;;
DetailPrint "Ярлык на рабочий стол"
;;;

${EndIf}
${If} $Check1 == 1
CreateDirectory "$SMPROGRAMS\${PRODUCT_NAME}"
CreateShortCut "$SMPROGRAMS\${PRODUCT_NAME}\${PRODUCT_NAME}.lnk" "$INSTDIR\CCleaner.exe" сответственно будет $INSTDIR\CCleaner64.exe"
CreateShortCut "$SMPROGRAMS\${PRODUCT_NAME}\Удалить ${PRODUCT_NAME}.lnk" "$INSTDIR\Удалить CCleaner.exe"
;;;
DetailPrint "Ярлык в меню Пуск"
${Else}

и уже если х86
;;;
${EndIf}
${EndIf}
SectionEnd

И аналогично при удалении ключей реестра в секции Uninstall так?

И аналогично при создании контекста корзина

Section "-Корзина"
${If} $Check2 == 1
${If} ${RunningX64}
ключи для контекста под х64
${Else}
ключи для контекста под х86
;;;
${EndIf}
${EndIf}
SectionEnd

Ил моно как то упростить)))

[kotkovets]

diakov, Я же говорил общие ключи, ярлыки пишите вне логики, ну зачем
же писать одно тоже по несколько раз.

И еще такое теперь получается, если х64 то Ил моно как то упростить)))

Все зависит от конкретной программы и требований к установке.
Ну к примеру, если 32-битная и 64-битная программа распаковывается в папку C:\app,
то команду создания ярлыков по логике пишем один раз, а если в папку программ, то можно
пуступить так:

Код:

InstallDir "$ProgramFiles64\App"
-
Section
  SetOutPath "$INSTDIR"
   ${If} ${RunningX64}   
          File /r "${pkgdir}\greylink\x64\"
          ;;
   ${Else}
          File /r "${pkgdir}\greylink\x86\"
         ;;
  ${EndIf}
    ;команда cоздания ярлыков
SecnionEnd

В x64 в переменную $INSTDIR - вернет путь к папке 64-битных программ
Program Files, а не 32 битных программ - Program Files(х86)
И следовательно в х32 вернет путь к обычной папке программ Program Files
С деинсталятором почти также, но важное отличие, деисталлятор возвращает путь в
переменную $INSTDIR - текущий каталог, откуда запущен деинсталлятор.

ключи для контекста под х64 ${Else} ключи для контекста под х86

Если CLSID ключей одинаковы, то можно писать только один раз.
Во общем смотрите, что общее в х32 и х64, а различия пишите в логику RunningX64

[diakov]

спасибо...kotkovets, шаманю тогда дальше...жалко что ноут не поддерживает х64 виртуализацию...так бы счас потестил...а так надо два компа под руками