[Iska]

zion87, как поступать, когда в папке «D:\1» несколько файлов *.exe, помимо «ghsrh.exe» и «ghsrh.exe»?

[zion87]

нет, там может быть только один кроме этих двух

ghsrh.exe, ghszm.exe - имена этих перепутал

[Iska]

zion87, попробуйте так:

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

set sPath=d:\1

if exist "%sPath%\." (
	for %%i in ("%sPath%\*.exe") do if "%%~nxi" neq "ghsrh.exe" if "%%~nxi" neq "ghszm.exe" if not defined sFileName set sFileName=%%~nxi
	
	if defined sFileName (
		echo [!sFileName!]
	) else (
		echo Not found file other [ghsrh.exe], [ghszm.exe].
	)
) else (
	echo Path [%sPath%] not found.
)

endlocal
exit /b 0

[zion87]

так выводит на экран exe но надо чтобы set s=этот.exe еще после этого
@echo off
color 09

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
твоя часть кода
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

:start
echo :%S% это фаил? (Y/N)
set /p X=
If "%X%"=="y" goto next
If "%X%"=="n" goto nex
If "%X%"=="Y" goto next
If "%X%"=="N" goto nex
goto start
:nex
echo :Введите имя с расширением
ты
ры
пы
:next
ты
ры
пы
ры
exit

вот так возможно замутить???????

[kiripanda]

надо чтобы set s »

ну замени sFileName на S

вариант с findstr
*можно использовать текстовый файл со списком исключений и регэкспы

Код:

@echo off
setlocal

set sPath=d:\1

set "S="
for /f "delims=" %%i in ('dir /b "%sPath%\*.exe" ^|findstr /bev /c:ghsrh.exe /c:ghszm.exe') do set "S=%%i"
echo [%S%]

If "%X%"=="y" goto next If "%X%"=="Y" goto next

сокращается до

If /i "%X%"=="Y" goto next

[zion87]

Товарищи kiripanda, Iska спасибо огромное, все ТЫРЫПЫРИТ!!!! Ну вы и красавчиКИ )))))))